重要事項：本教學課程適用於舊版巨集。如果您只需要支援 Bazel 8 以上版本，建議改用符號巨集，請參閱「建立符號巨集」。
假設您需要在建構過程中執行工具。舉例來說，您可能想產生或預先處理來源檔案，或是壓縮二進位檔。在本教學課程中，您將建立可調整圖片大小的舊版巨集。
巨集適合用於簡單的工作。如要執行更複雜的操作 (例如新增對新程式設計語言的支援)，請考慮建立規則。規則可讓您進一步控管及調整。
如要建立可調整圖片大小的巨集，最簡單的方法是使用 genrule：
genrule(
name = "logo_miniature",
srcs = ["logo.png"],
outs = ["small_logo.png"],
cmd = "convert $< -resize 100x100 $@",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
如果需要調整更多圖片的大小，建議重複使用程式碼。如要這麼做，請在個別的 .bzl 檔案中定義函式，並呼叫 miniature.bzl 檔案：
def miniature(name, src, size = "100x100", **kwargs):
"""Create a miniature of the src image.
The generated file is prefixed with 'small_'.
"""
native.genrule(
name = name,
srcs = [src],
# Note that the line below will fail if `src` is not a filename string
outs = ["small_" + src],
cmd = "convert $< -resize " + size + " $@",
**kwargs
)
注意事項：
按照慣例，舊版巨集會包含
name引數，與規則相同。如要記錄舊版巨集的行為，請使用 docstring，就像在 Python 中一樣。
如要呼叫
genrule或任何其他原生規則，請加上native.前置字串。使用
**kwargs將額外引數轉送至基礎genrule(運作方式與 Python 相同)。這項功能非常實用，使用者可以運用visibility或tags等標準屬性。
現在，請使用 BUILD 檔案中的巨集：
load("//path/to:miniature.bzl", "miniature")
miniature(
name = "logo_miniature",
src = "image.png",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
最後，請注意警告：巨集會假設 src 是檔案名稱字串 (否則 outs = ["small_" + src] 會失敗)。因此 src = "image.png" 可以運作，但如果 BUILD 檔案改用 src =
"/versions/8.2.0//other/package:image.png"，甚至是 src = select(...)，會發生什麼情況？
請務必在巨集的說明文件中宣告這類假設。遺憾的是，舊版巨集 (尤其是大型巨集) 往往很脆弱，因為您可能難以注意到並記錄程式碼中的所有這類假設，而且當然，部分巨集使用者不會閱讀文件。如有可能，建議改用符號巨集，這類巨集內建屬性類型檢查。