BazelCon 2024 报名现已开放！

此页面由 Cloud Translation API 翻译。

Bazel 教程：配置 C++ 工具链

报告问题查看源代码每夜 build · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本教程通过一个示例场景介绍了如何为项目配置 C++ 工具链。它基于一个使用 clang 构建且没有错误的 C++ 示例项目。

学习内容

在本教程中，您将学习如何：

设置构建环境
配置 C++ 工具链
创建一个 Starlark 规则，为 cc_toolchain 提供额外的配置，以便 Bazel 可以使用 clang 构建应用
通过运行以下命令确认预期结果： bazel build --config=clang_config //main:hello-world（在 Linux 计算机上）
构建 C++ 应用

准备工作

设置构建环境

本教程假定您使用的是 Linux，并且已成功构建 C++ 应用，并安装了相应的工具和库。本教程使用 clang version 9.0.1，您可以在自己的系统上安装它。

请按照以下步骤设置构建环境：

如果您还没有这样做下载并安装 Bazel 0.23 或更高版本。
从 GitHub 下载 C++ 示例项目，并将其放在本地机器上的空目录中。

将以下 cc_binary 目标添加到 main/BUILD 文件中：

cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

在工作区目录的根目录下创建一个 .bazelrc 文件，其中包含以下内容，以便使用 --config 标志：

# Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

对于条目 build:{config_name} --flag=value，使用命令行标记 --config={config_name} 与该特定标志相关联。请参阅所用标志的文档： crosstool_top, cpu和 host_crosstool_top。

构建目标时与 bazel build --config=clang_config //main:hello-world 结合使用时，Bazel 会使用您的自定义工具链 cc_toolchain_suite //toolchain:clang_suite。该套件可能会列出工具链，适用于不同 CPU 因此，它使用 --cpu=k8 标志进行了区分。

由于 Bazel 在构建过程中会使用许多使用 C++ 编写的内部工具（例如 process-wrapper），因此为宿主平台指定了现有的默认 C++ 工具链，以便使用该工具链（而非本教程中创建的工具链）构建这些工具。

配置 C++ 工具链

要配置 C++ 工具链，重复构建应用并消除逐一检查每个错误。

使用以下命令运行构建：
```
bazel build --config=clang_config //main:hello-world
```
由于您在 .bazelrc 文件中指定了 --crosstool_top=//toolchain:clang_suite，因此 Bazel 会抛出以下错误：
```
No such package `toolchain`: BUILD file not found on package path.
```
在工作区目录中，为软件包创建 toolchain 目录并在 toolchain 目录下有一个空的 BUILD 文件。

再次运行 build。由于 toolchain 软件包尚未定义 clang_suite 目标，则 Bazel 会抛出以下错误：

No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD

在 toolchain/BUILD 文件中，定义一个空文件组，如下所示：

package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")

再次运行 build。Bazel 会抛出以下错误：
```
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'
```
Bazel 发现 --crosstool_top 标志指向的规则没有提供必要的 ToolchainInfo 提供商。因此，您需要将 --crosstool_top 指向确实提供 ToolchainInfo 的规则，即 cc_toolchain_suite 规则。在 toolchain/BUILD 文件，请将空文件组替换为以下代码：
```
cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)
```
toolchains 属性会自动将 --cpu（以及指定的 --compiler）值映射到 cc_toolchain。您尚未定义了任何 cc_toolchain 目标，Bazel 会指出这一点。

再次运行 build。Bazel 会抛出以下错误：

Rule '//toolchain:k8_toolchain' does not exist

现在您需要为cc_toolchain cc_toolchain_suite.toolchains 属性。将以下内容添加到 toolchain/BUILD 文件：

filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

再次运行构建。Bazel 会抛出以下错误：
```
Rule '//toolchain:k8_toolchain_config' does not exist
```
接下来，将“:k8_toolchain_config”目标添加到 toolchain/BUILD 文件中：
```
filegroup(name = "k8_toolchain_config")
```

再次运行 build。Bazel 会抛出以下错误：

'//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'

CcToolchainConfigInfo 是您用于配置 C++ 工具链。如需修正此错误，请创建一个 Starlark 规则，通过创建包含以下内容的 toolchain/cc_toolchain_config.bzl 文件向 Bazel 提供 CcToolchainConfigInfo：

def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

cc_common.create_cc_toolchain_config_info() 会创建所需的提供程序 CcToolchainConfigInfo。如需使用 cc_toolchain_config 规则，请添加加载项发送给 toolchains/BUILD：

load(":cc_toolchain_config.bzl", "cc_toolchain_config")

并替换“k8_toolchain_config”带有一个声明的 cc_toolchain_config 规则：

cc_toolchain_config(name = "k8_toolchain_config")

再次运行 build。Bazel 会抛出以下错误：

.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

此时，Bazel 有足够的信息来尝试构建代码，但它仍然不知道使用什么工具来完成所需的构建操作。您将修改 Starlark 规则实现，告诉 Bazel，什么所需的各种工具为此，您需要 @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl 中的 tool_path() 构造函数：

# toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

请确保 /usr/bin/clang 和 /usr/bin/ld 是正确的路径对系统的影响

再次运行构建。Bazel 会抛出以下错误：

 ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....

Bazel 需要知道在哪里搜索包含的头文件。还有有多种方法可以解决此问题，如使用 includes 属性 cc_binary，但这里使用 cxx_builtin_include_directories cc_common.create_cc_toolchain_config_info 的参数。请注意，如果您使用的是其他版本的 clang，包含路径将有所不同。这些路径也可能因分布而异。

将 toolchain/cc_toolchain_config.bzl 中的返回值修改为如下所示：

 return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )

再次运行构建命令，您将看到如下错误：

/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

这是因为链接器缺少 C++ 标准库，并且找不到其符号。您可以通过多种方式解决此问题，例如使用 cc_binary 的 linkopts 属性。在这里，谜题解开了确保使用工具链的任何目标都不必指定。

将以下代码复制到 cc_toolchain_config.bzl：

  # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

如果您运行 bazel build --config=clang_config //main:hello-world，它应该终于构建了

查看您的工作

在本教程中，您学习了如何配置基本的 C++ 工具链，但工具链的功能比这个简单示例更强大。

主要要点如下： - 您需要在命令行中指定一个 --crosstool_top 标志，该标志应指向 cc_toolchain_suite - 您可以使用 .bazelrc 文件为特定配置创建快捷方式 - cc_toolchain_suite 可能会为不同的 CPU 和编译器列出 cc_toolchains。您可以使用 --cpu 等命令行标志来区分。 - 您必须告知工具链工具所在的位置。在本教程中有一个简化版本，您可以通过系统访问相关工具。如果您对更独立的方法感兴趣，可以点击此处了解工作区。您的工具可能来自您需要将其文件设为可公开访问，设置为 cc_toolchain，其中包含属性的目标依赖项，例如 compiler_files。tool_paths 也需要更改。 - 您可以创建功能来自定义应将哪些标志传递给不同的操作，无论是关联操作还是任何其他类型的操作。

深入阅读

有关详情，请参阅 C++ 工具链配置