總覽
為了以正確的選項叫用編譯器，Bazel 需要一些關於編譯器內部資訊的知識，例如包含目錄和重要標記。換句話說，Bazel 需要簡化的編譯器模型，才能瞭解其運作方式。
Bazel 需要知道以下資訊：
- 是否支援精簡 LTO、模組、動態連結或 PIC (位置無關程式碼)。
- 必要工具的路徑，例如 gcc、ld、ar、objcopy 等等。
- 內建系統包含目錄。Bazel 需要這些資訊，才能驗證來源檔案中包含的所有標頭是否已在
BUILD檔案中正確宣告。 - 預設的 sysroot。
- 要用於編譯、連結、封存的標記。
- 針對支援的編譯模式 (opt、dbg、fastbuild) 使用哪些標記。
- 建立編譯器特別需要的變數。
如果編譯器支援多個架構，Bazel 就需要分別設定這些架構。
CcToolchainConfigInfo 是供應工具，可提供必要的細微程度，用於設定 Bazel 的 C++ 規則行為。根據預設，Bazel 會自動為建構作業設定 CcToolchainConfigInfo，但您也可以選擇手動設定。為此，您需要使用提供 CcToolchainConfigInfo 的 Starlark 規則，並將 cc_toolchain 的 toolchain_config 屬性指向規則。您可以呼叫 cc_common.create_cc_toolchain_config_info() 建立 CcToolchainConfigInfo。您可以在 @rules_cc//cc:cc_toolchain_config_lib.bzl 中找到 Starlark 建構函式，用於處理程序中所需的所有結構體。
當 C++ 目標進入分析階段時，Bazel 會根據 BUILD 檔案選取適當的 cc_toolchain 目標，並從 cc_toolchain.toolchain_config 屬性中指定的目標取得 CcToolchainConfigInfo 供應器。cc_toolchain 目標會透過 CcToolchainProvider 將這項資訊傳遞至 C++ 目標。
舉例來說，由 cc_binary 或 cc_library 等規則例項化的編譯或連結動作，需要以下資訊：
- 要使用的編譯器或連結器
- 編譯器/連結器的指令列標記
- 透過
--copt/--linkopt選項傳遞的設定旗標 - 環境變數
- 在動作執行的沙箱中所需的構件
除了沙箱中所需的構件外，上述所有資訊都會在 cc_toolchain 指向的 Starlark 目標中指定。
cc_toolchain 目標會宣告要運送至沙箱的構件。舉例來說，您可以使用 cc_toolchain.linker_files 屬性，指定要運送至沙箱的連結器二進位檔和工具鍊程式庫。
工具鍊選項
工具鍊選擇邏輯的運作方式如下：
使用者在
BUILD檔案中指定cc_toolchain_suite目標，並使用--crosstool_top選項將 Bazel 指向目標。cc_toolchain_suite目標會參照多個工具鍊。--cpu和--compiler標記的值會決定要選取哪個工具鍊，可依據--cpu標記值或共同--cpu | --compiler值。遴選流程如下：如果指定
--compiler選項，Bazel 會使用--cpu | --compiler從cc_toolchain_suite.toolchains屬性中選取對應的項目。如果 Bazel 找不到對應的項目，就會擲回錯誤。如果未指定
--compiler選項，Bazel 會使用--cpu從cc_toolchain_suite.toolchains屬性中選取對應的項目。如果未指定標記，Bazel 會檢查主機系統，並根據所找到的結果選取
--cpu值。請參閱檢查機制程式碼。
選取工具鍊後，Starlark 規則中的對應 feature 和 action_config 物件會控管建構的設定 (即後文所述項目)。這些訊息可讓您在 Bazel 中實作完整的 C++ 功能，而無須修改 Bazel 二進位檔。C++ 規則支援多種獨特動作，詳情請參閱 Bazel 原始碼。
功能
功能是指需要指令列標記、動作、執行環境限制或依附元件變更的實體。功能可以很簡單，例如允許 BUILD 檔案選取標記的設定 (例如 treat_warnings_as_errors)，或是與 C++ 規則互動，並在編譯時加入新的編譯動作和輸入內容 (例如 header_modules 或 thin_lto)。
理想情況下，CcToolchainConfigInfo 會包含一長串功能，每個功能都包含一或多個標記群組，每個群組都會定義一組適用於特定 Bazel 動作的標記。
功能會以名稱指定，可讓 Starlark 規則設定與 Bazel 版本完全解耦。換句話說，只要 CcToolchainConfigInfo 設定不需要使用新功能，Bazel 版本就不會影響其行為。
功能會透過下列其中一種方式啟用：
- 功能的
enabled欄位已設為true。 - Bazel 或規則擁有者明確啟用。
- 使用者可透過
--featureBazel 選項或features規則屬性啟用此功能。
功能可能會相互依賴，並依賴指令列旗標、BUILD 檔案設定和其他變數。
功能關係
依附元件通常會直接透過 Bazel 管理，Bazel 只會強制執行需求，並管理建構中定義的功能本質內在的衝突。工具鍊規格可讓您在 Starlark 規則中直接使用更精細的限制，以便控管功能支援和擴充功能。包括：
| 約束條件 | 說明 |
requires = [
feature_set (features = [
'feature-name-1',
'feature-name-2'
]),
] |
地圖項目等級。只有在啟用指定的必要功能時，系統才會支援這項功能。舉例來說，如果某項功能只在特定建構模式 (opt、dbg 或 fastbuild) 中受支援。如果 `requires` 包含多個 `feature_set`，只要滿足任何一個 `feature_set` (也就是所有指定功能都已啟用)，系統就會支援該功能。 |
implies = ['feature'] |
地圖項目等級。這項功能會暗示指定的功能。啟用某項功能也會隱含啟用該功能所暗示的所有功能 (也就是遞迴運作)。 也提供將常見功能子集從一組功能中分離出來的功能，例如消毒程式的常見部分。無法停用隱含的功能。 |
provides = ['feature'] |
地圖項目等級。表示這項功能是多項互斥的替代功能之一。舉例來說，所有消毒程式都可能會指定 如果使用者要求兩個或更多互斥的功能，系統會列出替代方案，藉此改善錯誤處理方式。 |
with_features = [
with_feature_set(
features = ['feature-1'],
not_features = ['feature-2'],
),
] |
標記設定層級。功能可使用多個標記集指定多個標記。指定 with_features 後，只有在至少有一個 with_feature_set 的情況下，標記集才會擴展至建構指令，且指定 features 集的所有功能都已啟用，而 not_features 集的所有功能都已停用。如果未指定 with_features，系統會對每個指定動作無條件套用旗標組合。 |
動作
動作可讓您彈性地修改動作執行的情況，而無須假設動作的執行方式。action_config 會指定動作叫用的工具二進位檔，而 feature 則會指定設定 (旗標)，決定該工具在動作叫用時的行為。
功能會參照動作，指出哪些 Bazel 動作會受到影響，因為動作可以修改 Bazel 動作圖表。CcToolchainConfigInfo 供應器包含與標記和工具相關聯的動作，例如 c++-compile。您可以將標記與功能建立關聯，藉此將標記指派給各項動作。
每個動作名稱都代表 Bazel 執行的單一類型動作，例如編譯或連結。不過，動作和 Bazel 動作類型之間存在多對一關係，其中 Bazel 動作類型是指實作動作的 Java 類別 (例如 CppCompileAction)。具體來說，下表中的「組譯器動作」和「編譯器動作」是 CppCompileAction，而連結動作則是 CppLinkAction。
組譯器動作
| 動作 | 說明 |
preprocess-assemble
|
使用預先處理功能組合。通常用於 .S 檔案。 |
assemble
|
不經過預處理程序即可組合。通常用於 .s 檔案。 |
編譯器動作
| 動作 | 說明 |
cc-flags-make-variable
|
將 CC_FLAGS 傳播至 genrules。 |
c-compile
|
以 C 編譯。 |
c++-compile
|
以 C++ 編譯。 |
c++-header-parsing
|
請在標頭檔案上執行編譯器的剖析器，確保標頭是自給自足的，否則會產生編譯錯誤。僅適用於支援模組的工具鍊。 |
連結動作
| 動作 | 說明 |
c++-link-dynamic-library
|
連結共用程式庫，其中包含所有依附元件。 |
c++-link-nodeps-dynamic-library
|
連結只包含 cc_library 來源的共用程式庫。 |
c++-link-executable
|
連結最終的即時執行程式庫。 |
AR 動作
AR 動作會透過 ar 將物件檔案組合成封存資料庫 (.a 檔案)，並將部分語意編碼至名稱中。
| 動作 | 說明 |
c++-link-static-library
|
建立靜態程式庫 (封存檔)。 |
LTO 動作
| 動作 | 說明 |
lto-backend
|
精簡 LTO 動作會將位元碼編譯為原生物件。 |
lto-index
|
產生全域索引的 ThinLTO 動作。 |
使用 action_config
action_config 是 Starlark 結構體，可透過指定在動作期間要叫用的工具 (二進位檔) 和旗標集合 (由功能定義) 來描述 Bazel 動作。這些標記會將限制套用至動作的執行作業。
action_config() 建構函式有以下參數：
| 屬性 | 說明 |
action_name
|
這個動作對應的 Bazel 動作。Bazel 會使用這項屬性來探索個別動作工具和執行要求。 |
tools
|
要叫用的執行檔。套用至動作的工具會是清單中第一個工具，且功能集必須與功能設定相符。必須提供預設值。 |
flag_sets
|
適用於一組動作的標記清單。與功能相同。 |
env_sets
|
適用於一組動作的環境限制清單。與功能相同。 |
action_config 可根據先前所述的特徵關係，要求及暗示其他特徵和 action_config。這項行為與功能的行為類似。
最後兩個屬性與功能的對應屬性重複，但我們仍將其納入，因為部分 Bazel 動作需要特定標記或環境變數，而我們的目標是避免不必要的 action_config+feature 組合。通常建議在多個 action_config 之間共用單一功能。
在同一個工具鍊中，您無法使用相同的 action_name 定義多個 action_config。這可避免工具路徑產生混淆，並確保 action_config 背後的意圖，也就是在工具鍊中單一位置清楚描述動作的屬性。
使用工具建構函式
action_config 可以透過 tools 參數指定一組工具。tool() 建構函式會採用下列參數：
| 欄位 | 說明 |
path
|
有問題的工具路徑 (相對於目前位置)。 |
with_features
|
功能集清單，其中至少一個必須滿足，才能套用此工具。 |
對於特定 action_config，只有單一 tool 會將其工具路徑和執行需求套用至 Bazel 動作。選取工具的方式是，在 action_config 上重複執行 tools 屬性，直到找到具有與功能設定相符的 with_feature 集合的工具為止 (詳情請參閱本頁稍早的「功能關聯」)。您應以空白功能設定對應的預設工具結束工具清單。
使用案例：
您可以結合使用功能和動作，以便透過各種跨平台語意實作 Bazel 動作。舉例來說，在 macOS 上產生偵錯符號時，需要在編譯動作中產生符號，然後在連結動作期間叫用專用工具，建立壓縮的 dsym 封存檔，接著解壓縮該封存檔，產生應用程式套件和 Xcode 可使用的 .plist 檔案。
使用 Bazel 時，您可以改為實作以下程序，其中 unbundle-debuginfo 為 Bazel 動作：
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
action_name = ACTION_NAMES.cpp_link_executable,
tools = [
tool(
with_features = [
with_feature(features=["generate-debug-symbols"]),
],
path = "toolchain/mac/ld-with-dsym-packaging",
),
tool (path = "toolchain/mac/ld"),
],
),
]
features = [
feature(
name = "generate-debug-symbols",
flag_sets = [
flag_set (
actions = [
ACTION_NAMES.c_compile,
ACTION_NAMES.cpp_compile
],
flag_groups = [
flag_group(
flags = ["-g"],
),
],
)
],
implies = ["unbundle-debuginfo"],
),
]
對於使用 fission 的 Linux，或產生 .pdb 檔案的 Windows，這項功能可以完全以不同的方式實作。舉例來說，以 fission 為基礎的偵錯符號產生作業的實作方式可能如下所示：
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
name = ACTION_NAMES.cpp_compile,
tools = [
tool(
path = "toolchain/bin/gcc",
),
],
),
]
features = [
feature (
name = "generate-debug-symbols",
requires = [with_feature_set(features = ["dbg"])],
flag_sets = [
flag_set(
actions = [ACTION_NAMES.cpp_compile],
flag_groups = [
flag_group(
flags = ["-gsplit-dwarf"],
),
],
),
flag_set(
actions = [ACTION_NAMES.cpp_link_executable],
flag_groups = [
flag_group(
flags = ["-Wl", "--gdb-index"],
),
],
),
],
),
]
標記群組
CcToolchainConfigInfo 可讓您將標記綁定為用於特定用途的群組。您可以在旗標值中使用預先定義的變數指定旗標，編譯器會在將旗標新增至建構指令時展開該變數。例如：
flag_group (
flags = ["%{output_execpath}"],
)
在這種情況下，標記的內容會替換為動作的輸出檔案路徑。
標記群組會依照清單中的顯示順序 (由上而下、由左至右) 展開至建構指令。
如果旗標在加入建構指令時需要重複使用不同值，旗標群組可以對 list 型別的變數進行疊代。例如，類型為 list 的變數 include_path：
flag_group (
iterate_over = "include_paths",
flags = ["-I%{include_paths}"],
)
會將 include_paths 清單中的每個路徑元素展開為 -I<path>。旗標群組宣告主體中的所有旗標 (或 flag_group) 會以單元展開。例如：
flag_group (
iterate_over = "include_paths",
flags = ["-I", "%{include_paths}"],
)
會將 include_paths 清單中的每個路徑元素展開為 -I <path>。
變數可以重複多次。例如：
flag_group (
iterate_over = "include_paths",
flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)
展開為：
-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>
變數可對應至可透過點號符號存取的結構體。例如：
flag_group (
flags = ["-l%{libraries_to_link.name}"],
)
結構體可嵌套，也可能包含序列。為避免名稱衝突並確保明確性，您必須透過欄位指定完整路徑。例如：
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
],
)
條件式展開
旗標群組可根據 expand_if_available、expand_if_not_available、expand_if_true、expand_if_false 或 expand_if_equal 屬性，根據特定變數或其欄位的存在情況支援條件式展開。例如：
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flag_groups = [
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--whole_archive"],
),
flag_group (
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--no_whole_archive"],
),
],
),
],
)
CcToolchainConfigInfo 參考資料
本節提供建構變數、功能和其他資訊的參考資料，這些資訊可協助您成功設定 C++ 規則。
CcToolchainConfigInfo 建構變數
以下是 CcToolchainConfigInfo 建構變數的參考資料。
| 變數 | 動作 | 說明 |
source_file
|
compile | 要編譯的來源檔案。 |
input_file
|
條紋 | 要移除的構件。 |
output_file
|
compile、strip | 編譯輸出內容。 |
output_assembly_file
|
compile | 已產生的組合語檔案。只有在 compile 動作發出彙整文字時才會套用，通常是在使用 --save_temps 標記時。內容與 output_file 相同。 |
output_preprocess_file
|
compile | 經過預處理的輸出內容。僅適用於只會預先處理來源檔案的編譯動作，通常是在使用 --save_temps 標記時。內容與 output_file 相同。 |
includes
|
compile | 編譯器必須無條件納入編譯來源的檔案序列。 |
include_paths
|
compile | 編譯器會使用 #include<foo.h> 和 #include "foo.h" 搜尋所包含標頭的序列目錄。 |
quote_include_paths
|
compile | -iquote 序列包含 - 目錄，其中編譯器會搜尋使用 #include "foo.h" 所納入的標頭。 |
system_include_paths
|
compile | -isystem 序列包含 - 目錄，其中編譯器會搜尋使用 #include <foo.h> 所納入的標頭。 |
dependency_file
|
compile | 編譯器產生的 .d 依附元件檔案。 |
preprocessor_defines
|
compile | defines 的序列，例如 --DDEBUG。 |
pic
|
compile | 將輸出內容編譯為位置無關的程式碼。 |
gcov_gcno_file
|
compile | gcov 涵蓋率檔案。 |
per_object_debug_info_file
|
compile | 每個物件的偵錯資訊 (.dwp) 檔案。 |
stripopts
|
條紋 | stripopts 的序列。 |
legacy_compile_flags
|
compile | 來自舊版 CROSSTOOL 欄位 (例如 compiler_flag、optional_compiler_flag、cxx_flag 和 optional_cxx_flag) 的標記序列。 |
user_compile_flags
|
compile | copt 規則屬性或 --copt、--cxxopt 和 --conlyopt 標記的旗標序列。 |
unfiltered_compile_flags
|
compile | unfiltered_cxx_flag 舊版 CROSSTOOL 欄位或 unfiltered_compile_flags 功能的標記序列。這些項目不會受到 nocopts 規則屬性的篩選。 |
sysroot
|
sysroot。 |
|
runtime_library_search_directories
|
連結 | 連結器執行階段搜尋路徑中的項目 (通常會使用 -rpath 標記設定)。 |
library_search_directories
|
連結 | 連結器搜尋路徑中的項目 (通常會使用 -L 標記設定)。 |
libraries_to_link
|
連結 | 在連結器叫用作業中，提供要連結的檔案做為輸入內容的標記。 |
def_file_path
|
連結 | 在 Windows 上使用 MSVC 時，def 檔案的位置。 |
linker_param_file
|
連結 | 由 Bazel 建立的連結器參數檔案位置，用於克服指令列長度限制。 |
output_execpath
|
連結 | 連結器輸出的執行路徑。 |
generate_interface_library
|
連結 | "yes" 或 "no"，視是否應產生介面程式庫而定。 |
interface_library_builder_path
|
連結 | 介面程式庫建構工具的路徑。 |
interface_library_input_path
|
連結 | 介面程式庫 ifso 建構工具的輸入內容。 |
interface_library_output_path
|
連結 | 使用 ifso 建構工具產生介面程式庫的路徑。 |
legacy_link_flags
|
連結 | 來自舊版 CROSSTOOL 欄位的連結器標記。 |
user_link_flags
|
連結 | 來自 --linkopt 或 linkopts 屬性的連結器標記。 |
linkstamp_paths
|
連結 | 提供連結圖章路徑的建構變數。 |
force_pic
|
連結 | 這個變數的存在表示應產生 PIC/PIE 程式碼 (已傳遞 Bazel 選項 `--force_pic`)。 |
strip_debug_symbols
|
連結 | 如果這個變數存在，表示應移除偵錯符號。 |
is_cc_test
|
連結 | 如果目前的動作是 cc_test 連結動作，則傳回真值，否則傳回假值。 |
is_using_fission
|
compile、link | 如果有這個變數，表示已啟用分裂 (每個物件偵錯資訊)。偵錯資訊會儲存在 .dwo 檔案中，而非 .o 檔案，編譯器和連結器需要知道這一點。 |
fdo_instrument_path
|
compile、link | 儲存 FDO 檢測設定檔的目錄路徑。 |
fdo_profile_path
|
compile | FDO 設定檔的路徑。 |
fdo_prefetch_hints_path
|
compile | 快取預先擷取設定檔的路徑。 |
cs_fdo_instrument_path
|
compile、link | 儲存情境敏感 FDO 檢測設定檔的目錄路徑。 |
常見功能
以下是功能和啟用條件的參考資料。
| 功能 | 說明文件 |
opt | dbg | fastbuild
|
根據編譯模式預設為啟用。 |
static_linking_mode | dynamic_linking_mode
|
根據連結模式預設為啟用。 |
per_object_debug_info
|
如果已指定並啟用 supports_fission 功能，且目前的編譯模式已在 --fission 標記中指定，則會啟用。 |
supports_start_end_lib
|
如果已啟用 (且已設定 --start_end_lib 選項)，Bazel 就不會連結至靜態資料庫，而是使用 --start-lib/--end-lib 連結器選項直接連結至物件。這樣一來，Bazel 就不需要建構靜態資料庫，因此可加快建構作業速度。 |
supports_interface_shared_libraries
|
如果啟用 (且已設定 --interface_shared_objects 選項)，Bazel 會將 linkstatic 設為 False (預設為 cc_test) 的目標連結至介面共用程式庫。這樣一來，增量重新連結的速度就會加快。 |
supports_dynamic_linker
|
啟用後，C++ 規則就會知道工具鍊可產生共用程式庫。 |
static_link_cpp_runtimes
|
如果啟用，Bazel 會在靜態連結模式中靜態連結 C++ 執行階段，並在動態連結模式中動態連結。cc_toolchain.static_runtime_lib 或 cc_toolchain.dynamic_runtime_lib 屬性中指定的構件 (視連結模式而定) 會新增至連結動作。 |
supports_pic
|
如果啟用，工具鍊就會知道要為動態程式庫使用 PIC 物件。每當需要 PIC 編譯時，就會出現 `pic` 變數。如果未預設啟用，且傳遞了 `--force_pic`，Bazel 會要求 `supports_pic`，並驗證是否已啟用這項功能。如果缺少這項功能，或無法啟用，就無法使用 `--force_pic`。 |
static_linking_mode | dynamic_linking_mode
|
根據連結模式預設為啟用。 |
no_legacy_features
|
避免 Bazel 在 C++ 設定中新增舊版功能 (如有)。請參閱下方的完整功能清單。 |
舊版功能修補邏輯
Bazel 會將下列變更套用至工具鍊的功能，以便回溯相容性：
- 將
legacy_compile_flags功能移至工具鍊頂端 - 將
default_compile_flags功能移至工具鍊頂端 - 將
dependency_file(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
pic(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
per_object_debug_info(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
preprocessor_defines(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
includes(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
include_paths(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
fdo_instrument(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
fdo_optimize(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
cs_fdo_instrument(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
cs_fdo_optimize(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
fdo_prefetch_hints(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
autofdo(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
build_interface_libraries(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
dynamic_library_linker_tool(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
shared_flag(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
linkstamps(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
output_execpath_flags(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
runtime_library_search_directories(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
library_search_directories(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
archiver_flags(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
libraries_to_link(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
force_pic_flags(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
user_link_flags(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
legacy_link_flags(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
static_libgcc(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
fission_support(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
strip_debug_symbols(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
coverage(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
llvm_coverage_map_format(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
gcc_coverage_map_format(如果沒有，則顯示 ) 功能新增至工具鍊頂端 - 將
fully_static_link(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
user_compile_flags(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
sysroot(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
unfiltered_compile_flags(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
linker_param_file(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
compiler_input_flags(如果沒有，則顯示 ) 功能新增至工具鍊底部 - 將
compiler_output_flags(如果沒有，則顯示 ) 功能新增至工具鍊底部
這是一長串功能清單。我們預計在Starlark 中的 Crosstool 完成後，移除這些檔案。如有興趣，請參閱 CppActionConfigs 中的實作方式，如果是正式版工具鍊，建議您新增 no_legacy_features，讓工具鍊更為獨立。