Variáveis de compartilhamento

Os arquivos BUILD precisam ser simples e declarativos. Normalmente, elas consistem em uma série de declarações de destino. À medida que a base de código e os arquivos BUILD ficam maiores, é provável que você note alguma duplicação, como:

cc_library(
  name = "foo",
  copts = ["-DVERSION=5"],
  srcs = ["foo.cc"],
)

cc_library(
  name = "bar",
  copts = ["-DVERSION=5"],
  srcs = ["bar.cc"],
  deps = [":foo"],
)

A duplicação de código em arquivos BUILD costuma ser boa. Isso pode deixar o arquivo mais legível: cada declaração pode ser lida e entendida sem contexto. Isso é importante, não apenas para humanos, mas também para ferramentas externas. Por exemplo, uma ferramenta pode ler e atualizar arquivos BUILD para adicionar dependências ausentes. A refatoração e a reutilização de código podem impedir esse tipo de modificação automatizada.

Se for útil compartilhar valores (por exemplo, se eles precisarem ser mantidos sincronizados), você poderá introduzir uma variável:

COPTS = ["-DVERSION=5"]

cc_library(
  name = "foo",
  copts = COPTS,
  srcs = ["foo.cc"],
)

cc_library(
  name = "bar",
  copts = COPTS,
  srcs = ["bar.cc"],
  deps = [":foo"],
)

Várias declarações agora usam o valor COPTS. Por convenção, use letras maiúsculas para nomear constantes globais.

Como compartilhar variáveis em vários arquivos BUILD

Se for necessário compartilhar um valor em vários arquivos BUILD, coloque-o em um arquivo .bzl. Os arquivos .bzl contêm definições (variáveis e funções) que podem ser usadas em arquivos BUILD.

Em path/to/variables.bzl, escreva:

COPTS = ["-DVERSION=5"]

Em seguida, atualize os arquivos BUILD para acessar a variável:

load("//path/to:variables.bzl", "COPTS")

cc_library(
  name = "foo",
  copts = COPTS,
  srcs = ["foo.cc"],
)

cc_library(
  name = "bar",
  copts = COPTS,
  srcs = ["bar.cc"],
  deps = [":foo"],
)