Bazel 教學課程：設定 C++ 工具鍊

回報問題 查看原始碼 Nightly · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本教學課程會以示例情境說明如何為專案設定 C++ 工具鍊。

課程內容

在本教學課程中，您將學習如何：

  • 設定建構環境
  • 使用 --toolchain_resolution_debug 偵錯工具鍊解析度
  • 設定 C++ 工具鍊
  • 建立 Starlark 規則，為 cc_toolchain 提供額外設定，讓 Bazel 能夠使用 clang 建構應用程式
  • 在 Linux 電腦上執行 bazel build //main:hello-world，以便建構 C++ 二進位檔
  • 執行 bazel build //main:hello-world --platforms=//:android_x86_64，為 Android 跨平台編譯二進位檔

事前準備

本教學課程假設您使用的是 Linux，且已成功建構 C++ 應用程式，並安裝適當的工具和程式庫。本教學課程使用 clang version 16，您可以將其安裝在系統中。

設定建構環境

請按照下列步驟設定建構環境：

  1. 如果您尚未下載並安裝 Bazel 7.0.2 以上版本，請先完成這項操作。

  2. 在根資料夾中新增空白的 MODULE.bazel 檔案。

  3. 將下列 cc_binary 目標新增至 main/BUILD 檔案：

    cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

    由於 Bazel 在建構期間會使用許多以 C++ 編寫的內部工具 (例如 process-wrapper)，因此會為主機平台指定預先存在的預設 C++ 工具鍊。這樣一來，這些內部工具就能使用本教學課程中建立的工具鍊進行建構。因此，cc_binary 目標也會使用預設工具鍊進行建構。

  4. 使用下列指令執行建構作業：

    bazel build //main:hello-world

    建構作業成功，且未在 MODULE.bazel 中註冊任何工具鍊。

    如要進一步查看實際運作情形，請執行：

    bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type'

INFO: ToolchainResolution: Target platform @@platforms//host:host: Selected execution platform @@platforms//host:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8

    如果未指定 --platforms，Bazel 會使用 @bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8 建構 @platforms//host 的目標。

設定 C++ 工具鍊

如要設定 C++ 工具鍊，請反覆建構應用程式，並逐一排除每個錯誤，如下所述。

它也假設 clang version 9.0.1，但不同版本的 clang 之間的詳細資料應只會略有變動。

  1. 使用以下方法新增 toolchain/BUILD：

    filegroup(name = "empty")

cc_toolchain(
    name = "linux_x86_64_toolchain",
    toolchain_identifier = "linux_x86_64-toolchain",
    toolchain_config = ":linux_x86_64_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

toolchain(
    name = "cc_toolchain_for_linux_x86_64",
    toolchain = ":linux_x86_64_toolchain",
    toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
    exec_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ],
)

    接著，請新增適當的依附元件，並使用 MODULE.bazel 註冊工具鍊。

    bazel_dep(name = "platforms", version = "0.0.10")
register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64"
)

    這個步驟會定義 cc_toolchain，並將其繫結至主機設定的 toolchain 目標。

  2. 再次執行版本。由於 toolchain 套件尚未定義 linux_x86_64_toolchain_config 目標，因此 Bazel 會擲回以下錯誤：

    ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.

  3. 在 toolchain/BUILD 檔案中，定義空白的檔案群組，如下所示：

    package(default_visibility = ["//visibility:public"])

filegroup(name = "linux_x86_64_toolchain_config")

  4. 再次執行版本。Bazel 會擲回以下錯誤：

    '//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.

    CcToolchainConfigInfo 是用來設定 C++ 工具鍊的供應器。如要修正這項錯誤，請建立 Starlark 規則，透過建立含有下列內容的 toolchain/cc_toolchain_config.bzl 檔案，將 CcToolchainConfigInfo 提供給 Bazel：

    def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

    cc_common.create_cc_toolchain_config_info() 會建立所需的提供者 CcToolchainConfigInfo。如要使用 cc_toolchain_config 規則，請在套件陳述式下方右側的 toolchain/BUILD 中新增載入陳述式：

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")

    並將「linux_x86_64_toolchain_config」檔案群組替換為 cc_toolchain_config 規則的宣告：

    cc_toolchain_config(name = "linux_x86_64_toolchain_config")

  5. 再次執行版本。Bazel 會擲回以下錯誤：

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

    此時，Bazel 已取得足夠資訊，可嘗試建構程式碼，但仍不知道要使用哪些工具來完成必要的建構動作。您將修改 Starlark 規則實作，告訴 Bazel 要使用哪些工具。為此，您需要 @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl 中的 tool_path() 建構函式：

    # toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

    請確認 /usr/bin/clang 和 /usr/bin/ld 是系統的正確路徑。

  6. 再次執行版本。Bazel 會擲回以下錯誤：

    ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world':
the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain):
  '/usr/include/c++/13/ctime'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h'
  '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h'
  ...

    Bazel 需要知道要從何處搜尋所包含的標頭。解決這個問題的方法有很多，例如使用 cc_binary 的 includes 屬性，但這裡是透過 cc_common.create_cc_toolchain_config_info 的 cxx_builtin_include_directories 參數，在工具鍊層級解決這個問題。請注意，如果您使用的是其他版本的 clang，包含路徑就會有所不同。這些路徑也可能因發布版本而異。

    將 toolchain/cc_toolchain_config.bzl 中的傳回值修改為以下格式：

    return cc_common.create_cc_toolchain_config_info(
    ctx = ctx,
    cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-16/lib/clang/16/include",
        "/usr/include",
    ],
    toolchain_identifier = "local",
    host_system_name = "local",
    target_system_name = "local",
    target_cpu = "k8",
    target_libc = "unknown",
    compiler = "clang",
    abi_version = "unknown",
    abi_libc_version = "unknown",
    tool_paths = tool_paths,
)

  7. 再次執行建構指令，您會看到類似以下的錯誤訊息：

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

    這是因為連結器缺少 C++ 標準程式庫，因此無法找到其符號。解決這個問題的方法有很多，例如使用 cc_binary 的 linkopts 屬性。這裡的解決方法是確保使用工具鍊的任何目標都不需要指定這個標記。

    將下列程式碼複製到 toolchain/cc_toolchain_config.bzl：

    # NEW
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
# NEW
load(
    "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
    "feature",    # NEW
    "flag_group", # NEW
    "flag_set",   # NEW
    "tool_path",
)

all_link_actions = [ # NEW
    ACTION_NAMES.cpp_link_executable,
    ACTION_NAMES.cpp_link_dynamic_library,
    ACTION_NAMES.cpp_link_nodeps_dynamic_library,
]

def _impl(ctx):
    tool_paths = [
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/bin/false",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]

    features = [ # NEW
        feature(
            name = "default_linker_flags",
            enabled = True,
            flag_sets = [
                flag_set(
                    actions = all_link_actions,
                    flag_groups = ([
                        flag_group(
                            flags = [
                                "-lstdc++",
                            ],
                        ),
                    ]),
                ),
            ],
        ),
    ]

    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        features = features, # NEW
        cxx_builtin_include_directories = [
            "/usr/lib/llvm-9/lib/clang/9.0.1/include",
            "/usr/include",
        ],
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths,
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

  8. 執行 bazel build //main:hello-world 後，系統應該會成功為主機建構二進位檔。

  9. 在 toolchain/BUILD 中，複製 cc_toolchain_config、cc_toolchain 和 toolchain 目標，並在目標名稱中將 linux_x86_64 替換為 android_x86_64。

    在 MODULE.bazel 中註冊 Android 的工具鍊

    register_toolchains(
    "//toolchain:cc_toolchain_for_linux_x86_64",
    "//toolchain:cc_toolchain_for_android_x86_64"
)

  10. 執行 bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64 來建構 Android 的二進位檔。

在實際操作中，Linux 和 Android 應具有不同的 C++ 工具鍊設定。您可以修改現有的 cc_toolchain_config 以便處理差異，也可以為不同的平台建立個別規則 (即 CcToolchainConfigInfo 供應器)。

查看作業

在本教學課程中，您已瞭解如何設定基本 C++ 工具鍊，但工具鍊的功能比這個範例更強大。

重點摘要如下：

  • 您需要在指令列中指定相符的 platforms 旗標，讓 Bazel 將工具鍊解析為平台上的相同限制值。說明文件會提供更多關於語言專屬設定旗標的資訊。
  • 您必須讓工具鍊知道工具所在位置。本教學課程提供簡化版，讓您透過系統存取工具。如果您想採用更獨立的方法，請參閱外部依附元件。您的工具可能來自不同的模組，因此您必須將這些檔案提供給 cc_toolchain，並在屬性 (例如 compiler_files) 上設定目標依附元件。tool_paths 也需要變更。
  • 您可以建立功能，自訂應將哪些標記傳遞至不同的動作，無論是連結或任何其他類型的動作皆然。

延伸閱讀

詳情請參閱「C++ 工具鍊設定」