บทแนะนำกฎ

รายงานปัญหา ดูแหล่งที่มา /3} /4} {3/4} {3/4} {3/4} {3/4} /4.

Starlark เป็นภาษาการกำหนดค่าที่มีลักษณะคล้ายกับ Python ซึ่งเดิมพัฒนาขึ้นเพื่อใช้ใน Bazel และนับจากนั้นใช้โดยเครื่องมืออื่นๆ ไฟล์ BUILD และ .bzl ของ Bazel เขียนในภาษาถิ่นของ Starlark ที่รู้จักกันอย่างถูกต้องในชื่อ "Build Language" แม้ว่ามักจะเรียกสั้นๆ ว่า "Starlark" โดยเฉพาะอย่างยิ่งเมื่อเน้นว่าฟีเจอร์แสดงในภาษาของบิลด์ ไม่ใช่ส่วนในตัวหรือส่วน "เนทีฟ" ของ Bazel Bazel เสริมภาษาหลักด้วยฟังก์ชันที่เกี่ยวข้องกับบิลด์มากมาย เช่น glob, genrule, java_binary เป็นต้น

ดูรายละเอียดเพิ่มเติมได้ในเอกสารประกอบของ Bazel และ Starlark รวมถึงเทมเพลต SIG ของกฎเป็นจุดเริ่มต้นสำหรับชุดกฎใหม่

กฎว่างเปล่า

หากต้องการสร้างกฎแรก ให้สร้างไฟล์ foo.bzl:

def _foo_binary_impl(ctx):
    pass

foo_binary = rule(
    implementation = _foo_binary_impl,
)

เมื่อเรียกใช้ฟังก์ชัน rule คุณต้องกำหนดฟังก์ชัน Callback ตรรกะจะเก็บไว้ที่นั่น แต่ ตอนนี้คุณสามารถปล่อยฟังก์ชันว่างไว้ได้ อาร์กิวเมนต์ ctx ให้ข้อมูลเกี่ยวกับเป้าหมาย

คุณจะโหลดกฎและใช้กฎจากไฟล์ BUILD ได้

สร้างไฟล์ BUILD ในไดเรกทอรีเดียวกัน

load(":foo.bzl", "foo_binary")

foo_binary(name = "bin")

วันนี้คุณสามารถกำหนดเป้าหมายได้โดยทำดังนี้

$ bazel build bin
INFO: Analyzed target //:bin (2 packages loaded, 17 targets configured).
INFO: Found 1 target...
Target //:bin up-to-date (nothing to build)

แม้ว่ากฎจะไม่ได้ดำเนินการใดๆ แต่กฎก็ทำงานเหมือนกับกฎอื่นๆ อยู่แล้ว ซึ่งมีชื่อที่จำเป็นและรองรับแอตทริบิวต์ทั่วไป เช่น visibility, testonly และ tags

โมเดลการประเมิน

ก่อนที่จะดำเนินการต่อ คุณควรทำความเข้าใจวิธีประเมินโค้ดก่อน

อัปเดต foo.bzl ด้วยข้อความคำสั่งพิมพ์บางรายการ:

def _foo_binary_impl(ctx):
    print("analyzing", ctx.label)

foo_binary = rule(
    implementation = _foo_binary_impl,
)

print("bzl file evaluation")

และ BUILD:

load(":foo.bzl", "foo_binary")

print("BUILD file")
foo_binary(name = "bin1")
foo_binary(name = "bin2")

ctx.label ตรงกับป้ายกำกับของเป้าหมายที่วิเคราะห์ ออบเจ็กต์ ctx มีช่องและวิธีการที่เป็นประโยชน์มากมาย คุณดูรายการอย่างละเอียดได้ในข้อมูลอ้างอิง API

ค้นหาโค้ดโดยใช้คำสั่งต่อไปนี้

$ bazel query :all
DEBUG: /usr/home/bazel-codelab/foo.bzl:8:1: bzl file evaluation
DEBUG: /usr/home/bazel-codelab/BUILD:2:1: BUILD file
//:bin2
//:bin1

โปรดสังเกต

• พิมพ์ "การประเมินไฟล์ bzl" ก่อน ก่อนประเมินไฟล์ BUILD Bazel จะประเมินไฟล์ทั้งหมดที่โหลด หากไฟล์ BUILD หลายไฟล์กําลังโหลด foo.bzl คุณจะเห็น "การประเมินไฟล์ bzl" เพียง 1 ครั้งเนื่องจาก Bazel แคชผลของการประเมิน
• ไม่มีการเรียกฟังก์ชัน Callback _foo_binary_impl การค้นหา Bazel จะโหลดไฟล์ BUILD ไฟล์ แต่ไม่วิเคราะห์เป้าหมาย

หากต้องการวิเคราะห์เป้าหมาย ให้ใช้cquery ("คำค้นหาที่กำหนดค่า") หรือคำสั่ง build ดังนี้

$ bazel build :all
DEBUG: /usr/home/bazel-codelab/foo.bzl:2:5: analyzing //:bin1
DEBUG: /usr/home/bazel-codelab/foo.bzl:2:5: analyzing //:bin2
INFO: Analyzed 2 targets (0 packages loaded, 0 targets configured).
INFO: Found 2 targets...

จะเห็นได้ว่าตอนนี้ระบบเรียก _foo_binary_impl 2 ครั้ง คือ 1 ครั้งสำหรับแต่ละเป้าหมาย

โปรดสังเกตว่าจะไม่มีการพิมพ์ "การประเมินไฟล์ bzl" และ "ไฟล์ BUILD" อีก เพราะการประเมิน foo.bzl ถูกแคชไว้หลังจากการเรียกไปยัง bazel query Bazel จะแสดงคำสั่ง print เมื่อมีการเรียกใช้จริงเท่านั้น

กำลังสร้างไฟล์

หากต้องการให้กฎมีประโยชน์มากขึ้น โปรดอัปเดตกฎเพื่อสร้างไฟล์ ขั้นแรก ประกาศไฟล์และตั้งชื่อ ในตัวอย่างนี้ ให้สร้างไฟล์ที่มีชื่อเดียวกับเป้าหมาย

ctx.actions.declare_file(ctx.label.name)

หากเรียกใช้ bazel build :all ตอนนี้ คุณจะได้รับข้อผิดพลาด

The following files have no generating action:
bin2

เมื่อใดก็ตามที่คุณประกาศไฟล์ คุณต้องแจ้งให้ Bazel ทราบว่าสร้างไฟล์ด้วยการสร้างการดำเนินการ ใช้ ctx.actions.write เพื่อสร้างไฟล์ที่มีเนื้อหาที่ระบุ

def _foo_binary_impl(ctx):
    out = ctx.actions.declare_file(ctx.label.name)
    ctx.actions.write(
        output = out,
        content = "Hello\n",
    )

รหัสถูกต้อง แต่ไม่สามารถดำเนินการใดๆ ได้:

$ bazel build bin1
Target //:bin1 up-to-date (nothing to build)

ฟังก์ชัน ctx.actions.write ลงทะเบียนการดำเนินการ ซึ่งสอนวิธีสร้างไฟล์ให้ Bazel ทราบ แต่ Bazel จะไม่สร้างไฟล์จนกว่าจะมีการขอไฟล์จริง ดังนั้นสิ่งสุดท้ายที่ต้องทำคือบอก Bazel ว่าไฟล์นี้เป็นเอาต์พุตของกฎ ไม่ใช่ไฟล์ชั่วคราวที่ใช้ภายในการใช้งานกฎ

def _foo_binary_impl(ctx):
    out = ctx.actions.declare_file(ctx.label.name)
    ctx.actions.write(
        output = out,
        content = "Hello!\n",
    )
    return [DefaultInfo(files = depset([out]))]

ดูฟังก์ชัน DefaultInfo และ depset ภายหลัง สำหรับตอนนี้ ให้สมมติว่าบรรทัดสุดท้ายเป็นวิธีสำหรับเลือกเอาต์พุตของกฎ

จากนั้นเรียกใช้ Bazel

$ bazel build bin1
INFO: Found 1 target...
Target //:bin1 up-to-date:
  bazel-bin/bin1

$ cat bazel-bin/bin1
Hello!

คุณสร้างไฟล์สำเร็จแล้ว

Attributes

หากต้องการให้กฎมีประโยชน์มากขึ้น ให้เพิ่มแอตทริบิวต์ใหม่โดยใช้โมดูล attr และอัปเดตคำจำกัดความของกฎ

เพิ่มแอตทริบิวต์สตริงชื่อ username:

foo_binary = rule(
    implementation = _foo_binary_impl,
    attrs = {
        "username": attr.string(),
    },
)

จากนั้นให้ตั้งค่าในไฟล์ BUILD ดังนี้

foo_binary(
    name = "bin",
    username = "Alice",
)

หากต้องการเข้าถึงค่าในฟังก์ชัน Callback ให้ใช้ ctx.attr.username ตัวอย่างเช่น

def _foo_binary_impl(ctx):
    out = ctx.actions.declare_file(ctx.label.name)
    ctx.actions.write(
        output = out,
        content = "Hello {}!\n".format(ctx.attr.username),
    )
    return [DefaultInfo(files = depset([out]))]

โปรดทราบว่าคุณสามารถกำหนดให้แอตทริบิวต์เป็นแอตทริบิวต์บังคับหรือตั้งค่าเริ่มต้นได้ ดูเอกสารประกอบของ attr.string คุณยังใช้แอตทริบิวต์ประเภทอื่นๆ ได้ด้วย เช่น booleanหรือรายการจำนวนเต็ม

การอ้างอิง

แอตทริบิวต์การขึ้นต่อกัน เช่น attr.label และ attr.label_list จะประกาศทรัพยากร Dependency จากเป้าหมายที่เป็นเจ้าของแอตทริบิวต์ไปยังเป้าหมายที่มีป้ายกำกับปรากฏในค่าของแอตทริบิวต์ แอตทริบิวต์ประเภทนี้เป็นพื้นฐานของกราฟเป้าหมาย

ในไฟล์ BUILD ป้ายกำกับเป้าหมายจะปรากฏเป็นออบเจ็กต์สตริง เช่น //pkg:name ในฟังก์ชันการติดตั้งใช้งาน คุณจะเข้าถึงเป้าหมายได้ด้วยออบเจ็กต์ Target เช่น ดูไฟล์ที่เป้าหมายส่งคืนด้วย Target.files

หลายไฟล์

โดยค่าเริ่มต้น เฉพาะเป้าหมายที่สร้างโดยกฎเท่านั้นที่อาจปรากฏเป็นทรัพยากร Dependency (เช่น เป้าหมาย foo_library()) หากต้องการให้แอตทริบิวต์ยอมรับเป้าหมายที่เป็นไฟล์อินพุต (เช่น ไฟล์ต้นฉบับในที่เก็บ) ให้ใช้ allow_files และระบุรายการนามสกุลไฟล์ที่ยอมรับ (หรือ True เพื่ออนุญาตนามสกุลไฟล์ใดก็ได้) ดังนี้

"srcs": attr.label_list(allow_files = [".java"]),

คุณเข้าถึงรายการไฟล์ได้ด้วย ctx.files.<attribute name> ตัวอย่างเช่น รายการไฟล์ในแอตทริบิวต์ srcs สามารถเข้าถึงได้

ctx.files.srcs

ไฟล์เดียว

หากต้องการเพียงไฟล์เดียว ให้ใช้ allow_single_file

"src": attr.label(allow_single_file = [".java"])

จากนั้นไฟล์นี้จะสามารถเข้าถึงได้โดยใช้ ctx.file.<attribute name>:

ctx.file.src

สร้างไฟล์ด้วยเทมเพลต

คุณสามารถสร้างกฎที่สร้างไฟล์ .cc ตามเทมเพลต นอกจากนี้ คุณจะใช้ ctx.actions.write เพื่อแสดงสตริงที่สร้างขึ้นในฟังก์ชันการใช้งานกฎได้ แต่อาจมีปัญหา 2 ข้อ อย่างแรก เมื่อเทมเพลตใหญ่ขึ้น หน่วยความจำจะมีประสิทธิภาพมากขึ้นเมื่อใส่ไว้ในไฟล์แยกต่างหากและหลีกเลี่ยงการสร้างสตริงขนาดใหญ่ในช่วงการวิเคราะห์ อย่างที่ 2 การใช้ไฟล์แยกต่างหาก จะสะดวกสำหรับผู้ใช้มากกว่า แต่ให้ใช้ ctx.actions.expand_template ซึ่งจะดำเนินการแทนที่ไฟล์เทมเพลต

สร้างแอตทริบิวต์ template เพื่อประกาศทรัพยากร Dependency ในไฟล์เทมเพลต

def _hello_world_impl(ctx):
    out = ctx.actions.declare_file(ctx.label.name + ".cc")
    ctx.actions.expand_template(
        output = out,
        template = ctx.file.template,
        substitutions = {"{NAME}": ctx.attr.username},
    )
    return [DefaultInfo(files = depset([out]))]

hello_world = rule(
    implementation = _hello_world_impl,
    attrs = {
        "username": attr.string(default = "unknown person"),
        "template": attr.label(
            allow_single_file = [".cc.tpl"],
            mandatory = True,
        ),
    },
)

ผู้ใช้ใช้กฎดังนี้ได้

hello_world(
    name = "hello",
    username = "Alice",
    template = "file.cc.tpl",
)

cc_binary(
    name = "hello_bin",
    srcs = [":hello"],
)

หากไม่ต้องการแสดงเทมเพลตต่อผู้ใช้ปลายทางและใช้เทมเพลตเดียวกันทุกครั้ง ก็กำหนดค่าเริ่มต้นและทำให้แอตทริบิวต์เป็นแบบส่วนตัวได้โดยทำดังนี้

    "_template": attr.label(
        allow_single_file = True,
        default = "file.cc.tpl",
    ),

แอตทริบิวต์ที่ขึ้นต้นด้วยขีดล่างจะเป็นแบบส่วนตัวและไม่สามารถตั้งค่าในไฟล์ BUILD ตอนนี้เทมเพลตกลายเป็นทรัพยากร Dependency แบบโดยนัยแล้ว: ทุกเป้าหมาย hello_world มีการขึ้นต่อกันในไฟล์นี้ อย่าลืมทำให้แพ็กเกจอื่นๆ เห็นไฟล์นี้ด้วยการอัปเดตไฟล์ BUILD และใช้ exports_files

exports_files(["file.cc.tpl"])

ก้าวต่อไป

• ดูเอกสารอ้างอิงสำหรับกฎ
• ทำความคุ้นเคยกับdepset
• ดูที่เก็บตัวอย่าง ซึ่งมีตัวอย่างกฎเพิ่มเติม