重要提示：本教程适用于旧版宏。如果您只需要支持 Bazel 8 或更高版本，我们建议您改用符号宏；请参阅创建符号宏。
假设您需要在 build 过程中运行某个工具。例如，您可能需要生成或预处理源文件，或者压缩二进制文件。在本教程中，您将创建一个用于调整图片大小的旧版宏。
宏适合简单的任务。如果您想执行更复杂的操作，例如添加对新编程语言的支持，请考虑创建规则。规则可让您获得更高的控制权和灵活性。
创建可调整图片大小的宏的最简单方法是使用 genrule：
genrule(
name = "logo_miniature",
srcs = ["logo.png"],
outs = ["small_logo.png"],
cmd = "convert $< -resize 100x100 $@",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
如果您需要调整更多图片的大小，不妨重复使用该代码。为此，请在单独的 .bzl 文件中定义一个函数，并将该文件命名为 miniature.bzl：
def miniature(name, src, size = "100x100", **kwargs):
"""Create a miniature of the src image.
The generated file is prefixed with 'small_'.
"""
native.genrule(
name = name,
srcs = [src],
# Note that the line below will fail if `src` is not a filename string
outs = ["small_" + src],
cmd = "convert $< -resize " + size + " $@",
**kwargs
)
几点说明：
按照惯例，旧版宏具有
name实参，就像规则一样。如需记录旧版宏的行为，请使用 docstring（与 Python 中类似）。
如需调用
genrule或任何其他原生规则，请添加native.前缀。使用
**kwargs将额外的实参转发给底层genrule（其工作方式与 Python 中完全相同）。这非常有用，因为用户可以使用visibility或tags等标准属性。
现在，使用 BUILD 文件中的宏：
load("//path/to:miniature.bzl", "miniature")
miniature(
name = "logo_miniature",
src = "image.png",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
最后，请注意警告：该宏假定 src 是文件名字符串（否则，outs = ["small_" + src] 将失败）。因此，src = "image.png" 可以正常运行；但如果 BUILD 文件改用 src =
"/versions/8.2.0//other/package:image.png" 甚至 src = select(...)，会发生什么情况？
您应确保在宏的文档中声明此类假设。遗憾的是，旧版宏（尤其是大型宏）往往不太稳定，因为很难注意到代码中的所有此类假设并将其记录在文档中，而且当然，有些宏用户不会阅读文档。我们建议尽可能改用符号宏，它们内置了对属性类型的检查。