หน้านี้ได้รับการแปลโดย Cloud Translation API

บทแนะนำ Bazel: กำหนดค่าเชนเครื่องมือ C++

รายงานปัญหา ดูแหล่งที่มา /3} /4} {3/4} {3/4} {3/4} {3/4} /4.

บทแนะนำนี้ใช้สถานการณ์ตัวอย่างเพื่ออธิบายวิธีกำหนดค่าเครื่องมือเชน C++ สำหรับโปรเจ็กต์ ซึ่งอิงตามโปรเจ็กต์ C++ ตัวอย่าง ที่สร้างโดยไม่มีข้อผิดพลาดโดยใช้ clang

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีต่อไปนี้

ตั้งค่าสภาพแวดล้อมของบิลด์
กำหนดค่าเครื่องมือเชน C++
สร้างกฎ Starlark ที่มีการกำหนดค่าเพิ่มเติมสำหรับ cc_toolchain เพื่อให้ Bazel สร้างแอปพลิเคชันด้วย clang ได้
ยืนยันผลลัพธ์ที่คาดหวังโดยการเรียกใช้ bazel build --config=clang_config //main:hello-world บนเครื่อง Linux
สร้างแอปพลิเคชัน C++

ก่อนเริ่มต้น

ตั้งค่าสภาพแวดล้อมของบิลด์

บทแนะนำนี้จะถือว่าคุณกำลังใช้ Linux และได้สร้างแอปพลิเคชัน C++ และติดตั้งเครื่องมือและไลบรารีที่เหมาะสมเรียบร้อยแล้ว บทแนะนำนี้ใช้ clang version 9.0.1 ซึ่งคุณสามารถติดตั้งในระบบของคุณ

ตั้งค่าสภาพแวดล้อมของบิลด์ดังนี้

หากยังไม่ได้ดำเนินการ ให้ดาวน์โหลดและติดตั้ง Bazel 0.23 ขึ้นไป
ดาวน์โหลดโปรเจ็กต์ C++ ตัวอย่างจาก GitHub แล้ววางไว้ในไดเรกทอรีที่ว่างเปล่าในเครื่องของคุณ
เพิ่มเป้าหมาย cc_binary ต่อไปนี้ลงในไฟล์ main/BUILD:
```
cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)
```

สร้างไฟล์ .bazelrc ที่รูทของไดเรกทอรีพื้นที่ทำงานด้วยเนื้อหาต่อไปนี้เพื่อให้ใช้แฟล็ก --config ได้

# Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

สำหรับรายการ build:{config_name} --flag=value แฟล็กบรรทัดคำสั่ง --config={config_name} จะเชื่อมโยงกับแฟล็กนั้นๆ โปรดดูเอกสารประกอบเกี่ยวกับแฟล็กที่ใช้ ดังนี้ crosstool_top, cpu และ host_crosstool_top

เมื่อสร้างเป้าหมายด้วย bazel build --config=clang_config //main:hello-world แล้ว Bazel จะใช้ Toolchain ที่กำหนดเองจาก cc_toolchain_suite //toolchain:clang_suite ชุดโปรแกรมดังกล่าวอาจแสดงเครื่องมือเชนที่แตกต่างกันสำหรับ CPU ที่แตกต่างกัน จึงมีความแตกต่างด้วย Flag --cpu=k8

เนื่องจาก Bazel ใช้เครื่องมือภายในที่เขียนด้วย C++ จำนวนมากขณะสร้าง เช่น process-wrapper จึงมีการระบุเครื่องมือเชน C++ เริ่มต้นที่มีอยู่เดิมสำหรับแพลตฟอร์มโฮสต์ไว้ ดังนั้นเครื่องมือเหล่านี้จึงสร้างขึ้นโดยใช้ Toolchain ดังกล่าวแทนที่จะเป็นเครื่องมือที่สร้างขึ้นในบทแนะนำนี้

การกำหนดค่าเครื่องมือเชน C++

หากต้องการกำหนดค่าเครื่องมือเชน C++ ให้สร้างแอปพลิเคชันซ้ำๆ และกำจัดข้อผิดพลาดทีละรายการตามที่อธิบายไว้ด้านล่าง

เรียกใช้บิลด์ด้วยคำสั่งต่อไปนี้
```
bazel build --config=clang_config //main:hello-world
```
เนื่องจากคุณระบุ --crosstool_top=//toolchain:clang_suite ในไฟล์ .bazelrc ทำให้ Bazel พบข้อผิดพลาดต่อไปนี้
```
No such package `toolchain`: BUILD file not found on package path.
```
ในไดเรกทอรีพื้นที่ทำงาน ให้สร้างไดเรกทอรี toolchain สำหรับแพ็กเกจ และไฟล์ BUILD ที่ว่างเปล่าภายในไดเรกทอรี toolchain
เรียกใช้บิลด์อีกครั้ง เนื่องจากแพ็กเกจ toolchain ยังไม่ได้กำหนดเป้าหมาย clang_suite Bazel จึงแสดงข้อผิดพลาดต่อไปนี้
```
No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD
```
ในไฟล์ toolchain/BUILD ให้กำหนดกลุ่มไฟล์ที่ว่างเปล่าดังนี้
```
package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")
```
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'
```
Bazel พบว่าแฟล็ก --crosstool_top ชี้ไปยังกฎที่ไม่ได้ระบุผู้ให้บริการ ToolchainInfo ที่จำเป็น คุณจึงต้องชี้ --crosstool_top ไปยังกฎที่ระบุ ToolchainInfo ซึ่งก็คือกฎ cc_toolchain_suite ในไฟล์ toolchain/BUILD ให้แทนที่กลุ่มไฟล์ที่ว่างเปล่าด้วยข้อมูลต่อไปนี้
```
cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)
```
แอตทริบิวต์ toolchains จะแมปค่า --cpu (และ --compiler เมื่อระบุ) กับ cc_toolchain โดยอัตโนมัติ คุณยังไม่ได้กำหนดเป้าหมาย cc_toolchain ใดๆ และ Bazel จะบ่นในเร็วๆ นี้
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
Rule '//toolchain:k8_toolchain' does not exist
```
ตอนนี้คุณต้องกำหนดเป้าหมาย cc_toolchain สำหรับทุกค่าในแอตทริบิวต์ cc_toolchain_suite.toolchains เพิ่มโค้ดต่อไปนี้ลงในไฟล์ toolchain/BUILD
```
filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)
```
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
Rule '//toolchain:k8_toolchain_config' does not exist
```
ถัดไป ให้เพิ่มเป้าหมาย ":k8_toolchain_config" ไปยังไฟล์ toolchain/BUILD ดังนี้
```
filegroup(name = "k8_toolchain_config")
```
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
'//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'
```
CcToolchainConfigInfo เป็นผู้ให้บริการที่คุณใช้ในการกำหนดค่าเครื่องมือเชน C++ ของคุณ หากต้องการแก้ไขข้อผิดพลาดนี้ ให้สร้างกฎ Starlark ที่จัดเตรียม CcToolchainConfigInfo ให้กับ Bazel โดยการสร้างไฟล์ toolchain/cc_toolchain_config.bzl ที่มีเนื้อหาต่อไปนี้
```
def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)
```
cc_common.create_cc_toolchain_config_info() สร้างผู้ให้บริการที่จำเป็น CcToolchainConfigInfo หากต้องการใช้กฎ cc_toolchain_config ให้เพิ่มคำสั่งการโหลดลงใน toolchain/BUILD ใต้คำสั่งแพ็กเกจ ดังนี้
```
load(":cc_toolchain_config.bzl", "cc_toolchain_config")
```
และแทนที่กลุ่มไฟล์ "k8_toolchain_config" ด้วยการประกาศกฎ cc_toolchain_config ดังนี้
```
cc_toolchain_config(name = "k8_toolchain_config")
```

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

ณ จุดนี้ Bazel มีข้อมูลเพียงพอที่จะพยายามสร้างโค้ด แต่ยังไม่ทราบว่าจะใช้เครื่องมือใดเพื่อดำเนินการบิลด์ที่จำเป็น คุณจะต้องแก้ไขการใช้กฎ Starlark เพื่อบอก Bazel ว่าต้องใช้เครื่องมือใด คุณต้องมีตัวสร้าง Tool_path() จาก @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl ดังนี้

# toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

ตรวจสอบว่า /usr/bin/clang และ /usr/bin/ld เป็นเส้นทางที่ถูกต้องสำหรับระบบ

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
 ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....
```
Bazel ต้องการทราบตำแหน่งที่จะค้นหาส่วนหัวที่รวมอยู่ ปัญหานี้ทำได้หลายวิธี เช่น การใช้แอตทริบิวต์ includes ของ cc_binary แต่ในที่นี้จะแก้ที่ระดับเครื่องมือเชนด้วยพารามิเตอร์ cxx_builtin_include_directories เป็น cc_common.create_cc_toolchain_config_info โปรดระวังว่าหากคุณใช้ clang เวอร์ชันอื่น เส้นทางการรวมจะแตกต่างออกไป เส้นทางเหล่านี้อาจแตกต่างกันขึ้นอยู่กับการกระจาย

แก้ไขค่าการแสดงผลใน toolchain/cc_toolchain_config.bzl ให้มีลักษณะดังนี้
```
 return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )
```

เรียกใช้คำสั่งบิลด์อีกครั้ง คุณจะเห็นข้อผิดพลาดอย่างเช่น

/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

เนื่องจาก Linker ไม่มีไลบรารีมาตรฐาน C++ และไม่พบสัญลักษณ์ ซึ่งทำได้หลายวิธี เช่น การใช้แอตทริบิวต์ linkopts ของ cc_binary ซึ่งแก้ปัญหาได้ด้วยการตรวจสอบว่าเป้าหมายที่ใช้เครื่องมือ Toolchain นั้นไม่จำเป็นต้องระบุ Flag นี้

คัดลอกรหัสต่อไปนี้ไปยัง cc_toolchain_config.bzl:

  # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

หากคุณเรียกใช้ bazel build --config=clang_config //main:hello-world จริงๆ แล้วเครื่อง ควรสร้างได้

ตรวจสอบงานของคุณ

ในบทแนะนำนี้ คุณได้เรียนรู้วิธีกำหนดค่า Toolchain พื้นฐาน C++ แล้ว แต่ Toolchain นั้นมีประสิทธิภาพมากกว่าตัวอย่างง่ายๆ นี้

สรุปประเด็นสำคัญมีดังนี้ - คุณต้องระบุ Flag --crosstool_top ในบรรทัดคำสั่งซึ่งควรชี้ไปยัง cc_toolchain_suite - คุณสร้างทางลัดสำหรับการกำหนดค่าที่เจาะจงได้โดยใช้ไฟล์ .bazelrc - cc_toolchain_suite อาจแสดง cc_toolchains สำหรับ CPU และคอมไพเลอร์ที่แตกต่างกัน คุณใช้แฟล็กบรรทัดคำสั่ง เช่น --cpu เพื่อแยกความแตกต่างได้ - คุณต้องแจ้งให้ Toolchain ทราบว่าเครื่องมืออยู่ ณ ที่ใด ในบทแนะนำนี้ เรามีเวอร์ชันที่เรียบง่ายเพื่อให้คุณเข้าถึงเครื่องมือจากระบบ หากสนใจวิธีการใช้งานที่พัฒนาได้ด้วยตนเอง คุณก็อ่านข้อมูลเกี่ยวกับพื้นที่ทำงานได้ที่นี่ เครื่องมืออาจมาจากพื้นที่ทำงานอื่นและคุณจะต้องทำให้ไฟล์ใช้งานได้ใน cc_toolchain โดยมีทรัพยากร Dependency เป้าหมายในแอตทริบิวต์ เช่น compiler_files คุณจะต้องเปลี่ยน tool_paths ด้วย - คุณสามารถสร้างฟีเจอร์เพื่อปรับแต่งแฟล็กที่ควรส่งไปยังการดำเนินการต่างๆ ไม่ว่าจะเป็นการลิงก์หรือการดำเนินการประเภทอื่นๆ

อ่านเพิ่มเติม

ดูรายละเอียดเพิ่มเติมได้ที่ การกำหนดค่าเครื่องมือเชน C++