自动执行组会为每种工具链类型选择一个执行平台。换句话说，一个目标可以有多个执行平台，而无需定义执行组。
快速摘要
自动执行组与工具链密切相关。如果您使用的是工具链，则需要通过添加 toolchain 参数在受影响的操作（使用工具链中的可执行文件或工具的操作）上进行设置。例如：
ctx.actions.run(
...,
executable = ctx.toolchain['@bazel_tools//tools/jdk:toolchain_type'].tool,
...,
toolchain = '@bazel_tools//tools/jdk:toolchain_type',
)
如果操作不使用工具链中的工具或可执行文件，并且 Blaze 未检测到这一点（引发错误），您可以设置 toolchain = None。
如果您需要在单个执行平台上使用多个工具链（某个操作使用两个或更多工具链中的可执行文件或工具），则需要手动定义 exec_groups（请参阅何时应使用自定义 exec_group？部分）。
历史记录
在 AEG 之前，执行平台是在规则级别选择的。例如：
my_rule = rule(
_impl,
toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
)
规则 my_rule 会注册两种工具链类型。这意味着，工具链解析用于查找同时支持这两种工具链类型的执行平台。除非使用 exec_groups 指定了其他执行平台，否则系统会对规则中的每个已注册操作使用所选执行平台。也就是说，规则中的所有操作以前都使用单个执行平台，即使它们使用来自不同工具链的工具也是如此（系统会为每个目标选择执行平台）。这导致当没有支持所有工具链的执行平台时，会出现失败。
当前状态
使用 AEG 时，系统会为每种工具链类型选择执行平台。前面示例的实现函数 my_rule 如下所示：
def _impl(ctx):
ctx.actions.run(
mnemonic = "First action",
executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
toolchain = '//tools:toolchain_type_1',
)
ctx.actions.run(
mnemonic = "Second action",
executable = ctx.toolchain['//tools:toolchain_type_2'].tool,
toolchain = '//tools:toolchain_type_2',
)
此规则会创建两项操作，First action 使用 //tools:toolchain_type_1 中的可执行文件，Second action 使用 //tools:toolchain_type_2 中的可执行文件。在 AEG 之前，这两项操作都将在支持这两种工具链类型的单个执行平台上执行。使用 AEG 时，只需在操作中添加 toolchain 参数，即可在提供工具链的执行平台上执行每个操作。这些操作可在不同的执行平台上执行。
同样，对于 ctx.actions.run_shell，当 tools 来自工具链时，应添加 toolchain 参数。
自定义执行组与自动执行组之间的区别
顾名思义，AEG 是系统为规则中注册的每种工具链类型自动创建的执行组。与“传统”执行组不同，您无需手动指定它们。
何时应使用自定义 exec_group？
只有在需要在单个执行平台上执行多个工具链时，才需要自定义 exec_groups。在所有其他情况下，无需定义自定义 exec_groups。例如：
def _impl(ctx):
ctx.actions.run(
...,
executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
tools = [ctx.toolchain['//tools:toolchain_type_2'].tool],
exec_group = 'two_toolchains',
)
my_rule = rule(
_impl,
exec_groups = {
"two_toolchains": exec_group(
toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
),
}
)
AEG 迁移
在 google3 内部，Blaze 已经在使用 AEG。 对于 Bazel 的外部依赖项，迁移工作正在进行中。部分规则已经在使用此功能（例如 Java 和 C++ 规则）。
哪些 Bazel 版本支持此迁移？
从 Bazel 7 开始，完全支持 AEG。
如何启用 AEG？
将 --incompatible_auto_exec_groups 设置为 true。如需详细了解该标志，请参阅 GitHub 问题。
如何在特定规则中启用 AEG？
为规则设置 _use_auto_exec_groups 属性。
my_rule = rule(
_impl,
attrs = {
"_use_auto_exec_groups": attr.bool(default = True),
}
)
这只会在 my_rule 中启用 AEG，并且其操作在选择执行平台时会开始使用新逻辑。此属性会替换不兼容的标志。
如何在出现错误时停用 AEG？
将 --incompatible_auto_exec_groups 设置为 false 可在项目中完全停用 AEG（标志的 GitHub 问题），或通过将 _use_auto_exec_groups 属性设置为 False 来停用特定规则（有关该属性的更多详细信息）。
迁移到 AEG 时的错误消息
无法确定工具是来自隐式依赖项还是工具链。请设置工具链参数。如果您不使用工具链，请将其设置为“None”。
- 在这种情况下，您会获得发生错误之前的一堆调用，并且可以清楚地看到哪些确切操作需要工具链参数。检查操作使用的工具链，并使用 toolchain 参数进行设置。如果操作中未针对工具或可执行文件使用任何工具链，请将其设置为
None。
为不存在的工具链“[toolchain_type]”声明了操作。
- 这意味着，您已在操作上设置了工具链参数，但未在规则上注册该参数。注册工具链或在操作中设置
None。
其他资料
如需了解详情，请参阅设计文档：工具链的自动执行组。