บทแนะนำ Bazel: กำหนดค่าเชนเครื่องมือ C++

รายงานปัญหา ดูซอร์สโค้ด รุ่น Nightly · 8.0 7.4 7.3 · 7.2 · 7.1 · 7.0 · 6.5

บทแนะนำนี้ใช้สถานการณ์ตัวอย่างเพื่ออธิบายวิธีกำหนดค่าชุดเครื่องมือ C++ สําหรับโปรเจ็กต์

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีทำสิ่งต่อไปนี้

ตั้งค่าสภาพแวดล้อมการสร้าง
ใช้ --toolchain_resolution_debug เพื่อแก้ไขข้อบกพร่องในการแก้ปัญหาเกี่ยวกับเครื่องมือทางเทคนิค
กำหนดค่าชุดเครื่องมือ C++
สร้างกฎ Starlark ที่ให้การกำหนดค่าเพิ่มเติมสำหรับ cc_toolchain เพื่อให้ Bazel สามารถสร้างแอปพลิเคชันด้วย clang ได้
คอมไพล์ไบนารี C++ สำหรับ Linux โดยเรียกใช้ bazel build //main:hello-world ในเครื่อง Linux
คอมไพล์แบบข้ามระบบสำหรับไบนารีของ Android โดยเรียกใช้ bazel build //main:hello-world --platforms=//:android_x86_64

ก่อนเริ่มต้น

บทแนะนํานี้ถือว่าคุณใช้ Linux และสร้างแอปพลิเคชัน C++ รวมถึงติดตั้งเครื่องมือและไลบรารีที่เหมาะสมเรียบร้อยแล้ว บทแนะนำใช้ clang version 16 ซึ่งคุณติดตั้งในระบบได้

ตั้งค่าสภาพแวดล้อมการสร้าง

ตั้งค่าสภาพแวดล้อมการสร้างดังนี้

ดาวน์โหลดและติดตั้ง Bazel เวอร์ชัน 7.0.2 ขึ้นไป หากยังไม่ได้ทำ
เพิ่มไฟล์ MODULE.bazel ที่ว่างเปล่าในโฟลเดอร์รูท
เพิ่มเป้าหมาย cc_binary ต่อไปนี้ลงในไฟล์ main/BUILD
```
cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)
```
เนื่องจาก Bazel ใช้เครื่องมือภายในจำนวนมากที่เขียนด้วย C++ ในระหว่างการสร้าง เช่น process-wrapper ระบบจะระบุชุดเครื่องมือ C++ เริ่มต้นที่มีอยู่สำหรับแพลตฟอร์มโฮสต์ ซึ่งจะช่วยให้เครื่องมือภายในเหล่านี้สร้างโดยใช้ชุดเครื่องมือของเครื่องมือที่สร้างในบทแนะนำนี้ได้ ดังนั้น เป้าหมาย cc_binary จึงสร้างขึ้นด้วยชุดเครื่องมือเริ่มต้นด้วย
เรียกใช้บิลด์ด้วยคําสั่งต่อไปนี้
```
bazel build //main:hello-world
```
บิลด์สำเร็จโดยไม่มีเครื่องมือทางเทคนิคที่ลงทะเบียนใน MODULE.bazel

หากต้องการดูข้อมูลเพิ่มเติมเกี่ยวกับสิ่งที่เกิดขึ้น ให้เรียกใช้คำสั่งต่อไปนี้
```
bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type'

INFO: ToolchainResolution: Target platform @@platforms//host:host: Selected execution platform @@platforms//host:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8
```
หากไม่ได้ระบุ --platforms ไว้ Bazel จะสร้างเป้าหมายสำหรับ @platforms//host โดยใช้ @bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8

กำหนดค่าชุดเครื่องมือ C++

หากต้องการกำหนดค่าชุดเครื่องมือ C++ ให้สร้างแอปพลิเคชันซ้ำๆ และแก้ไขข้อผิดพลาดแต่ละข้อทีละรายการตามที่อธิบายไว้ด้านล่าง

และถือว่า clang version 9.0.1 ด้วย แม้ว่ารายละเอียดจะเปลี่ยนแปลงเพียงเล็กน้อยระหว่าง clang เวอร์ชันต่างๆ

เพิ่ม toolchain/BUILD ด้วย

filegroup(name = "empty")

cc_toolchain(
    name = "linux_x86_64_toolchain",
    toolchain_identifier = "linux_x86_64-toolchain",
    toolchain_config = ":linux_x86_64_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

toolchain(
    name = "cc_toolchain_for_linux_x86_64",
    toolchain = ":linux_x86_64_toolchain",
    toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
    exec_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
)

จากนั้นเพิ่มข้อกําหนดที่เกี่ยวข้องและลงทะเบียนเครื่องมือทางเทคนิคกับ MODULE.bazel ด้วย

bazel_dep(name = "platforms", version = "0.0.10")
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64"
)

ขั้นตอนนี้จะกำหนด cc_toolchain และเชื่อมโยงกับเป้าหมาย toolchain สำหรับการกําหนดค่าโฮสต์

เรียกใช้บิลด์อีกครั้ง เนื่องจากแพ็กเกจ toolchain ยังไม่ได้กำหนดเป้าหมาย linux_x86_64_toolchain_config Bazel จึงแสดงข้อผิดพลาดต่อไปนี้
```
ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.
```
ในไฟล์ toolchain/BUILD ให้กําหนดกลุ่มไฟล์ว่างดังนี้
```
package(default_visibility = ["//visibility:public"])

filegroup(name = "linux_x86_64_toolchain_config")
```
เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
'//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.
```
CcToolchainConfigInfo เป็นผู้ให้บริการที่คุณใช้กำหนดค่าชุดเครื่องมือ C++ หากต้องการแก้ไขข้อผิดพลาดนี้ ให้สร้างกฎ Starlark ที่ระบุ CcToolchainConfigInfo ให้กับ Bazel โดยสร้างไฟล์ toolchain/cc_toolchain_config.bzl ที่มีเนื้อหาต่อไปนี้
```
def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)
```
cc_common.create_cc_toolchain_config_info() สร้างผู้ให้บริการที่จําเป็น CcToolchainConfigInfo หากต้องการใช้กฎ cc_toolchain_config ให้เพิ่มคำสั่งโหลดลงใน toolchain/BUILD ใต้คำสั่งแพ็กเกจ
```
load(":cc_toolchain_config.bzl", "cc_toolchain_config")
```
และแทนที่กลุ่มไฟล์ "linux_x86_64_toolchain_config" ด้วยการประกาศกฎ cc_toolchain_config ดังนี้
```
cc_toolchain_config(name = "linux_x86_64_toolchain_config")
```

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

ณ จุดนี้ Bazel มีข้อมูลเพียงพอที่จะพยายามสร้างโค้ด แต่ก็ยังไม่ทราบว่าจะต้องใช้เครื่องมือใดในการดําเนินการบิลด์ที่จําเป็นให้เสร็จสมบูรณ์ คุณจะแก้ไขการใช้งานกฎ Starlark เพื่อบอก Bazel ว่าจะใช้เครื่องมือใด ซึ่งต้องใช้เครื่องมือสร้าง tool_path() จาก @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl ดังนี้

# toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

ตรวจสอบว่า /usr/bin/clang และ /usr/bin/ld เป็นเส้นทางที่ถูกต้องสำหรับระบบของคุณ

เรียกใช้บิลด์อีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้
```
ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world':
the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain):
  '/usr/include/c++/13/ctime'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h'
  ...
```
Bazel จำเป็นต้องทราบว่าจะค้นหาส่วนหัวที่รวมไว้ที่ใด การแก้ปัญหานี้ทำได้หลายวิธี เช่น การใช้แอตทริบิวต์ includes ของ cc_binary แต่ที่นี่เราแก้ปัญหานี้ที่ระดับเครื่องมือทางเทคนิคด้วยพารามิเตอร์ cxx_builtin_include_directories ของ cc_common.create_cc_toolchain_config_info โปรดทราบว่าหากคุณใช้ clang เวอร์ชันอื่น เส้นทางรวมจะแตกต่างออกไป เส้นทางเหล่านี้อาจแตกต่างกันไปตามการแจกจ่าย

แก้ไขค่าที่แสดงผลใน toolchain/cc_toolchain_config.bzl ให้มีลักษณะดังนี้
```
return cc_common.create_cc_toolchain_config_info(
    ctx = ctx,
    cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-16/lib/clang/16/include",
        "/usr/include",
    ],
    toolchain_identifier = "local",
    host_system_name = "local",
    target_system_name = "local",
    target_cpu = "k8",
    target_libc = "unknown",
    compiler = "clang",
    abi_version = "unknown",
    abi_libc_version = "unknown",
    tool_paths = tool_paths,
)
```

เรียกใช้คำสั่งบิลด์อีกครั้ง คุณจะเห็นข้อผิดพลาด เช่น

/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

สาเหตุคือตัวลิงก์ไม่มีไลบรารีมาตรฐาน C++ และหาสัญลักษณ์ของไลบรารีดังกล่าวไม่พบ การแก้ปัญหานี้ทำได้หลายวิธี เช่น การใช้แอตทริบิวต์ linkopts ของ cc_binary ปัญหานี้แก้ไขได้โดยการตรวจสอบว่าเป้าหมายที่ใช้ชุดเครื่องมือไม่จำเป็นต้องระบุ Flag นี้

คัดลอกโค้ดต่อไปนี้ไปยัง toolchain/cc_toolchain_config.bzl

# NEW
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
# NEW
load(
    "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
    "feature",    # NEW
    "flag_group", # NEW
    "flag_set",   # NEW
    "tool_path",
)

all_link_actions = [ # NEW
    ACTION_NAMES.cpp_link_executable,
    ACTION_NAMES.cpp_link_dynamic_library,
    ACTION_NAMES.cpp_link_nodeps_dynamic_library,
]

def _impl(ctx):
    tool_paths = [
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/bin/false",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    features = [ # NEW
        feature(
            name = "default_linker_flags",
            enabled = True,
            flag_sets = [
                flag_set(
                    actions = all_link_actions,
                    flag_groups = ([
                        flag_group(
                            flags = [
                                "-lstdc++",
                            ],
                        ),
                    ]),
                ),
            ],
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        features = features, # NEW
        cxx_builtin_include_directories = [
            "/usr/lib/llvm-9/lib/clang/9.0.1/include",
            "/usr/include",
        ],
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths,
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

เมื่อเรียกใช้ bazel build //main:hello-world ในที่สุดก็ควรสร้างไบนารีสําหรับโฮสต์ได้สําเร็จ
ใน toolchain/BUILD ให้คัดลอกเป้าหมาย cc_toolchain_config, cc_toolchain และ toolchain แล้วแทนที่ linux_x86_64 ด้วย android_x86_64 ในชื่อเป้าหมาย

ใน MODULE.bazel ให้ลงทะเบียนชุดเครื่องมือสําหรับ Android
```
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64",
    "//toolchain:cc_toolchain_for_android_x86_64"
)
```
เรียกใช้ bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64 เพื่อสร้างไบนารีสำหรับ Android

ในทางปฏิบัติแล้ว Linux และ Android ควรมีการกําหนดค่าเครื่องมือ C++ ที่แตกต่างกัน คุณสามารถแก้ไข cc_toolchain_config ที่มีอยู่เพื่อระบุความแตกต่าง หรือสร้างกฎแยกต่างหาก (เช่น ผู้ให้บริการ CcToolchainConfigInfo) สําหรับแพลตฟอร์มต่างๆ

ตรวจสอบงาน

ในบทแนะนำนี้ คุณได้เรียนรู้วิธีกำหนดค่าเครื่องมือชุด C++ พื้นฐาน แต่เครื่องมือชุดมีประสิทธิภาพมากกว่าตัวอย่างนี้

ประเด็นสําคัญมีดังนี้

คุณต้องระบุ Flag platforms ที่ตรงกันในบรรทัดคำสั่งเพื่อให้ Bazel แก้ปัญหาในเครื่องมือทางเทคนิคสำหรับค่าข้อจำกัดเดียวกันบนแพลตฟอร์ม เอกสารประกอบมีข้อมูลเพิ่มเติมเกี่ยวกับ Flag การกําหนดค่าเฉพาะภาษา
คุณต้องแจ้งให้เครื่องมือทราบตำแหน่งของเครื่องมือ ในบทแนะนำนี้จะมีเวอร์ชันที่เข้าใจง่ายซึ่งคุณเข้าถึงเครื่องมือจากระบบได้ หากสนใจแนวทางแบบสําเร็จรูปมากขึ้น โปรดอ่านเกี่ยวกับการอ้างอิงภายนอก เครื่องมืออาจมาจากโมดูลอื่น และคุณจะต้องทำให้ไฟล์ของเครื่องมือพร้อมใช้งานสำหรับ cc_toolchain ที่มีแอตทริบิวต์เป้าหมาย เช่น compiler_files tool_paths จะต้องเปลี่ยนด้วย
คุณสามารถสร้างฟีเจอร์เพื่อปรับแต่ง Flag ที่ควรส่งไปยังการดำเนินการต่างๆ ไม่ว่าจะเป็นการลิงก์หรือการดําเนินการประเภทอื่นๆ

อ่านเพิ่มเติม

โปรดดูรายละเอียดเพิ่มเติมที่หัวข้อการกำหนดค่า toolchain ของ C++