การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

รายงานปัญหา ดูแหล่งที่มา /3} /4} {3/4} {3/4} {3/4} {3/4} /4.

หากคุณเพิ่งเริ่มใช้ Bazel ให้เริ่มจากบทแนะนำการสร้าง Android ด้วย Bazel

ภาพรวม

Bazel ใช้งานได้ในการกำหนดค่าบิลด์ที่หลากหลาย รวมถึงการกำหนดค่าบิลด์หลายรายการที่ใช้เครื่องมือเชน Android Native Development Kit (NDK) ซึ่งหมายความว่าระบบจะรวบรวมกฎ cc_library และ cc_binary ปกติสำหรับ Android ได้โดยตรงภายใน Bazel Bazel ดำเนินการนี้ได้โดยใช้กฎที่เก็บ android_ndk_repository

สิ่งที่ต้องดำเนินการก่อน

โปรดตรวจสอบว่าคุณได้ติดตั้ง Android SDK และ NDK แล้ว

หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

ดูข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository ได้ที่รายการสร้างสารานุกรม

หากคุณใช้ Android NDK เวอร์ชันล่าสุด (r22 ขึ้นไป) ให้ใช้ Starlark ของ android_ndk_repository ทำตามวิธีการใน README

คู่มือเริ่มต้นฉบับย่อ

หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มทรัพยากร Dependency ของ cc_library ลงในกฎ android_binary หรือ android_library

เช่น ระบุไฟล์ BUILD ต่อไปนี้สำหรับแอป Android

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้ให้ผลลัพธ์ในกราฟเป้าหมายต่อไปนี้

ตัวอย่างผลการแข่ง

รูปที่ 1 สร้างกราฟของโปรเจ็กต์ Android ที่มีทรัพยากร Dependency ของ cc_library

หากต้องการสร้างแอป เพียงเรียกใช้

bazel build //app/src/main:app

คำสั่ง bazel build จะรวบรวมไฟล์ Java, ไฟล์ทรัพยากร Android และกฎ cc_library และจัดแพ็กเกจทุกอย่างลงใน APK

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel รวบรวม cc_libraries ทั้งหมดลงในไฟล์ออบเจ็กต์ที่ใช้ร่วมกัน (.so) ไฟล์เดียว ซึ่งกำหนดเป้าหมายสำหรับ ABI ของ armeabi-v7a โดยค่าเริ่มต้น หากต้องการเปลี่ยนหรือสร้างสำหรับ ABI หลายรายการพร้อมกัน โปรดดูส่วนการกำหนดค่า ABI เป้าหมาย

ตัวอย่างการตั้งค่า

ตัวอย่างนี้มีอยู่ในที่เก็บข้อมูลตัวอย่าง Bazel

ในไฟล์ BUILD.bazel มีการกำหนดกลุ่มเป้าหมาย 3 รายการด้วยกฎ android_binary, android_library และ cc_library

เป้าหมายระดับบนสุด android_binary จะสร้าง APK

เป้าหมาย cc_library มีไฟล์ต้นฉบับ C++ ไฟล์เดียวที่มีการใช้งานฟังก์ชัน JNI ดังนี้

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

เป้าหมาย android_library จะระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และการพึ่งพาเป้าหมาย cc_library สำหรับตัวอย่างนี้ MainActivity.java จะโหลดไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นเมธอดสำหรับฟังก์ชัน JNI ดังนี้

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า STL

หากต้องการกำหนดค่า C++ STL ให้ใช้แฟล็ก --android_crosstool_top

bazel build //:app --android_crosstool_top=target label

STL ที่ใช้ได้ใน @androidndk ได้แก่

STL ป้ายกำกับเป้าหมาย
STLport @androidndk//:toolchain-stlport
libc++ @androidndk//:toolchain-libcpp
Gnustl @androidndk//:toolchain-gnu-libstdcpp

STL เริ่มต้นสำหรับ r16 หรือต่ำกว่าคือ gnustl สำหรับ r17 ขึ้นไปจะเป็น libc++ เพื่อความสะดวก จะมีการใช้แทน @androidndk//:default_crosstool เป้าหมายกับ STL เริ่มต้นที่เกี่ยวข้อง

โปรดทราบว่าตั้งแต่ r18 เป็นต้นไป จะมีการนำ STLport และ gnustl ออก ทำให้ libc++ เป็น STL เดียวใน NDK

ดูข้อมูลเพิ่มเติมเกี่ยวกับ STL เหล่านี้ในเอกสารประกอบ NDK

กำลังกำหนดค่า ABI เป้าหมาย

หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --fat_apk_cpu ดังนี้

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

โดยค่าเริ่มต้น Bazel จะสร้างโค้ด Android แบบเนทีฟสำหรับ armeabi-v7a หากต้องการสร้างสำหรับ x86 (เช่น สำหรับโปรแกรมจำลอง) ให้ผ่าน --fat_apk_cpu=x86 หากต้องการสร้าง APK ที่สมบูรณ์สำหรับหลายสถาปัตยกรรม คุณสามารถระบุ CPU หลายรายการได้: --fat_apk_cpu=armeabi-v7a,x86

หากระบุ ABI มากกว่า 1 รายการ Bazel จะสร้าง APK ที่มีออบเจ็กต์ที่ใช้ร่วมกันสำหรับ ABI แต่ละรายการ

มี ABI ต่อไปนี้ให้ใช้งานโดยขึ้นอยู่กับการแก้ไข NDK และระดับ Android API

การแก้ไข NDK ABI
16 ปีหรือต่ำกว่า Armeabi, Armeabi-v7a, arm64-v8a, Mips, Mips64, x86, x86_64
17 ปีขึ้นไป Armeabi-v7a, arm64-v8a, x86, x86_64

ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสาร NDK

ไม่แนะนำให้ใช้ APK แบบ Multi-ABI Fat กับบิลด์ที่เผยแพร่เนื่องจากจะเพิ่มขนาดของ APK แต่ก็อาจมีประโยชน์สำหรับบิลด์การพัฒนาและ QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

C++ มาตรฐาน ธง
C++98 ค่าเริ่มต้น ไม่ต้องแจ้งว่าไม่เหมาะสม
C++11 --cxxopt=-std=c++11
C++14 --cxxopt=-std=c++14

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และ Linker ด้วย --cxxopt, --copt และ --linkopt ในคู่มือผู้ใช้

คุณยังระบุแฟล็กคอมไพเลอร์และ Linker เป็นแอตทริบิวต์ใน cc_library โดยใช้ copts และ linkopts ได้ด้วย เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การผสานรวมกับแพลตฟอร์มและ Toolchain

โมเดลการกำหนดค่าของ Bazel จะย้ายไปยังแพลตฟอร์มและtoolchain หากเวอร์ชันใช้ Flag --platforms เพื่อเลือกสถาปัตยกรรมหรือระบบปฏิบัติการที่จะสร้าง คุณจะต้องส่ง Flag --extra_toolchains ไปยัง Bazel เพื่อใช้ NDK

ตัวอย่างเช่น หากต้องการผสานรวมกับเครื่องมือ android_arm64_cgo ที่ให้บริการโดยกฎ Go ให้ส่ง --extra_toolchains=@androidndk//:all นอกเหนือจาก Flag --platforms

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

นอกจากนี้คุณยังลงทะเบียนในไฟล์ WORKSPACE ได้โดยตรง โดยทำดังนี้

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

การลงทะเบียนเครื่องมือเชนเหล่านี้จะบอกให้ Bazel มองหารหัสในไฟล์ BUILD ของ NDK (สำหรับ NDK 20) เมื่อแก้ไขข้อจำกัดของสถาปัตยกรรมและระบบปฏิบัติการ ดังนี้

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

วิธีการทำงาน: แนะนำการเปลี่ยนการกำหนดค่า Android

กฎ android_binary จะขอให้ Bazel สร้างทรัพยากร Dependency ได้โดยตรงในการกำหนดค่าที่เข้ากันได้กับ Android เพื่อให้บิลด์ของ Bazel ทำงานได้โดยไม่มีแฟล็กพิเศษใดๆ ยกเว้น --fat_apk_cpu และ --android_crosstool_top สำหรับการกำหนดค่า ABI และ STL

การกำหนดค่าอัตโนมัตินี้ใช้การเปลี่ยนการกำหนดค่าของ Android ในเบื้องหลัง

กฎที่ใช้ร่วมกันได้ เช่น android_binary จะเปลี่ยนการกำหนดค่าทรัพยากร Dependency เป็นการกำหนดค่า Android โดยอัตโนมัติ ดังนั้นจะมีเฉพาะโครงสร้างย่อยเฉพาะสำหรับ Android ของบิลด์เท่านั้นที่ได้รับผลกระทบ ส่วนอื่นๆ ของกราฟบิลด์จะได้รับการประมวลผลโดยใช้การกำหนดค่าเป้าหมายระดับบนสุด และอาจประมวลผลเป้าหมายเดียวในการกำหนดค่าทั้ง 2 แบบ หากมีเส้นทางผ่านกราฟบิลด์เพื่อรองรับการดำเนินการดังกล่าว

เมื่อ Bazel อยู่ในการกำหนดค่าที่เข้ากันได้กับ Android ซึ่งระบุที่ระดับบนสุดหรือเนื่องจากจุดเปลี่ยนที่ระดับสูงกว่า จุดเปลี่ยนที่พบเพิ่มเติมจะไม่แก้ไขการกำหนดค่าเพิ่มเติม

ตำแหน่งในตัวเดียวที่ทำให้เกิดการเปลี่ยนไปใช้การกำหนดค่า Android คือแอตทริบิวต์ deps ของ android_binary

ตัวอย่างเช่น หากคุณพยายามสร้างเป้าหมาย android_library ที่ขึ้นอยู่กับ cc_library โดยไม่มีการแฟล็ก คุณอาจพบข้อผิดพลาดเกี่ยวกับส่วนหัว JNI ที่ขาดหายไป ดังนี้

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

ตามหลักแล้ว การเปลี่ยนโดยอัตโนมัติเหล่านี้ควรทำให้ Bazel ทำสิ่งที่ถูกต้องได้ในบางกรณี อย่างไรก็ตาม หากเป้าหมายในบรรทัดคำสั่ง Bazel ต่ำกว่ากฎการเปลี่ยนเหล่านี้อยู่แล้ว เช่น นักพัฒนาซอฟต์แวร์ C++ ที่ทดสอบ cc_library ที่เจาะจง ก็จะต้องใช้ --crosstool_top ที่กำหนดเอง

การสร้าง cc_library สำหรับ Android โดยไม่ใช้ android_binary

หากต้องการสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ให้ใช้แฟล็ก --crosstool_top, --cpu และ --host_crosstool_top

เช่น

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

ในตัวอย่างนี้ เป้าหมาย cc_library และ cc_binary ระดับบนสุดสร้างขึ้นโดยใช้เครื่องมือเชน NDK แต่วิธีนี้ทำให้เครื่องมือโฮสต์ของ Bazel สร้างขึ้นด้วย Toolchain ของ NDK (และสำหรับ Android) เนื่องจากเครื่องมือดังกล่าวคัดลอกจาก Toolchain เป้าหมาย หากต้องการหลีกเลี่ยงปัญหานี้ ให้ระบุค่าของ --host_crosstool_top เป็น @bazel_tools//tools/cpp:toolchain เพื่อตั้งค่าเครื่องมือเชน C++ ของโฮสต์อย่างชัดแจ้ง

ด้วยวิธีการนี้ แผนผังบิลด์ทั้งหมดจะได้รับผลกระทบ

แฟล็กเหล่านี้อยู่ในการกำหนดค่า bazelrc (1 รายการสำหรับ ABI แต่ละรายการ) ได้ใน project/.bazelrc

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

จากนั้น หากต้องการสร้าง cc_library สำหรับ x86 ตัวอย่างเช่น ให้เรียกใช้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ให้ใช้วิธีนี้สำหรับเป้าหมายระดับต่ำ (เช่น cc_library) หรือเมื่อรู้อยู่แล้วว่าคุณกำลังสร้างอะไร อาศัยการเปลี่ยนแปลงการกำหนดค่าอัตโนมัติจาก android_binary สำหรับเป้าหมายระดับสูงที่คาดว่าจะสร้างเป้าหมายจำนวนมากที่คุณไม่สามารถควบคุมได้