Bazel 教程:配置 C++ 工具链

本教程使用一个示例场景来说明如何为项目配置 C++ 工具链。它基于使用 clang 构建无错的示例 C++ 项目

学习内容

在本教程中,您将学习如何:

  • 设置构建环境
  • 配置 C++ 工具链
  • 创建一条为 cc_toolchain 提供其他配置的 Starlark 规则,以便 Bazel 可以使用 clang 构建应用
  • 通过在 Linux 机器上运行 bazel build --config=clang_config //main:hello-world 来确认预期结果
  • 构建 C++ 应用

准备工作

设置构建环境

本教程假定您使用 Linux,并且已成功构建了 C++ 应用并安装了适当的工具和库。本教程使用 clang version 9.0.1,您可以将其安装在系统上。

按如下方式设置构建环境:

  1. 下载并安装 Bazel 0.23 或更高版本(如果您尚未执行此操作)。

  2. 从 GitHub 下载示例 C++ 项目,并将其放置在本地机器上的空目录中。

  3. 将以下 cc_binary 目标添加到 main/BUILD 文件中:

    cc_binary(
        name = "hello-world",
        srcs = ["hello-world.cc"],
    )
    
  4. 使用以下内容在工作区目录的根目录下创建一个 .bazelrc 文件,以启用 --config 标志:

    # Use our custom-configured c++ toolchain.
    
    build:clang_config --crosstool_top=//toolchain:clang_suite
    
    # Use --cpu as a differentiator.
    
    build:clang_config --cpu=k8
    
    # Use the default Bazel C++ toolchain to build the tools used during the
    # build.
    
    build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
    

对于条目 build:{config_name} --flag=value,命令行标志 --config={config_name} 与该特定标志相关联。请参阅相关文档,了解所用标志:crosstool_topcpuhost_crosstool_top

当您使用 bazel build --config=clang_config //main:hello-world 构建目标时,Bazel 会使用 cc_toolchain_suite //toolchain:clang_suite 中的自定义工具链。该套件可能会针对不同的 CPU 列出不同的工具链,因此它通过 --cpu=k8 标志与众不同。

由于 Bazel 在构建过程中会使用许多以 C++ 编写的内部工具(例如进程封装容器),因此系统会为主机平台指定预先存在的默认 C++ 工具链,以便使用该工具链(而不是本教程中创建的工具链)构建这些工具。

配置 C++ 工具链

如需配置 C++ 工具链,请重复构建应用并逐个消除每个错误,如下所述。

  1. 使用以下命令运行 build:

    bazel build --config=clang_config //main:hello-world
    

    由于您在 .bazelrc 文件中指定了 --crosstool_top=//toolchain:clang_suite,因此 Bazel 会抛出以下错误:

    No such package `toolchain`: BUILD file not found on package path.
    

    在工作区目录中,为软件包创建 toolchain 目录,并在 toolchain 目录内创建一个空的 BUILD 文件。

  2. 再次运行构建。由于 toolchain 软件包尚未定义 clang_suite 目标,因此 Bazel 会抛出以下错误:

    No such target '//toolchain:clang_suite': target 'clang_suite' not declared
    in package 'toolchain' defined by .../toolchain/BUILD
    

    toolchain/BUILD 文件中,按如下所示定义一个空文件组:

    package(default_visibility = ["//visibility:public"])
    
    filegroup(name = "clang_suite")
    
  3. 再次运行构建。Bazel 会抛出以下错误:

    '//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'
    

    Bazel 发现 --crosstool_top 标志指向的规则未提供必要的 ToolchainInfo 提供程序。因此,您需要将 --crosstool_top 指向提供 ToolchainInfo 的规则,即 cc_toolchain_suite 规则。在 toolchain/BUILD 文件中,将空文件组替换为以下内容:

    cc_toolchain_suite(
        name = "clang_suite",
        toolchains = {
            "k8": ":k8_toolchain",
        },
    )
    

    toolchains 属性会自动将 --cpu 值(以及 --compiler 指定时)值映射到 cc_toolchain。您尚未定义任何 cc_toolchain 目标,Bazel 很快就会指出这一点。

  4. 再次运行构建。Bazel 会抛出以下错误:

    Rule '//toolchain:k8_toolchain' does not exist
    

    现在,您需要为 cc_toolchain_suite.toolchains 属性中的每个值定义 cc_toolchain 目标。将以下内容添加到 toolchain/BUILD 文件中:

    filegroup(name = "empty")
    
    cc_toolchain(
        name = "k8_toolchain",
        toolchain_identifier = "k8-toolchain",
        toolchain_config = ":k8_toolchain_config",
        all_files = ":empty",
        compiler_files = ":empty",
        dwp_files = ":empty",
        linker_files = ":empty",
        objcopy_files = ":empty",
        strip_files = ":empty",
        supports_param_files = 0,
    )
    
  5. 再次运行构建。Bazel 会抛出以下错误:

    Rule '//toolchain:k8_toolchain_config' does not exist
    

    接下来,将“:k8_toolchain_config”目标添加到 toolchain/BUILD 文件中:

    filegroup(name = "k8_toolchain_config")
    
  6. 再次运行构建。Bazel 会抛出以下错误:

    '//toolchain:k8_toolchain_config' does not have mandatory providers:
    'CcToolchainConfigInfo'
    

    CcToolchainConfigInfo 是用于配置 C++ 工具链的提供程序。如需修复此错误,请创建一个包含以下内容的 toolchain/cc_toolchain_config.bzl 文件,从而创建一条向 Bazel 提供 CcToolchainConfigInfo 的 Starlark 规则:

    def _impl(ctx):
        return cc_common.create_cc_toolchain_config_info(
            ctx = ctx,
            toolchain_identifier = "k8-toolchain",
            host_system_name = "local",
            target_system_name = "local",
            target_cpu = "k8",
            target_libc = "unknown",
            compiler = "clang",
            abi_version = "unknown",
            abi_libc_version = "unknown",
        )
    
    cc_toolchain_config = rule(
        implementation = _impl,
        attrs = {},
        provides = [CcToolchainConfigInfo],
    )
    

    cc_common.create_cc_toolchain_config_info() 会创建所需的提供程序 CcToolchainConfigInfo。如需使用 cc_toolchain_config 规则,请向 toolchains/BUILD 添加 load 语句:

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")
    

    并将“k8_toolchain_config”文件组替换为 cc_toolchain_config 规则的声明:

    cc_toolchain_config(name = "k8_toolchain_config")
    
  7. 再次运行构建。Bazel 会抛出以下错误:

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
    src/main/tools/linux-sandbox-pid1.cc:421:
    "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
    Target //:hello-world failed to build`
    

    此时,Bazel 已掌握了足够的信息来尝试构建代码,但仍不知道使用哪些工具来完成所需的构建操作。您将修改 Starlark 规则实现,告知 Bazel 使用哪些工具。为此,您需要 @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl 中的 tool_path() 构造函数:

    # toolchain/cc_toolchain_config.bzl:
    # NEW
    load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")
    
    def _impl(ctx):
        tool_paths = [ # NEW
            tool_path(
                name = "gcc",
                path = "/usr/bin/clang",
            ),
            tool_path(
                name = "ld",
                path = "/usr/bin/ld",
            ),
            tool_path(
                name = "ar",
                path = "/usr/bin/ar",
            ),
            tool_path(
                name = "cpp",
                path = "/bin/false",
            ),
            tool_path(
                name = "gcov",
                path = "/bin/false",
            ),
            tool_path(
                name = "nm",
                path = "/bin/false",
            ),
            tool_path(
                name = "objdump",
                path = "/bin/false",
            ),
            tool_path(
                name = "strip",
                path = "/bin/false",
            ),
        ]
        return cc_common.create_cc_toolchain_config_info(
            ctx = ctx,
            toolchain_identifier = "local",
            host_system_name = "local",
            target_system_name = "local",
            target_cpu = "k8",
            target_libc = "unknown",
            compiler = "clang",
            abi_version = "unknown",
            abi_libc_version = "unknown",
            tool_paths = tool_paths, # NEW
        )
    

    确保 /usr/bin/clang/usr/bin/ld 是您的系统的正确路径。

  8. 再次运行构建。Bazel 会抛出以下错误:

     ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
     this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
     '/usr/include/c++/9/ctime'
     '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
     '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
     ....
    

    Bazel 需要知道在哪里搜索包含的头文件。有多种方法可以解决此问题,例如使用 cc_binaryincludes 属性,但在这里,可以使用 cc_common.create_cc_toolchain_config_infocxx_builtin_include_directories 参数在工具链级别解决此问题。请注意,如果您使用的是不同版本的 clang,包含路径将有所不同。这些路径也可能因分发而异。

    toolchain/cc_toolchain_config.bzl 中的返回值修改为如下所示:

     return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          cxx_builtin_include_directories = [ # NEW
            "/usr/lib/llvm-9/lib/clang/9.0.1/include",
            "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
     )
    
  9. 再次运行构建命令,您将会看到如下错误:

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
    hello-world.cc:(.text+0x68): undefined reference to `std::cout'
    

    这是因为链接器缺少 C++ 标准库,且找不到其符号。解决此问题的方法有很多,例如使用 cc_binarylinkopts 属性。在这里,可以通过确保使用工具链的任何目标都不需要指定此标志来解决此问题。

    将以下代码复制到 cc_toolchain_config.bzl

      # NEW
      load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
      # NEW
      load(
          "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
          "feature",
          "flag_group",
          "flag_set",
          "tool_path",
      )
    
      all_link_actions = [ # NEW
          ACTION_NAMES.cpp_link_executable,
          ACTION_NAMES.cpp_link_dynamic_library,
          ACTION_NAMES.cpp_link_nodeps_dynamic_library,
      ]
    
      def _impl(ctx):
          tool_paths = [
              tool_path(
                  name = "gcc",
                  path = "/usr/bin/clang",
              ),
              tool_path(
                  name = "ld",
                  path = "/usr/bin/ld",
              ),
              tool_path(
                  name = "ar",
                  path = "/bin/false",
              ),
              tool_path(
                  name = "cpp",
                  path = "/bin/false",
              ),
              tool_path(
                  name = "gcov",
                  path = "/bin/false",
              ),
              tool_path(
                  name = "nm",
                  path = "/bin/false",
              ),
              tool_path(
                  name = "objdump",
                  path = "/bin/false",
              ),
              tool_path(
                  name = "strip",
                  path = "/bin/false",
              ),
          ]
    
          features = [ # NEW
              feature(
                  name = "default_linker_flags",
                  enabled = True,
                  flag_sets = [
                      flag_set(
                          actions = all_link_actions,
                          flag_groups = ([
                              flag_group(
                                  flags = [
                                      "-lstdc++",
                                  ],
                              ),
                          ]),
                      ),
                  ],
              ),
          ]
    
          return cc_common.create_cc_toolchain_config_info(
              ctx = ctx,
              features = features, # NEW
              cxx_builtin_include_directories = [
                  "/usr/lib/llvm-9/lib/clang/9.0.1/include",
                  "/usr/include",
              ],
              toolchain_identifier = "local",
              host_system_name = "local",
              target_system_name = "local",
              target_cpu = "k8",
              target_libc = "unknown",
              compiler = "clang",
              abi_version = "unknown",
              abi_libc_version = "unknown",
              tool_paths = tool_paths,
          )
    
      cc_toolchain_config = rule(
          implementation = _impl,
          attrs = {},
          provides = [CcToolchainConfigInfo],
      )
    
  10. 如果您运行 bazel build --config=clang_config //main:hello-world,它应该会最终进行构建。

检查您的工作

在本教程中,您学习了如何配置基本的 C++ 工具链。不过,工具链比这个简单的示例更强大。

关键要点如下: - 您需要在命令行中指定应指向 cc_toolchain_suite--crosstool_top 标志。 - 您可以使用 .bazelrc 文件为特定配置创建快捷方式。cc_toolchain_suite 可能会针对不同的 CPU 和编译器列出 cc_toolchains。您可以使用 --cpu 等命令行标志进行区分。- 您必须让工具链知道工具所在的位置。在本教程中,有一个简化版本,您可以从系统访问这些工具。如果您希望采用更加独立的方法,可以点击此处了解工作区。您的工具可能来自不同的工作区,并且您必须将其文件提供给 cc_toolchain,并使目标依赖项依赖于 compiler_files 等属性。tool_paths 也需要更改。- 您可以创建功能来自定义应将哪些标志传递给不同的操作,无论是链接操作还是任何其他类型的操作。

深入阅读

如需了解详情,请参阅 C++ 工具链配置