หากคุณเพิ่งเคยใช้ Bazel โปรดเริ่มต้นด้วยบทแนะนำการสร้าง Android ด้วย Bazel
ภาพรวม
Bazel ทำงานได้ในการกำหนดค่าบิวด์ต่างๆ มากมาย ซึ่งรวมถึงหลายรูปแบบที่ใช้เชนเครื่องมือ Android Native Development Kit (NDK) ซึ่งหมายความว่าระบบจะคอมไพล์กฎ cc_library
และ cc_binary
ปกติสำหรับ Android ได้โดยตรงใน Bazel Bazel ดำเนินการนี้ด้วยการใช้กฎที่เก็บ android_ndk_repository
ข้อกำหนดเบื้องต้น
โปรดตรวจสอบว่าคุณติดตั้ง Android SDK และ NDK แล้ว
หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE
android_sdk_repository(
name = "androidsdk", # Required. Name *must* be "androidsdk".
path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)
android_ndk_repository(
name = "androidndk", # Required. Name *must* be "androidndk".
path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)
ดูข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository
ได้ที่รายการสร้างสารานุกรม
คู่มือเริ่มต้นฉบับย่อ
หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มทรัพยากร Dependency cc_library
ลงในกฎ android_binary
หรือ android_library
เช่น ระบุไฟล์ BUILD
ต่อไปนี้สำหรับแอป Android
# In <project>/app/src/main/BUILD.bazel
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
)
android_library(
name = "lib",
srcs = ["java/com/example/android/bazel/MainActivity.java"],
resource_files = glob(["res/**/*"]),
custom_package = "com.example.android.bazel",
manifest = "LibraryManifest.xml",
deps = [":jni_lib"],
)
android_binary(
name = "app",
deps = [":lib"],
manifest = "AndroidManifest.xml",
)
ไฟล์ BUILD
นี้จะส่งผลให้เกิดกราฟเป้าหมายต่อไปนี้
รูปที่ 1 สร้างกราฟสำหรับโปรเจ็กต์ Android ด้วยทรัพยากร Dependency ของ cc_library
หากต้องการสร้างแอป เพียงเรียกใช้:
bazel build //app/src/main:app
คำสั่ง bazel build
จะรวมไฟล์ Java, ไฟล์ทรัพยากรของ Android และกฎ cc_library
และรวมทุกอย่างลงใน APK ดังนี้
$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF
Bazel คอมไพล์ cc_libraries ทั้งหมดเป็นไฟล์ออบเจ็กต์ที่แชร์ไฟล์เดียว (.so
) ซึ่งกำหนดเป้าหมายสำหรับ armeabi-v7a
ABI ตามค่าเริ่มต้น หากต้องการเปลี่ยนการตั้งค่านี้หรือบิลด์สำหรับ ABI หลายรายการพร้อมกัน ให้ดูหัวข้อการกำหนดค่า ABI เป้าหมาย
ตัวอย่างการตั้งค่า
ตัวอย่างนี้อยู่ในที่เก็บตัวอย่าง Bazel
ในไฟล์ BUILD.bazel
จะมีการกำหนดเป้าหมาย 3 รายการไว้ด้วยกฎ android_binary
, android_library
และ cc_library
เป้าหมายระดับบนสุด android_binary
จะสร้าง APK
เป้าหมาย cc_library
มีไฟล์แหล่งที่มา C++ ไฟล์เดียวที่มีการติดตั้งใช้งานฟังก์ชัน JNI ดังนี้
#include <jni.h>
#include <string>
extern "C"
JNIEXPORT jstring
JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
JNIEnv *env,
jobject /* this */) {
std::string hello = "Hello from C++";
return env->NewStringUTF(hello.c_str());
}
เป้าหมาย android_library
จะระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และความเกี่ยวข้องกับเป้าหมาย cc_library
สำหรับตัวอย่างนี้ MainActivity.java
จะโหลดไฟล์ออบเจ็กต์ที่แชร์ libapp.so
และกำหนดลายเซ็นของเมธอดสำหรับฟังก์ชัน JNI ดังนี้
public class MainActivity extends AppCompatActivity {
static {
System.loadLibrary("app");
}
@Override
protected void onCreate(Bundle savedInstanceState) {
// ...
}
public native String stringFromJNI();
}
การกำหนดค่า STL
หากต้องการกำหนดค่า C++ STL ให้ใช้แฟล็ก --android_crosstool_top
bazel build //:app --android_crosstool_top=target label
STL ที่ใช้ได้ใน @androidndk
มีดังนี้
STL | ป้ายกำกับเป้าหมาย |
---|---|
STLport | @androidndk//:toolchain-stlport |
libc++ | @androidndk//:toolchain-libcpp |
Gunustl | @androidndk//:toolchain-gnu-libstdcpp |
สำหรับ r16 และต่ำกว่า STL เริ่มต้นคือ gnustl
สำหรับ r17 ขึ้นไปคือ libc++
เพื่อความสะดวก ระบบจะแทนที่เป้าหมาย @androidndk//:default_crosstool
เป็น STL เริ่มต้นที่เกี่ยวข้อง
โปรดทราบว่าตั้งแต่ r18 เป็นต้นไป STLport และ gnustl จะถูกนำออก ซึ่งทำให้ libc++
เป็น STL เพียงแห่งเดียวใน NDK
ดูข้อมูลเพิ่มเติมเกี่ยวกับ STL เหล่านี้ได้ในเอกสารประกอบ NDK
การกำหนดค่า ABI เป้าหมาย
หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --fat_apk_cpu
ดังนี้
bazel build //:app --fat_apk_cpu=comma-separated list of ABIs
โดยค่าเริ่มต้น Bazel จะสร้างโค้ด Android เนทีฟสำหรับ armeabi-v7a
หากต้องการสร้างสำหรับ x86
(เช่น สำหรับโปรแกรมจำลอง) ให้ส่ง --fat_apk_cpu=x86
หากต้องการสร้าง APK แบบอ้วนสำหรับสถาปัตยกรรมหลายๆ แบบ ให้ระบุ CPU หลายรายการดังนี้ --fat_apk_cpu=armeabi-v7a,x86
หากระบุ ABI มากกว่า 1 รายการ Bazel จะสร้าง APK ที่มีออบเจ็กต์ที่แชร์สำหรับ ABI แต่ละรายการ
ABI ต่อไปนี้จะพร้อมใช้งานโดยขึ้นอยู่กับการแก้ไข NDK และระดับ API ของ Android
การแก้ไข NDK | ABI |
---|---|
ไม่เกิน 16 ปี | Armeabi, Armeabi-V7a, Arm64-V8a, Mips, Mips64, X86, X86_64 |
17 ปีขึ้นไป | Armeabi-V7a, Arm64-V8a, X86, x86_64 |
ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสาร NDK
ไม่แนะนำให้ใช้ APK ของ Multi-ABI Fat สำหรับบิลด์ที่เผยแพร่ เนื่องจากจะเพิ่มขนาดของ APK แต่อาจมีประโยชน์สำหรับบิลด์การพัฒนาและ QA
การเลือกมาตรฐาน C++
ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++
มาตรฐาน C++ | ธง |
---|---|
C++98 | ค่าเริ่มต้น ไม่ต้องมีการแจ้งว่าไม่เหมาะสม |
ซี++11 | --cxxopt=-std=c++11 |
C++14 | --cxxopt=-std=c++14 |
เช่น
bazel build //:app --cxxopt=-std=c++11
อ่านข้อมูลเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และ Linker ด้วย --cxxopt
, --copt
และ --linkopt
ในคู่มือผู้ใช้
คุณยังระบุแฟล็กผู้คอมไพล์และ Linker เป็นแอตทริบิวต์ใน cc_library
โดยใช้ copts
และ linkopts
ได้ด้วย เช่น
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
copts = ["-std=c++11"],
linkopts = ["-ldl"], # link against libdl
)
การผสานรวมกับแพลตฟอร์มและห่วงโซ่เครื่องมือ
โมเดลการกำหนดค่าของ Bazel กำลังเปลี่ยนไปใช้แพลตฟอร์มและเครื่องมือเชน หากบิลด์ใช้แฟล็ก --platforms
เพื่อเลือกสถาปัตยกรรมหรือระบบปฏิบัติการที่จะสร้าง คุณจะต้องส่งแฟล็ก --extra_toolchains
ไปยัง Bazel เพื่อใช้ NDK
เช่น หากต้องการผสานรวมกับเครื่องมือ android_arm64_cgo
ที่ได้จากกฎ Go ให้ส่ง --extra_toolchains=@androidndk//:all
นอกเหนือจากแฟล็ก --platforms
bazel build //my/cc:lib \
--platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
--extra_toolchains=@androidndk//:all
นอกจากนี้คุณยังลงทะเบียนโดเมนดังกล่าวในไฟล์ WORKSPACE
ได้โดยตรง โดยทำดังนี้
android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")
การลงทะเบียนเครื่องมือเชนเหล่านี้จะบอก Bazel ให้ค้นหาในไฟล์ NDK BUILD
(สำหรับ NDK 20) เมื่อแก้ไขข้อจำกัดด้านสถาปัตยกรรมและระบบปฏิบัติการ
toolchain(
name = "x86-clang8.0.7-libcpp_toolchain",
toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
target_compatible_with = [
"@platforms//os:android",
"@platforms//cpu:x86_32",
],
toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)
toolchain(
name = "x86_64-clang8.0.7-libcpp_toolchain",
toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
target_compatible_with = [
"@platforms//os:android",
"@platforms//cpu:x86_64",
],
toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)
toolchain(
name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
target_compatible_with = [
"@platforms//os:android",
"@platforms//cpu:arm",
],
toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)
toolchain(
name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
target_compatible_with = [
"@platforms//os:android",
"@platforms//cpu:aarch64",
],
toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)
วิธีการทำงาน: ขอแนะนำการเปลี่ยนการกำหนดค่า Android
กฎ android_binary
สามารถขอให้ Bazel สร้างทรัพยากร Dependency ในการกำหนดค่าที่เข้ากันได้กับ Android โดยเฉพาะ เพื่อให้บิลด์ของ Bazel ทำงานได้โดยไม่มีแฟล็กพิเศษใดๆ ยกเว้น --fat_apk_cpu
และ --android_crosstool_top
สำหรับการกำหนดค่า ABI และ STL
การกำหนดค่าอัตโนมัตินี้ใช้การเปลี่ยนการกำหนดค่า Android ในเบื้องหลัง
กฎที่เข้ากันได้ เช่น android_binary
จะเปลี่ยนการกำหนดค่าทรัพยากร Dependency โดยอัตโนมัติเป็นการกำหนดค่า Android ดังนั้นเฉพาะโครงสร้างย่อยของบิลด์สำหรับ Android เท่านั้นที่จะได้รับผลกระทบ ส่วนอื่นๆ ของกราฟบิลด์จะประมวลผลโดยใช้การกำหนดค่าเป้าหมายระดับบนสุด และอาจประมวลผลเป้าหมายเดียวในการกำหนดค่าทั้งสองแบบ หากมีเส้นทางผ่านกราฟบิลด์เพื่อสนับสนุนเป้าหมายนั้น
เมื่อ Bazel อยู่ในการกำหนดค่าที่เข้ากันได้กับ Android ไม่ว่าจะระบุที่ระดับบนสุดหรือเนื่องจากจุดเปลี่ยนในระดับที่สูงกว่า จุดเปลี่ยนเพิ่มเติมที่พบจะไม่แก้ไขการกำหนดค่าเพิ่มเติม
ตำแหน่งในตัวเดียวที่ทริกเกอร์การเปลี่ยนไปใช้การกำหนดค่า Android คือแอตทริบิวต์ deps
ของ android_binary
ตัวอย่างเช่น หากคุณพยายามสร้างเป้าหมาย android_library
ที่มีการขึ้นต่อกันของ cc_library
โดยไม่มีแฟล็ก คุณอาจพบข้อผิดพลาดเกี่ยวกับส่วนหัว JNI ที่ขาดหายไป ดังนี้
ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.
ตามหลักแล้ว การเปลี่ยนโดยอัตโนมัติเหล่านี้ควรทำให้ Bazel ทำสิ่งที่ถูกต้องได้ในหลายกรณี อย่างไรก็ตาม หากเป้าหมายบนบรรทัดคำสั่ง Bazel ต่ำกว่ากฎการเปลี่ยนเหล่านี้อยู่แล้ว เช่น นักพัฒนาซอฟต์แวร์ C++ ที่ทดสอบ cc_library
ที่เจาะจง คุณจะต้องใช้ --crosstool_top
ที่กำหนดเอง
การสร้าง cc_library
สำหรับ Android โดยไม่ใช้ android_binary
หากต้องการสร้าง cc_binary
หรือ cc_library
แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary
ให้ใช้แฟล็ก --crosstool_top
, --cpu
และ --host_crosstool_top
เช่น
bazel build //my/cc/jni:target \
--crosstool_top=@androidndk//:default_crosstool \
--cpu=<abi> \
--host_crosstool_top=@bazel_tools//tools/cpp:toolchain
ในตัวอย่างนี้ เป้าหมาย cc_library
และ cc_binary
ระดับบนสุดสร้างขึ้นโดยใช้เชนเครื่องมือ NDK แต่วิธีนี้ทำให้สร้างเครื่องมือโฮสต์ของ Bazel เองด้วย Toolchain NDK (และสำหรับ Android) เนื่องจากเครื่องมือโฮสต์ของโฮสต์ได้รับการคัดลอกจาก Toolchain เป้าหมาย หากต้องการแก้ปัญหานี้ ให้ระบุค่า --host_crosstool_top
เป็น @bazel_tools//tools/cpp:toolchain
เพื่อตั้งค่าเชนเครื่องมือ C++ ของโฮสต์อย่างชัดแจ้ง
วิธีนี้ทำให้โครงสร้างบิลด์ทั้งหมดได้รับผลกระทบ
แฟล็กเหล่านี้สามารถใส่ลงในการกำหนดค่า bazelrc
(1 รายการสำหรับ ABI แต่ละรายการ) ใน project/.bazelrc
common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
จากนั้นหากต้องการสร้าง cc_library
สำหรับ x86
ให้เรียกใช้คำสั่งต่อไปนี้
bazel build //my/cc/jni:target --config=android_x86
โดยทั่วไป ใช้วิธีนี้กับเป้าหมายระดับต่ำ (เช่น cc_library
) หรือเมื่อทราบแน่ชัดว่ากำลังสร้างอะไร ใช้การเปลี่ยนการกำหนดค่าอัตโนมัติจาก android_binary
สำหรับเป้าหมายระดับสูงที่คุณคาดว่าจะสร้างเป้าหมายจำนวนมากที่คุณไม่ได้ควบคุม