มาโคร

รายงานปัญหา ดูแหล่งที่มา /3} /4} {3/4} {3/4} {3/4} {3/4} /4.

หน้านี้ครอบคลุมพื้นฐานของการใช้มาโครและมีกรณีการใช้งานทั่วไป การแก้ไขข้อบกพร่อง และกฎเกณฑ์ต่างๆ

มาโครเป็นฟังก์ชันที่เรียกจากไฟล์ BUILD ซึ่งสร้างอินสแตนซ์กฎได้ โดยหลักแล้วมาโครจะใช้สำหรับการสรุปและการนำกฎที่มีอยู่และมาโครอื่นๆ มาใช้ซ้ำ เมื่อสิ้นสุดระยะการโหลด มาโครจะไม่อยู่อีกต่อไปและ Bazel จะเห็นเฉพาะชุดกฎที่จำลองขึ้นอย่างเป็นรูปธรรมเท่านั้น

การใช้งาน

กรณีการใช้งานทั่วไปของมาโครคือเมื่อคุณต้องการใช้กฎซ้ำ

ตัวอย่างเช่น Genrule ในไฟล์ BUILD จะสร้างไฟล์โดยใช้ //:generator ที่มีฮาร์ดโค้ดอาร์กิวเมนต์ some_arg ในคำสั่ง

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

หมายเหตุ: $@ คือสร้างตัวแปร ที่อ้างถึงตำแหน่งเวลาปฏิบัติการของไฟล์ในรายการแอตทริบิวต์ outs โดยมีค่าเทียบเท่ากับ $(locations :file.txt)

หากต้องการสร้างไฟล์ที่มีอาร์กิวเมนต์อื่นๆ เพิ่มเติม คุณอาจต้องดึงข้อมูลโค้ดนี้ไปยังฟังก์ชันมาโคร สมมติว่ามาโคร file_generator ซึ่งมีพารามิเตอร์ name และ arg โดยแทนที่ Genrule ด้วยคำสั่งต่อไปนี้

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

คุณจะโหลดสัญลักษณ์ file_generator จากไฟล์ .bzl ที่อยู่ในแพ็กเกจ //path การใส่คำจำกัดความฟังก์ชันมาโครในไฟล์ .bzl แยกต่างหากจะทำให้ไฟล์ BUILD ของคุณดูสะอาดตาและชัดเจน สามารถโหลดไฟล์ .bzl จากแพ็กเกจใดก็ได้ในพื้นที่ทำงาน

สุดท้าย ใน path/generator.bzl ให้เขียนคำจำกัดความของมาโครเพื่อสรุปและนำพารามิเตอร์ Genrule ต้นฉบับไปใช้เป็นพารามิเตอร์ ดังนี้

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

คุณยังสามารถใช้มาโครเพื่อเชื่อมโยงกฎต่างๆ เข้าด้วยกัน ตัวอย่างนี้แสดง Genrules ที่มีการเชื่อมโยง โดยที่ Genrule ใช้เอาต์พุตของ Genrule ก่อนหน้าเป็นอินพุต

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

ตัวอย่างนี้กำหนดค่าการเปิดเผยให้กับ Genrule ที่ 2 เท่านั้น ซึ่งช่วยให้ผู้เขียนมาโครสามารถซ่อนเอาต์พุตของกฎระดับกลางไม่ให้เป้าหมายอื่นๆ ในพื้นที่ทำงานได้

หมายเหตุ: เช่นเดียวกับ $@ สำหรับเอาต์พุต $< จะขยายไปยังตำแหน่งของไฟล์ในรายการแอตทริบิวต์ srcs

มาโครการขยาย

เมื่อต้องการตรวจสอบการทำงานของมาโคร ให้ใช้คำสั่ง query กับ --output=build เพื่อดูแบบฟอร์มแบบขยาย

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

กำลังสร้างอินสแตนซ์กฎเนทีฟ

คุณจะตรวจสอบกฎเนทีฟ (กฎที่ไม่ต้องใช้คำสั่ง load()) ได้จากโมดูลเนทีฟ ดังนี้

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

หากต้องการทราบชื่อแพ็กเกจ (เช่น ไฟล์ BUILD ใดเรียกใช้มาโคร) ให้ใช้ฟังก์ชัน native.package_name() โปรดทราบว่า native ใช้ได้ในไฟล์ .bzl เท่านั้น ไม่ใช่ในไฟล์ WORKSPACE หรือ BUILD

ความละเอียดของป้ายกำกับในมาโคร

เนื่องจากมาโครจะได้รับการประเมินในระยะการโหลด สตริงป้ายกำกับ เช่น "//foo:bar" ที่เกิดขึ้นในมาโครจะตีความโดยสัมพันธ์กับไฟล์ BUILD ที่ใช้มาโครมากกว่าที่สัมพันธ์กับไฟล์ .bzl ที่กำหนดไว้ ลักษณะการทำงานนี้โดยทั่วไปไม่เป็นที่ต้องการสำหรับมาโครที่มีจุดประสงค์เพื่อใช้ในที่เก็บอื่นๆ เช่น เนื่องจากมาโครเป็นส่วนหนึ่งของชุดกฎ Starlark ที่เผยแพร่

หากต้องการให้ลักษณะการทำงานเดียวกันกับกฎของ Starlark ให้รวมสตริงป้ายกำกับด้วยเครื่องมือสร้าง Label ดังนี้

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main workspace, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

การแก้ไขข้อบกพร่อง

• bazel query --output=build //my/path:all จะแสดงลักษณะของไฟล์ BUILD หลังจากการประเมิน มาโคร โลก ลูป ทั้งหมดจะขยายออก ข้อจำกัดที่ทราบ: ขณะนี้นิพจน์ select จะไม่แสดงในเอาต์พุต

• คุณอาจกรองเอาต์พุตโดยอิงตาม generator_function (ซึ่งฟังก์ชันที่สร้างกฎ) หรือ generator_name (แอตทริบิวต์ชื่อของมาโคร) ก็ได้ ดังนี้ bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'

• หากต้องการดูว่ากฎ foo สร้างขึ้นที่ใดในไฟล์ BUILD คุณลองทำตามเคล็ดลับต่อไปนี้ได้ แทรกบรรทัดนี้ใกล้กับด้านบนของไฟล์ BUILD cc_library(name = "foo") เรียกใช้ Bazel คุณจะได้รับข้อยกเว้นเมื่อสร้างกฎ foo (เนื่องจากชื่อขัดแย้งกัน) ซึ่งจะแสดงสแต็กเทรซทั้งสแต็ก

• คุณยังใช้ print เพื่อแก้ไขข้อบกพร่องได้ด้วย โดยจะแสดงข้อความเป็นบรรทัด DEBUG ในระหว่างกระบวนการโหลด ยกเว้นในบางกรณีซึ่งเกิดขึ้นไม่บ่อยนัก ให้นำการเรียก print ออกหรือกำหนดให้มีเงื่อนไขภายใต้พารามิเตอร์ debugging ที่มีค่าเริ่มต้นเป็น False ก่อนที่จะส่งโค้ดไปยัง Depot

ข้อผิดพลาด

หากต้องการส่งข้อผิดพลาด ให้ใช้ฟังก์ชันล้มเหลว อธิบายให้ผู้ใช้ทราบอย่างชัดเจนถึงสิ่งที่ผิดพลาดและวิธีแก้ไขไฟล์ BUILD ระบบไม่สามารถตรวจจับข้อผิดพลาดได้

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

การประชุม

• ฟังก์ชันสาธารณะทั้งหมด (ฟังก์ชันที่ไม่ได้ขึ้นต้นด้วยขีดล่าง) ที่กฎสรุปต้องมีอาร์กิวเมนต์ name อาร์กิวเมนต์นี้ไม่ควรเป็น ตัวเลือก (อย่าระบุค่าเริ่มต้น)

• ฟังก์ชันสาธารณะควรใช้ docstring ตามแบบแผน Python

• ในไฟล์ BUILD อาร์กิวเมนต์ name ของมาโครต้องเป็นอาร์กิวเมนต์คีย์เวิร์ด (ไม่ใช่อาร์กิวเมนต์ตำแหน่ง)

• แอตทริบิวต์ name ของกฎที่มาโครสร้างขึ้นควรมีอาร์กิวเมนต์ชื่อเป็นคำนำหน้า ตัวอย่างเช่น macro(name = "foo") สามารถสร้าง foo cc_library และ Genrule foo_gen ได้

• ในกรณีส่วนใหญ่ พารามิเตอร์ที่ไม่บังคับควรมีค่าเริ่มต้นเป็น None ระบบอาจส่ง None ไปยังกฎแบบเนทีฟโดยตรง ซึ่งจะปฏิบัติเช่นเดียวกับคุณไม่ได้ส่งผ่านในอาร์กิวเมนต์ใดๆ จึงไม่จำเป็นต้องแทนที่ด้วย 0, False หรือ [] เพื่อจุดประสงค์นี้ มาโครควรยึดตามกฎที่สร้างขึ้นแทน เนื่องจากค่าเริ่มต้นของมาโครอาจมีความซับซ้อนหรือเปลี่ยนแปลงเมื่อเวลาผ่านไป นอกจากนี้ พารามิเตอร์ที่ตั้งไว้เป็นค่าเริ่มต้นอย่างชัดเจนจะแตกต่างจากพารามิเตอร์ที่ไม่เคยตั้งค่า (หรือตั้งค่าเป็น None) เมื่อเข้าถึงผ่านภาษาการค้นหาหรือภายในของระบบบิลด์

• มาโครควรมีอาร์กิวเมนต์ visibility ที่ไม่บังคับ