Bazel Sorgu Referansı

Sorun bildirme Kaynağı görüntüleme Nightly · 7.4 .

Bu sayfa, derleme bağımlılıklarını analiz etmek için bazel query kullandığınızda kullanılan Bazel Sorgu Dili için bir referans kılavuzudur. Ayrıca, bazel query'ün desteklediği çıkış biçimlerini de açıklar.

Pratik kullanım durumları için Bazel Sorgusu Nasıl Yapılır? bölümüne bakın.

Ek sorgu referansı

Yükleme sonrası aşama hedef grafiğinde çalışan query'ye ek olarak, Bazel'de eylem grafiği sorgusu ve yapılandırılabilir sorgu bulunur.

İşlem grafiği sorgusu

Eylem grafiği sorgusu (aquery), analiz sonrası Yapılandırılmış Hedef Grafik üzerinde çalışır ve İşlemler, Yapılar ve bunların ilişkileri hakkındaki bilgileri gösterir. aquery, yapılandırılmış hedef grafiğinden oluşturulan işlemler/yapıların özellikleriyle ilgilendiğinizde kullanışlıdır. Örneğin, gerçek komutların yanı sıra bunların girişleri, çıkışları ve anımsatıcıları çalışır.

Daha ayrıntılı bilgi için sorgu referansı bölümünü inceleyin.

Yapılandırılabilir sorgu

Geleneksel Bazel sorgusu, yükleme sonrası aşama hedef grafiğinde çalışır ve bu nedenle yapılandırma ve ilgili kavramları içermez. Özellikle, select ifadeleri doğru şekilde çözülmez ve bunun yerine seçimlerin tüm olası çözümlerini döndürür. Bununla birlikte, yapılandırılabilir sorgu ortamı cquery, yapılandırmaları düzgün şekilde işler ancak bu orijinal sorgunun tüm işlevlerini sunmaz.

Daha fazla bilgi için sorgu referansı bölümüne bakın.

Örnekler

Kullanıcılar bazel query ürününü nasıl kullanıyor? Aşağıda tipik örnekler verilmiştir:

//foo ağacı neden //bar/baz'a bağlı? Bir yol göster:

somepath(foo/..., //bar/baz:all)

Tüm foo testleri, foo_bin hedefinin kullanmadığı hangi C++ kitaplıklarına bağlı?

kind("cc_library", deps(kind(".*test rule", foo/...)) except deps(//foo:foo_bin))

Jetonlar: Söz dizimi

Sorgu dilindeki ifadeler aşağıdaki jetonlardan oluşur:

• let gibi anahtar kelimeler. Anahtar kelimeler, dilin ayrılmış kelimeleridir ve her biri aşağıda açıklanmıştır. Anahtar kelime kümesinin tamamı şöyledir:

  • except

  • in

  • intersect

  • let

  • set

  • union

• "foo/..." veya ".*test rule" ya da "//bar/baz:all" gibi kelimeler. Bir karakter dizisi "tırnak içine alınmışsa" (tek tırnak işareti ' ile başlar ve bitiyorsa veya çift tırnak işareti " ile başlar ve bitiyorsa) kelimedir. Alıntılanan bir karakter dizisi, yine de kelime olarak ayrıştırılabilir. Tırnak işareti içinde olmayan kelimeler, A-Za-z arası alfabe karakterleri, 0-9 arası sayılar ve */@.-_:$~[] özel karakterleri (yıldız, eğik çizgi, , at, nokta, tire, alt çizgi, iki nokta, dolar işareti, yaklaşık işareti, sol köşeli parantez, sağ köşeli parantez) arasındaki karakter dizileridir. Ancak göreli hedef adlar bu karakterlerle başlasa da tırnak işareti - veya yıldız işaretiyle * başlayamaz. Harici depoları ifade eden etiketlerin işlenmesini kolaylaştırmayı amaçlayan özel bir kural olarak, @@ ile başlayan ve alıntılanmamış kelimeler + karakter içerebilir.

  Hedef adlarda bu karakterlere izin verilse de tırnak içine alınmayan kelimeler artı işareti + veya eşittir işareti = karakterlerini içeremez. Sorgu ifadeleri oluşturan kod yazılırken hedef adların tırnak içine alınması gerekir.

  Kullanıcı tarafından sağlanan değerlerden Bazel sorgu ifadeleri oluşturan komut dosyaları yazarken tırnak içine almak gerekir.

   //foo:bar+wiz    # WRONG: scanned as //foo:bar + wiz.
   //foo:bar=wiz    # WRONG: scanned as //foo:bar = wiz.
   "//foo:bar+wiz"  # OK.
   "//foo:bar=wiz"  # OK.
  

  Bu tırnak işaretlerinin, kabuğunuz tarafından gerekebilecek tırnak işaretlerine ek olduğunu unutmayın. Örneğin:

  bazel query ' "//foo:bar=wiz" '   # single-quotes for shell, double-quotes for Bazel.

  Anahtar kelimeler ve operatörler, tırnak içine alındığında normal kelimeler olarak değerlendirilir. Örneğin, some bir anahtar kelimedir, ancak "bazı" bir kelimedir. Hem foo hem de "foo" kelimedir.

  Ancak hedef adlarında tek veya çift tırnak kullanırken dikkatli olun. Bir veya daha fazla hedef adı tırnak içine alırken yalnızca bir tür tırnak işareti kullanın (tüm tırnak işaretleri tek veya çift olmalıdır).

  Aşağıda, Java sorgu dizesinin ne olacağına ilişkin örnekler verilmiştir:

    'a"'a'         # WRONG: Error message: unclosed quotation.
    "a'"a"         # WRONG: Error message: unclosed quotation.
    '"a" + 'a''    # WRONG: Error message: unexpected token 'a' after query expression '"a" + '
    "'a' + "a""    # WRONG: Error message: unexpected token 'a' after query expression ''a' + '
    "a'a"          # OK.
    'a"a'          # OK.
    '"a" + "a"'    # OK
    "'a' + 'a'"    # OK
  

  Çoğu durumda tırnak işaretlerine gerek olmaması için bu söz dizimini seçtik. (Olağan dışı) ".*test rule" örneğinin tırnak içine alınması gerekir: Örnek bir noktayla başlar ve boşluk içerir. "cc_library" değerini tırnak içine almak gereksizdir ancak zararsızdır.

• Parantez (), nokta . ve virgül , gibi noktalama işaretleri. Noktalama işareti içeren kelimeler (yukarıda belirtilen istisnalar dışında) tırnak içine alınmalıdır.

Tırnak içine alınan kelimenin dışındaki boşluk karakterleri yoksayılır.

Bazel sorgu dili kavramları

Bazel sorgu dili, ifade dilidir. Her ifade, hedeflerin kısmen sıralı bir kümesi veya eşdeğer olarak hedeflerin bir grafiği (DAG) olarak değerlendirilir. Tek veri türü budur.

Set ve grafik aynı veri türüne işaret eder, ancak farklı yönlerini vurgulayın. Örneğin:

• Set: Hedeflerin kısmi sırası ilgi çekici değildir.
• Grafik: Hedeflerin kısmi sırası önemlidir.

Bağımlılık grafiğindeki döngüler

Derleme bağımlılığı grafikleri döngüsel olmamalıdır.

Sorgu dili tarafından kullanılan algoritmalar döngüsel grafiklerde kullanılmak üzere tasarlanmıştır ancak döngülere karşı dayanıklıdır. Döngülerin nasıl ele alındığına dair ayrıntılar belirtilmemiştir ve bunlara güvenilmemelidir.

Dolaylı bağımlılıklar

Bazel, BUILD dosyalarında açıkça tanımlanan derleme bağımlılıklarına ek olarak kurallara örtülü bağımlılıklar da ekler. Örneğin, her Java kuralı dolaylı olarak JavaBuilder'a bağlıdır. Örtük bağımlılıklar, $ ile başlayan özellikler kullanılarak oluşturulur ve BUILD dosyalarında geçersiz kılınamaz.

Varsayılan olarak bazel query, sorgu sonucunu hesaplarken örtülü bağımlılıkları dikkate alır. Bu davranış, --[no]implicit_deps seçeneğiyle değiştirilebilir. Sorgu yapılandırmaları dikkate almadığı için olası araç zincirlerinin hiçbir zaman dikkate alınmadığını unutmayın.

Sağlamlık

Bazel sorgu dili ifadeleri, tüm BUILD dosyalarındaki tüm kural beyanları tarafından dolaylı olarak tanımlanan grafik olan derleme bağımlılık grafiği üzerinde çalışır. Bu grafiğin biraz soyut olduğunu ve derleme adımlarının tümünün nasıl uygulanacağına dair tam bir açıklama içermediğini anlamak önemlidir. Derleme yapmak için yapılandırma da gereklidir. Daha fazla bilgi için Kullanıcı Kılavuzu'nun yapılandırmalar bölümüne bakın.

Bir ifadenin Bazel sorgu dilinde değerlendirilmesinin sonucu tüm yapılandırmalar için doğrudur. Bu, tam olarak kesin olmayan konservatif bir aşırı tahmin olabileceği anlamına gelir. Derleme sırasında gerekli olan tüm kaynak dosyaları kümesini hesaplamak için sorgu aracını kullanırsanız gerçekte gerekli olandan daha fazlasını raporlayabilir. Bunun nedeni, örneğin sorgu aracı, derlemenizde bu özelliği kullanmak istemeseniz bile mesaj çevirisini desteklemek için gereken tüm dosyaları içermesini sağlar.

Grafik sırasının korunması hakkında

İşlemler, alt ifadelerinden devralınan tüm sıralama kısıtlamalarını korur. Bunu "kısmi sıranın korunumu yasası" olarak düşünebilirsiniz. Bir örnek verelim: Belirli bir hedefin bağımlılıklarının geçişli kapatmasını belirlemek için bir sorgu gönderirseniz elde edilen küme, bağımlılık grafiğine göre sıralanır. Yalnızca file türündeki hedefleri içerecek şekilde ayarlanan bir filtre uygularsanız, elde edilen alt kümedeki her hedef çifti arasında aynı geçişli kısmi sıralama ilişkisi geçerlidir (bu çiftlerin hiçbiri aslında orijinal grafikte doğrudan bağlı olmasa bile). (Derleme bağımlılık grafiğinde dosya-dosya kenarı yoktur).

Ancak tüm operatörler sırayı korurken set işlemleri gibi bazı işlemler kendi sıralama kısıtlamalarını getirmez. Şu ifadeyi ele alalım:

deps(x) union y

Nihai sonuç kümesinin sırasının, alt ifadelerinin tüm sıralama kısıtlamalarını koruduğu garanti edilir. Yani x'ün tüm geçişli bağımlılıkları birbirine göre doğru şekilde sıralanır. Ancak sorgu, y'teki hedeflerin sıralaması veya deps(x)'teki hedeflerin y'teki hedeflere göre sıralaması hakkında hiçbir garanti vermez (y'teki ve deps(x)'teki hedeflerin aynı olması durumu hariç).

Sıralama kısıtlamaları getiren operatörler şunlardır: allpaths, deps, rdeps, somepath ve hedef desen joker karakterleri package:*, dir/... vb.

Gökyüzü sorgusu

Sky Query, belirli bir evren kapsam üzerinde çalışan bir sorgu modudur.

Yalnızca SkyQuery'de kullanılabilen özel işlevler

Sky Query modunda allrdeps ve rbuildfiles ek sorgu işlevleri bulunur. Bu işlevler, evren kapsamının tamamında çalışır (bu nedenle normal sorgu için anlamlı değildir).

Evren kapsamını belirtme

Gökyüzü sorgusu modu, aşağıdaki iki işaretin iletilmesi ile etkinleştirilir: (--universe_scope veya --infer_universe_scope) ve --order_output=no. --universe_scope=<target_pattern1>,...,<target_patternN>, sorguya hedef kalıplar tarafından belirtilen hedef kalıbın geçişli kapatmasını önceden yüklemesini söyler. Bu kapatma hem eklemeli hem de çıkartmalı olabilir. Daha sonra tüm sorgular bu "kapsama" göre değerlendirilir. Özellikle allrdeps ve rbuildfiles operatörleri yalnızca bu kapsamdaki sonuçları döndürür. --infer_universe_scope, Bazel'a sorgu ifadesinden --universe_scope için bir değer çıkarmasını söyler. Tahmin edilen bu değer, sorgu ifadesindeki benzersiz hedef kalıplarının listesidir ancak istediğiniz bu olmayabilir. Örneğin:

bazel query --infer_universe_scope --order_output=no "allrdeps(//my:target)"

Bu sorgu ifadesindeki benzersiz hedef kalıpların listesi ["//my:target"] olduğundan Bazel bunu çağrıyla aynı şekilde ele alır:

bazel query --universe_scope=//my:target --order_output=no "allrdeps(//my:target)"

Ancak --universe_scope ile yapılan bu sorgunun sonucu yalnızca //my:target olur. //my:target öğesinin ters bağımlılıklarının hiçbiri yapı gereği evrende yoktur. Diğer yandan, şunu da göz önünde bulundurun:

bazel query --infer_universe_scope --order_output=no "tests(//a/... + b/...) intersect allrdeps(siblings(rbuildfiles(my/starlark/file.bzl)))"

Bu, tanımı belirli bir .bzl dosyası kullanan hedeflere geçişli olarak bazı dizinler altındaki hedeflerin tests genişletmesinde test hedeflerini hesaplamaya çalışan anlamlı bir sorgu çağrısıdır. Burada --infer_universe_scope, özellikle --infer_universe_scope seçiminin sorgu ifadesini kendinizin ayrıştırmanızı gerektirdiği durumlarda kolaylık sağlar.

Bu nedenle, allrdeps ve rbuildfiles gibi evren kapsamlı operatörlerin kullanıldığı sorgu ifadeleri için --infer_universe_scope'yi yalnızca istediğiniz davranışı sağlıyorsa kullandığınızdan emin olun.

Sky Query, varsayılan sorguya kıyasla bazı avantajlara ve dezavantajlara sahiptir. Ana dezavantajı, çıktısını grafik sırasına göre sıralayamaması ve bu nedenle belirli çıktı biçimlerinin yasaklanmasıdır. Bunun avantajları, varsayılan sorguda kullanılamayan iki operatör (allrdeps ve rbuildfiles) sağlamasıdır. Ayrıca Sky Query, varsayılan uygulamanın yaptığı yeni bir grafik oluşturmak yerine Skyframe grafiğini inceleyerek işini gerçekleştirir. Bu nedenle, daha hızlı ve daha az bellek kullandığı bazı durumlar vardır.

İfadeler: Dil bilgisinin söz dizimi ve semantiği

Bu, Bazel sorgu dilinin EBNF notasyonuyla ifade edilen dil bilgisidir:

expr ::= word
       | let name = expr in expr
       | (expr)
       | expr intersect expr
       | expr ^ expr
       | expr union expr
       | expr + expr
       | expr except expr
       | expr - expr
       | set(word *)
       | word '(' int | word | expr ... ')'

Aşağıdaki bölümlerde bu dilbilgisinin tüm üretimleri sırayla açıklanmaktadır.

Hedef kalıpları

expr ::= word

Söz dizimi açısından, hedef desen yalnızca bir kelimedir. Bu, bir (sıralı olmayan) hedef grubu olarak yorumlanır. En basit hedef kalıbı, tek bir hedefi (dosya veya kural) tanımlayan bir etikettir. Örneğin, //foo:bar hedef kalıbı bir öğe, hedef ve bar kuralını içeren bir küme olarak değerlendirilir.

Hedef kalıpları, paketler ve hedefler yerine joker karakterleri içerecek şekilde etiketleri genelleştirir. Örneğin, foo/...:all (veya yalnızca foo/...), foo dizininin altında bulunan her paketteki tüm kuralları yinelemeli olarak içeren bir küme olarak değerlendirilen bir hedef kalıptır. bar/baz:all, bar/baz paketindeki tüm kuralları içeren ancak alt paketlerini içermeyen bir küme olarak değerlendiren bir hedef kalıptır.

Benzer şekilde foo/...:*, foo dizininin altında bulunan her paketteki tüm hedefleri (kurallar ve dosyaları) içeren bir küme olarak değerlendirilen bir hedef kalıptır. bar/baz:* ise bar/baz paketindeki tüm hedefleri içeren ancak alt paketlerini içermeyen bir küme olarak değerlendirilir.

:* joker karakteri, kuralların yanı sıra dosyalarla da eşleştiğinden genellikle sorgular için :all'ten daha kullanışlıdır. Buna karşılık, :all joker karakteri (foo/... gibi hedef kalıplarda örtülü), genellikle derlemeler için daha yararlıdır.

bazel query hedef kalıpları, bazel build derleme hedeflerinin çalışmalarıyla aynı şekilde çalışır. Daha ayrıntılı bilgi için Hedef Kalıplar'a bakın veya bazel help target-syntax yazın.

Hedef kalıpları, bir tekil küme (etiket söz konusu olduğunda), çok sayıda öğe içeren bir küme (binlerce öğesi olan foo/...'de olduğu gibi) ya da hedef kalıp hiçbir hedefle eşleşmiyorsa boş küme olarak değerlendirilebilir.

Bir hedef kalıbı ifadesinin sonucundaki tüm düğümler, bağımlılık ilişkisine göre birbirine göre doğru şekilde sıralanır. Dolayısıyla, foo:* sonucu yalnızca foo paketindeki hedef kümesi değil, aynı zamanda bu hedeflerin grafiği de olur. (Sonuç düğümlerinin diğer düğümlere göre göreli sıralaması hakkında herhangi bir garanti verilmez.) Daha fazla bilgi için grafik sırası bölümüne bakın.

Değişkenler

expr ::= let name = expr1 in expr2
       | $name

Bazel sorgu dili, değişkenlerin tanımlanmasına ve değişkenlere referans verilmesine olanak tanır. Bir let ifadesinin değerlendirilmesinin sonucu, expr₂ ifadesinin sonuçlarıyla aynıdır. name değişkeninin tüm ücretsiz tekrarları, expr₁ değeriyle değiştirilir.

Örneğin let v = foo/... in allpaths($v, //common) intersect $v, allpaths(foo/...,//common) intersect foo/... ile eşdeğerdir.

name değişken referansının, kapsayıcı let name = ... ifadesi dışında kullanılması hatadır. Diğer bir deyişle, üst düzey sorgu ifadelerinde serbest değişkenler olamaz.

Yukarıdaki dil bilgisi üretimlerinde name, kelime gibidir ancak C programlama dilinde yasal bir tanımlayıcı olması ek kısıtlaması vardır. Değişken referanslarına "$" karakteri eklenmelidir.

Her let ifadesi yalnızca tek bir değişkeni tanımlar, ancak bunları iç içe yerleştirebilirsiniz.

Hem hedef kalıplar hem de değişken referansları yalnızca tek bir jetondan (kelime) oluştuğu için söz dizimi belirsizliği oluşturur. Ancak, yasal değişken adları olan kelime alt kümesi, yasal hedef kalıpları olan kelime alt kümesinden ayrı olduğundan anlamsal belirsizlik yoktur.

Teknik olarak, let ifadeleri sorgu dilinin ifade gücünü artırmaz: Dilde ifade edilebilen tüm sorgular bunlar olmadan da ifade edilebilir. Ancak, birçok sorgunun daha kısa ve öz olmasını sağlar ve sorgu değerlendirmesinin daha verimli olmasını sağlayabilir.

Parantez içine alınmış ifadeler

expr ::= (expr)

Parantezler, değerlendirme sırasını zorlamak için alt ifadeleri ilişkilendirir. Parantez içindeki bir ifade, bağımsız değişkeninin değerini değerlendirir.

Cebirsel küme işlemleri: kesişim, birleştirme, küme farkı

expr ::= expr intersect expr
       | expr ^ expr
       | expr union expr
       | expr + expr
       | expr except expr
       | expr - expr

Bu üç operatör, bağımsız değişkenleri yerine normal set işlemlerini hesaplar. Her operatörün iki biçimi vardır: intersect gibi nominal bir biçim ve ^ gibi sembolik bir biçim. Her iki biçim de eşdeğerdir; sembolik biçimler daha hızlı yazılır. (Daha net bir ifadeyle, bu sayfanın geri kalanında nominal formlar kullanılmaktadır.)

Örneğin,

foo/... except foo/bar/...

foo/... ile eşleşen, ancak foo/bar/... ile eşleşmeyen hedef kümesini değerlendirir.

Aynı sorguyu şu şekilde yazabilirsiniz:

foo/... - foo/bar/...

intersect (^) ve union (+) işlemleri değişmeli (simetrik) olup except (-) asimetriktir. Ayrıştırıcı, üç operatörü de sol-ilişkili ve eşit öncelikli olarak ele aldığından parantez isteyebilirsiniz. Örneğin, bu ifadelerden ilk ikisi eşdeğerdir ancak üçüncüsü eşdeğer değildir:

x intersect y union z
(x intersect y) union z
x intersect (y union z)

Önemli: Sorgu ifadesini okurken belirsizlik tehlikesi bulunan yerlerde parantez kullanın.

Harici bir kaynaktan hedefleri okuma: ayarlandı

expr ::= set(word *)

set(a b c ...) operatörü, boşlukla (virgül olmadan) ayrılmış sıfır veya daha fazla hedef kalıptan oluşan bir grubun birleşimini hesaplar.

Bourne kabuğunun $(...) özelliğiyle birlikte set(), bir sorgunun sonuçlarını normal bir metin dosyasına kaydetme, bu metin dosyasını diğer programlar (standart UNIX kabuk araçları gibi) kullanarak değiştirme ve ardından sonucu daha fazla işleme için bir değer olarak sorgu aracına geri getirme olanağı sağlar. Örneğin:

bazel query deps(//my:target) --output=label | grep ... | sed ... | awk ... > foo
bazel query "kind(cc_binary, set($(<foo)))"

Aşağıdaki örnekte, kind(cc_library, deps(//some_dir/foo:main, 5)), awk programı kullanılarak maxrank değerlerine göre filtrelenerek hesaplanır.

bazel query 'deps(//some_dir/foo:main)' --output maxrank | awk '($1 < 5) { print $2;} ' > foo
bazel query "kind(cc_library, set($(<foo)))"

Bu örneklerde $(<foo), $(cat foo) ifadesinin kısaltmasıdır ancak önceki awk komutu gibi cat dışındaki kabuk komutları da kullanılabilir.

Not: set(), grafik sıralama kısıtlaması getirmez. Bu nedenle, set() kullanılarak kaydedilen ve yeniden yüklenen düğüm kümeleri için yol bilgileri kaybolabilir. Daha fazla bilgi için aşağıdaki grafik sırası bölümüne bakın.

İşlevler

expr ::= word '(' int | word | expr ... ')'

Sorgu dili çeşitli işlevler tanımlar. İşlevin adı, gerektirdiği bağımsız değişkenlerin sayısını ve türünü belirler. Aşağıdaki işlevler kullanılabilir:

• allpaths
• attr
• buildfiles
• rbuildfiles
• deps
• filter
• kind
• labels
• loadfiles
• rdeps
• allrdeps
• same_pkg_direct_rdeps
• siblings
• some
• somepath
• tests
• visible

Bağımlılıkların geçişli kapatması: deps

expr ::= deps(expr)
       | deps(expr, depth)

deps(x) operatörü, bağımsız değişken kümesi x'ün bağımlılıkları için geçişli kapatma işlemiyle oluşturulan grafiği değerlendirir. Örneğin, deps(//foo) değeri, tüm bağımlılıkları dahil olmak üzere foo tek düğümüne dayanan bağımlılık grafiğidir. deps(foo/...) değeri, kökleri foo dizininin altındaki her pakette bulunan tüm kurallar olan bağımlılık grafikleridir. Bu bağlamda "bağımlılıklar" yalnızca kural ve dosya hedefleri anlamına gelir. Dolayısıyla bu hedefleri oluşturmak için gereken BUILD ve Starlark dosyaları buraya dahil edilmemiştir. Bunun için buildfiles operatörünü kullanmanız gerekir.

Ortaya çıkan grafik, bağımlılık ilişkisine göre sıralanır. Ayrıntılı bilgi için grafik sırası bölümüne bakın.

deps operatörü, aramanın derinliği için üst sınırı belirten tam sayı olan isteğe bağlı ikinci bağımsız değişkeni kabul eder. Dolayısıyla deps(foo:*, 0), foo paketindeki tüm hedefleri döndürürken deps(foo:*, 1) ayrıca foo paketindeki herhangi bir hedefin doğrudan ön koşullarını içerir ve deps(foo:*, 2) ayrıca deps(foo:*, 1) içindeki düğümlerden doğrudan erişilebilen düğümleri içerir. (Bu sayılar, minrank çıkış biçiminde gösterilen sıralamalara karşılık gelir.) depth parametresi atlanırsa arama sınırsızdır: ön koşulların yansıtmalı geçişli kapatmasını hesaplar.

Ters bağımlılıkların geçişli kapatması: rdeps

expr ::= rdeps(expr, expr)
       | rdeps(expr, expr, depth)

rdeps(u, x) operatörü, u evren kümesinin geçişli kapatma kümesi içinde x bağımsız değişken kümesinin ters bağımlılıkları olarak değerlendirilir.

Ortaya çıkan grafik, bağımlılık ilişkisine göre sıralanır. Daha fazla bilgi için grafik sırası bölümüne bakın.

rdeps operatörü, aramanın derinliği için üst sınırı belirten tam sayı olan isteğe bağlı üçüncü bağımsız değişkeni kabul eder. Sonuçta ortaya çıkan grafik, yalnızca bağımsız değişken grubundaki herhangi bir düğümden belirtilen derinliğe kadar olan mesafedeki düğümleri içerir. Dolayısıyla rdeps(//foo, //common, 1), //foo'un geçişli kapatmasında doğrudan //common'ye bağlı olan tüm düğümler olarak değerlendirilir. (Bu sayılar, minrank çıkış biçiminde gösterilen sıralamalara karşılık gelir.) depth parametresi atlanırsa arama sınırsızdır.

Tüm ters bağımlılıkların geçişli kapatması: allrdeps

expr ::= allrdeps(expr)
       | allrdeps(expr, depth)

Not: Yalnızca Sky Query

ile kullanılabilir

allrdeps operatörü, rdeps operatörü gibi davranır. Tek fark "evren grubu"nun ayrı olarak belirtilmeyip --universe_scope işaretinin değerlendirildiği değer olmasıdır. Bu nedenle, --universe_scope=//foo/... geçildiyse allrdeps(//bar), rdeps(//foo/..., //bar) ile eşdeğerdir.

Aynı paketteki doğrudan ters bağımlılıklar: Aynı_pkg_direct_rdeps

expr ::= same_pkg_direct_rdeps(expr)

same_pkg_direct_rdeps(x) operatörü, bağımsız değişken grubundaki bir hedefle aynı pakette bulunan ve doğrudan ona bağlı olan tüm hedef kümesini değerlendirir.

Bir hedefin paketiyle başa çıkma: kardeşler

expr ::= siblings(expr)

siblings(x) operatörü, bağımsız değişken grubundaki bir hedefle aynı pakette bulunan tüm hedef grubunu değerlendirir.

Rastgele seçim: bazı

expr ::= some(expr)
       | some(expr, count )

some(x, k) operatörü, bağımsız değişken kümesi x'den rastgele en fazla k hedef seçer ve yalnızca bu hedefleri içeren bir küme olarak değerlendirilir. k parametresi isteğe bağlıdır; eksikse sonuç, rastgele seçilen yalnızca bir hedef içeren tek bir küme olur. x bağımsız değişken grubunun boyutu k değerinden küçükse x bağımsız değişken kümesinin tamamı döndürülür.

Örneğin, some(//foo:main union //bar:baz) ifadesi //foo:main veya //bar:baz değerini içeren tek öğeli bir küme olarak değerlendirilir. Ancak hangi değer olduğu tanımlanmaz. some(//foo:main union //bar:baz, 2) veya some(//foo:main union //bar:baz, 3) ifadesi hem //foo:main hem de //bar:baz değerini döndürür.

Bağımsız değişken tekil ise some, kimlik işlevini hesaplar: some(//foo:main), //foo:main ile eşdeğerdir.

Belirtilen bağımsız değişken grubu boşsa (some(//foo:main intersect //bar:baz) ifadesinde olduğu gibi) hata oluşur.

Yol operatörleri: somepath, allpaths

expr ::= somepath(expr, expr)
       | allpaths(expr, expr)

somepath(S, E) ve allpaths(S, E) operatörleri, iki hedef grubu arasındaki yolları hesaplar. Her iki sorgu da iki bağımsız değişkeni kabul eder: bir başlangıç noktası S grubu ve bir bitiş noktası E grubu. somepath, S'daki bir hedeften E'daki bir hedefe giden belirli bir yoldaki düğümlerin grafiğini döndürür; allpaths ise S'daki herhangi bir hedeften E'daki herhangi bir hedefe giden tüm yollardaki düğümlerin grafiğini döndürür.

Elde edilen grafikler bağımlılık ilişkisine göre sıralanır. Daha ayrıntılı bilgi için grafik sırası ile ilgili bölüme bakın.

somepath(S1 + S2, E), bir olası sonuç.

somepath(S1 + S2, E), olası bir başka sonuçtur.

allpaths(S1 + S2, E)

Hedef türü filtreleme: kind

expr ::= kind(word, expr)

kind(pattern, input) operatörü, bir hedef grubuna filtre uygular ve beklenen türde olmayan hedefleri atar. pattern parametresi, eşlenecek hedefin türünü belirtir.

Örneğin, aşağıda gösterilen BUILD dosyası (p paketi için) tarafından tanımlanan dört hedefin türleri tabloda gösterilmiştir:

Kod	Hedef	Tür
genrule( name = "a", srcs = ["a.in"], outs = ["a.out"], cmd = "...", )	//p:a	genrule kuralı
	//p:a.in	kaynak dosya
	//p:a.out	oluşturulmuş dosya
	//p:BUILD	kaynak dosya

Bu nedenle, kind("cc_.* rule", foo/...), foo altındaki tüm cc_library, cc_binary vb. kural hedeflerinin kümesini, kind("source file", deps(//foo)) ise //foo hedefinin bağımlılıkların geçişli kapatma kümesinde bulunan tüm kaynak dosyalarının kümesini değerlendirir.

pattern bağımsız değişkeninin tırnak işareti kullanımı, bu bağımsız değişkenin ayrıştırıcı tarafından kelime olarak kabul edilmediği source file ve .*_test gibi birçok normal ifade olmadığı için çoğu zaman gereklidir.

package group ile eşleştirme yaparken :all ile biten hedefler hiçbir sonuç vermeyebilir. Bunun yerine :all-targets politikasını kullanın.

Hedef adı filtreleme: filtre

expr ::= filter(word, expr)

filter(pattern, input) operatörü, bir hedef grubuna filtre uygular ve etiketleri (mutlak biçimde) kalıpla eşleşmeyen hedefleri atar. Bu operatör, girişinin bir alt kümesi olarak değerlendirilir.

İlk bağımsız değişken pattern, hedef adlar üzerinde bir normal ifade içeren bir kelimedir. Bir filter ifadesi, x input kümesinin bir üyesi olacak şekilde tüm x hedeflerini içeren küme olarak değerlendirilir ve x etiketi (//foo:bar gibi mutlak biçimde), normal ifade pattern için bir (sabitlenmemiş) eşleşme içerir. Tüm hedef adlar // ile başladığından // normal ifade ankrasına alternatif olarak kullanılabilir.

Bu operatör genellikle intersect operatörüne kıyasla çok daha hızlı ve daha güçlü bir alternatif sunar. Örneğin, //foo:foo hedefinin tüm bar bağımlılıklarını görmek için şunları değerlendirebilirsiniz:

deps(//foo) intersect //bar/...

Ancak bu ifade, bar ağacındaki tüm BUILD dosyalarının ayrıştırılmasını gerektirir. Bu işlem yavaştır ve alakasız BUILD dosyalarında hatalara açıktır. Bir alternatif şöyle olabilir:

filter(//bar, deps(//foo))

Bu işlev, önce //foo bağımlılıklarını hesaplar ve ardından yalnızca sağlanan kalıpla eşleşen hedefleri (yani adlarında alt dize olarak //bar içeren hedefleri) filtreler.

filter(pattern, expr) operatörünün yaygın olarak kullanılan bir diğer işlevi, belirli dosyaları adlarına veya uzantılarına göre filtrelemektir. Örneğin,

filter("\.cc$", deps(//foo))

//foo öğesini oluşturmak için kullanılan tüm .cc dosyalarının bir listesini sağlar.

Kural özelliği filtreleme: attr

expr ::= attr(word, word, expr)

attr(name, pattern, input) operatörü, bir dizi hedefe filtre uygular ve kural olmayan hedefleri, name özelliğinin tanımlı olmadığı kural hedeflerini veya özellik değerinin sağlanan normal ifadeyle pattern eşleşmediği kural hedeflerini siler. Girişin bir alt kümesini değerlendirir.

İlk bağımsız değişken olan name, sağlanan normal ifade kalıbıyla eşleştirilmesi gereken kural özelliğinin adıdır. İkinci bağımsız değişken pattern, özellik değerleri için bir düzenli ifadedir. Bir attr ifadesi, tüm hedefleri içeren bir küme olarak değerlendirilir. Burada x, input grubunun üyesi, name olarak tanımlanan name özelliğine sahip bir kural ve özellik değeri pattern normal ifadesi için (bağlanmamış) eşleşme içerir.x name isteğe bağlı bir özellikse ve kuralda açıkça belirtilmezse karşılaştırma için varsayılan özellik değeri kullanılır. Örneğin,

attr(linkshared, 0, deps(//foo))

linkshared özelliğine sahip olmasına izin verilen tüm //foo bağımlılıkları (cc_binary kuralı gibi) seçer ve bu özelliği açıkça 0 olarak ayarlar veya hiç ayarlamaz ancak varsayılan değer 0 olur (cc_binary kuralları için olduğu gibi).

Liste türündeki özellikler (ör. srcs, data vb.), [ parantezle başlayıp ] parantezle biten ve birden fazla değeri sınırlamak için "," (virgül, boşluk) kullanılarak [value<sub>1</sub>, ..., value<sub>n</sub>] biçimindeki dizelere dönüştürülür. Etiketler, etiketin mutlak biçimi kullanılarak dizelere dönüştürülür. Örneğin, deps=[":foo", "//otherpkg:bar", "wiz"] özelliği [//thispkg:foo, //otherpkg:bar, //thispkg:wiz] dize dönüştürülür. Köşeli parantezler her zaman mevcuttur. Bu nedenle, boş listede eşleştirme amacıyla [] dize değeri kullanılır. Örneğin,

attr("srcs", "\[\]", deps(//foo))

boş bir srcs özelliğine sahip //foo bağımlılık arasındaki tüm kuralları seçerken

attr("data", ".{3,}", deps(//foo))

//foo bağımlılıkları arasından data özelliğinde en az bir değer belirten tüm kuralları seçer (// ve : nedeniyle her etiket en az 3 karakter uzunluğundadır).

Liste türü özelliğinde belirli bir value içeren //foo bağımlılıkları arasındaki tüm kuralları seçmek için şunu kullanın:

attr("tags", "[\[ ]value[,\]]", deps(//foo))

Bu, value karakterinden önceki karakterin [ veya boşluk, value karakterinden sonraki karakterin ise virgül veya ] olması nedeniyle işe yarar.

Kural görünürlüğü filtreleme: görünür

expr ::= visible(expr, expr)

visible(predicate, input) operatörü, bir dizi hedefe filtre uygular ve gerekli görünürlüğe sahip olmayan hedefleri siler.

Birinci bağımsız değişken olan predicate, çıkıştaki tüm hedeflerin görünür olması gereken bir hedef grubudur. Bir visible ifadesi, tüm x hedeflerini içeren kümeye değerlendirilir. Böylelikle x, grubunun üyesi olur ve x predicate içindeki tüm hedefler y, y tarafından görülebilir.input Örneğin:

visible(//foo, //bar:*)

//bar paketindeki //foo'ın görünürlük kısıtlamalarını ihlal etmeden bağımlı olabileceği tüm hedefleri seçer.

Etiket türü kural özelliklerinin değerlendirilmesi: etiketler

expr ::= labels(word, expr)

labels(attr_name, inputs) operatörü, inputs kümesindeki bir kuraldaki "etiket" veya "etiket listesi" türündeki attr_name özelliğinde belirtilen hedef grubunu döndürür.

Örneğin labels(srcs, //foo), //foo kuralının srcs özelliğinde görünen hedef grubunu döndürür. inputs kümesinde srcs özelliğine sahip birden fazla kural varsa bu kuralların srcs özelliğinin birleşimi döndürülür.

test_suites: testleri genişletip filtrele

expr ::= tests(expr)

tests(x) operatörü, x grubundaki tüm test kurallarının grubunu döndürür, tüm test_suite kurallarını atıfta bulundukları bağımsız testler grubuna genişletir ve tag ve size'e göre filtreleme uygular.

Sorgu değerlendirme, varsayılan olarak test_suite kurallarındaki test dışı hedefleri yoksayar. Bu, --strict_test_suite seçeneğiyle hata olarak değiştirilebilir.

Örneğin, kind(test, foo:*) sorgusu foo paketindeki tüm *_test ve test_suite kurallarını listeler. Tüm sonuçlar (tanım olarak) foo paketinin üyeleridir. Buna karşılık, tests(foo:*) sorgusu bazel test foo:* tarafından yürütülecek tüm bağımsız testleri döndürür: Bu, test_suite kuralları aracılığıyla doğrudan veya dolaylı olarak referans verilen, diğer paketlere ait testleri içerebilir.

Paket tanımı dosyaları: buildfiles

expr ::= buildfiles(expr)

buildfiles(x) operatörü, x kümesinde her bir hedefin paketlerini tanımlayan dosya kümesini döndürür. Diğer bir deyişle, her paket için BUILD dosyası ve load aracılığıyla referans verdiği tüm .bzl dosyaları döndürülür. Bu işlemin, bu load ed dosyalarını içeren paketlerin BUILD dosyalarını da döndürdüğünü unutmayın.

Bu operatör genellikle belirli bir hedefi oluşturmak için hangi dosyaların veya paketlerin gerekli olduğunu belirlerken ve genellikle aşağıdaki --output package seçeneğiyle birlikte kullanılır. Örneğin,

bazel query 'buildfiles(deps(//foo))' --output package

//foo öğesinin geçişli olarak bağlı olduğu tüm paketlerin grubunu döndürür.

Not: Yukarıdaki sorguda buildfiles operatörü atlanır ve yalnızca deps kullanılırsa yanlış bir sonuç elde edilir: Sonuç, gerekli paketlerin çoğunu içerir ancak yalnızca load()'lenmiş dosyaları içeren paketler eksik olur.

Uyarı: Bazel, buildfiles tarafından üretilen her .bzl dosyasının karşılık gelen bir hedefe sahip olduğunu varsayar (örneğin, dosya a/b.bzl => hedef //a:b.bzl), ancak bu her zaman doğru olmayabilir. Bu nedenle, buildfiles diğer sorgu operatörleriyle iyi uyum sağlamaz ve bunun sonuçları, [--output=xml](#output-xml) gibi yapılandırılmış bir şekilde biçimlendirildiğinde yanıltıcı olabilir.

Paket tanımı dosyaları: rbuildfiles

expr ::= rbuildfiles(word, ...)

Not: Yalnızca Sky Query ile kullanılabilir.

rbuildfiles operatörü, virgülle ayrılmış bir yol parçası listesi alır ve bu yol parçalarına geçişli olarak bağlı olan BUILD dosyası grubunu döndürür. Örneğin, //foo bir paketse rbuildfiles(foo/BUILD), //foo:BUILD hedefini döndürür. foo/BUILD dosyasında load('//bar:file.bzl'... varsa rbuildfiles(bar/file.bzl), //foo:BUILD hedefini ve //bar:file.bzl yükleyen diğer BUILD dosyalarının hedeflerini döndürür.

rbuildfiles operatörünün kapsamı, --universe_scope işaretçisi tarafından belirtilen evrendir. Doğrudan BUILD dosyalarına ve .bzl dosyalarına karşılık gelmeyen dosyalar sonuçları etkilemez. Örneğin, BUILD dosyasında açıkça belirtilmiş olsalar bile kaynak dosyalar (foo.cc gibi) yoksayılır. Ancak simge bağlantılarına saygı duyulur. Bu nedenle, foo/BUILD bar/BUILD'a giden bir simge bağlantısıysa rbuildfiles(bar/BUILD), sonuçlarına //foo:BUILD'ı ekler.

rbuildfiles operatörü, buildfiles operatörünün neredeyse ahlaki olarak tersidir. Ancak bu ahlaki ters çevirme, bir yönde daha güçlüdür: rbuildfiles'ün çıkışları buildfiles'ün girişlerine benzer; önceki yalnızca paketlerde BUILD dosya hedefleri içerir ve ikincisi bu tür hedefler içerebilir. Diğer yönde ise bu ilişki daha zayıftır. buildfiles operatörünün çıkışları, tüm paketlere ve .bzl dosyası gerekiyor. Bununla birlikte, rbuildfiles operatörünün girişleri bu hedefler değil, bu hedeflere karşılık gelen yol parçalarıdır.

Paket tanımı dosyaları: loadfiles

expr ::= loadfiles(expr)

loadfiles(x) operatörü, x kümesindeki her hedefin paketini yüklemek için gereken Starlark dosyaları kümesini döndürür. Diğer bir deyişle, her paket için BUILD dosyalarından referans verilen .bzl dosyalarını döndürür.

Uyarı: Bazel, bu .bzl dosyalarının her birine karşılık gelen bir hedef (örneğin, a/b.bzl => hedef //a:b.bzl) olduğunu iddia eder, ancak bu zorunlu değildir. Bu nedenle, loadfiles diğer sorgu operatörleriyle iyi bir şekilde birleşmez ve sonuçları [--output=xml](#output-xml) gibi yapılandırılmış bir şekilde biçimlendirildiğinde yanıltıcı olabilir.

Çıkış biçimleri

bazel query bir grafik oluşturur. bazel query tarafından bu grafiği sunmak için kullanılan içeriği, biçimi ve sıralamayı --output komut satırı seçeneğini kullanarak belirtirsiniz.

Sky Query ile çalıştırıldığında yalnızca sırasız çıkışla uyumlu çıkış biçimlerine izin verilir. Özellikle graph, minrank ve maxrank çıkış biçimleri yasaktır.

Çıkış biçimlerinden bazıları ek seçenekleri kabul eder. Her çıkış seçeneğinin adı, geçerli olduğu çıkış biçimiyle başlar. Bu nedenle --graph:factored yalnızca --output=graph kullanıldığında geçerli olur; graph dışında bir çıkış biçimi kullanıldığında etkisi yoktur. Benzer şekilde, --xml:line_numbers yalnızca --output=xml kullanılırken geçerlidir.

Sonuçların sıralaması

Sorgu ifadeleri her zaman "grafik sırasının korunması yasası"na uysa da sonuçların sunulması, bağımlılık sırasına göre veya sırasız olarak yapılabilir. Bu durum, sonuç kümesindeki hedefleri veya sorgunun nasıl hesaplanacağını etkilemez. Yalnızca sonuçların stdout'a nasıl yazdırıldığını etkiler. Ayrıca, bağımlılık sırasında eşdeğer olan düğümler alfabetik olarak sıralanabilir veya sıralanmayabilir. Bu davranışı kontrol etmek için --order_output işareti kullanılabilir. (--[no]order_results işareti, --order_output işaretinin işlevlerinin bir alt kümesini içerir ve desteği sonlandırılmıştır.)

Bu işaretin varsayılan değeri auto şeklindedir ve sonuçları sözlüksel sıralama ile yazdırır. Ancak somepath(a,b) kullanıldığında sonuçlar deps sırasına göre yazdırılır.

Bu işaret no olduğunda ve --output build, label, label_kind, location, package, proto veya xml arasından biri olduğunda çıkışlar rastgele sırayla yazdırılır. Bu genellikle en hızlı seçenektir. Ancak --output, graph, minrank veya maxrank arasından biri olduğunda desteklenmez: Bu biçimlerde Bazel, sonuçları her zaman bağımlılık sırasına veya sıralamaya göre yazdırır.

Bu işaret deps olduğunda Bazel baskıları bir topolojik sıralamayla, yani bağımlılıklarla başlar. Ancak bağımlılık sırasına göre sıralandırılmayan düğümler (birinden diğerine yol olmadığı için) herhangi bir sırada basılabilir.

Bu işaret full olduğunda Bazel, düğümleri tamamen deterministik (toplam) sırayla yazdırır. Öncelikle tüm düğümler alfabetik olarak sıralanır. Ardından, listedeki her düğüm, ziyaret edilmeyen düğümlere giden giden kenarların, halef düğümlerin alfabetik sırasına göre taranacağı bir sondan önce derinlik aramasının başlangıcı olarak kullanılır. Son olarak, düğümler ziyaret edildikleri sıranın tersi yönde yazdırılır.

Düğümleri bu sırada yazdırma işlemi daha yavaş olabilir. Bu nedenle, yalnızca determinizm önemli olduğunda kullanılmalıdır.

Hedeflerin kaynak biçimini BUILD'da görünecekleri şekilde yazdırın

--output build

Bu seçenekle her bir hedef, BUILD dilinde elle yazılmış gibi görünür. Tüm değişkenler ve işlev çağrıları (glob, makrolar gibi) genişletilir. Bu, Starlark makrolarının etkisini görmek açısından yararlıdır. Ayrıca her etkili kural, bir generator_name ve/veya generator_function) değeri bildirir ve etkili kuralı oluşturmak için değerlendirilen makronun adını verir.

Çıktı, BUILD dosyalarıyla aynı söz dizimini kullansa da geçerli bir BUILD dosyası oluşturması garanti edilmez.

Her hedefin etiketini yazdır

--output label

Bu seçenekle, elde edilen grafikteki her bir hedefin ad (veya etiket) grubu, topolojik sırayla her satıra bir etiket gelecek şekilde yazdırılır (--noorder_results belirtilmediği sürece sonuçların sıralamasıyla ilgili notlara bakın). (Topolojik sıralama, bir grafik düğümünün tüm haleflerinden önce göründüğü sıralamadır.) Elbette bir grafiğin birçok topolojik sıralaması vardır (ters sondan önce bunlardan yalnızca biridir). Hangisinin seçildiği belirtilmez.

somepath sorgusunun çıkışını yazdırırken düğümlerin yazdırılma sırası, yolun sırasıdır.

Uyarı: Bazı durumlarda, aynı etikete sahip iki farklı hedef olabilir. Örneğin, bir sh_binary kuralı ve tek (dolaylı) srcs dosyası foo.sh olarak çağrılabilir. Bir sorgunun sonucu bu hedeflerin ikisini de içeriyorsa çıkış (label biçiminde) bir kopya içeriyormuş gibi görünür. label_kind (aşağıya bakın) biçimi kullanılırken fark netleşir: İki hedef aynı ada sahiptir ancak birinin türü sh_binary rule, diğer türü ise source file olacaktır.

Her hedefin etiketini ve türünü yazdırma

--output label_kind

label gibi bu çıkış biçimi de sonuçta elde edilen grafikteki her hedefin etiketlerini topolojik sırayla yazdırır ancak etiketten önce hedefin türünü de ekler.

Hedefleri protokol arabelleği biçiminde yazdır

--output proto

Sorgu çıkışını QueryResult protokol arabelleği olarak yazdırır.

Hedefleri uzunlukla sınırlandırılmış protokol arabelleği biçiminde yazdır

--output streamed_proto

Target protokol arabelleklerinden oluşan uzunlukla sınırlanmış bir akış yazdırır. Bu, (i) tek bir QueryResult'e sığmayacak kadar çok hedef olduğunda protokol arabelleklerinin boyut sınırlamalarını aşmak veya (ii) Bazel hâlâ çıkış verirken işlemeyi başlatmak için kullanışlıdır.

Hedefleri metin protokolü biçiminde yazdır

--output textproto

--output proto'e benzer şekilde, QueryResult protokol arabelleğini metin biçiminde yazdırır.

Hedefleri ndjson biçiminde yazdırma

--output streamed_jsonproto

--output streamed_proto işlevine benzer şekilde, Target protokol arabelleklerinden oluşan bir akışı ndjson biçiminde yazdırır.

Her hedefin etiketini, sıraya göre yazdırma

--output minrank --output maxrank

label gibi, minrank ve maxrank çıkış biçimleri de elde edilen grafikte her hedefin etiketlerini yazdırır. Ancak bu etiketler topolojik sırada görünmek yerine sıralama numarasından önce gelen sırada görünür. Bunlar, sonuç sıralama --[no]order_results işaretinden etkilenmez (sonuçların sıralanmasıyla ilgili notlara bakın).

Bu biçimin iki varyantı vardır: minrank her düğümü bir kök düğümden kendisine giden en kısa yolun uzunluğuna göre sıralar. "Kök" düğümler (gelen kenarı olmayanlar) 0. sıradadır, halefleri 1. sıradadır vb. (Kenarlar her zaman bir hedeften ön koşullarına, yani bağlı olduğu hedeflere işaret eder.)

maxrank her düğümü, bir kök düğümden ona giden en uzun yolun uzunluğuna göre sıralar. Yine, "kökler" 0 sırasına sahiptir, diğer tüm düğümler ise önceki tüm düğümlerin maksimum sırasından bir fazla sıraya sahiptir.

Bir döngüdeki tüm düğümler eşit rütbeye sahiptir. (Çoğu grafik döngüsel değildir ancak döngüler, BUILD dosyalarında hatalı döngüler bulunduğu için oluşur.)

Bu çıkış biçimleri, bir grafiğin ne kadar derin olduğunu keşfetmek için kullanışlıdır. deps(x), rdeps(x) veya allpaths sorgusunun sonucu için kullanılırsa sıra numarası, x'ten bu sıradaki bir düğüme giden en kısa (minrank ile) veya en uzun (maxrank ile) yolun uzunluğuna eşittir. maxrank, bir hedef oluşturmak için gereken en uzun derleme adımı dizisini belirlemek amacıyla kullanılabilir.

Not: somepath, en kısa veya en uzun yolu döndürmeyi garanti etmediği ve bir yol düğümünden diğerine orijinal grafikte doğrudan olmayan "geçiş" kenarları içerebileceği için somepath sorgusunun sıralanmış çıkışı temelde anlamsızdır.

Örneğin, soldaki grafikte sırasıyla --output minrank ve --output maxrank belirtildiğinde sağdaki çıkışlar elde edilir.

minrank 0 //c:c 1 //b:b 1 //a:a 2 //b:b.cc 2 //a:a.cc

maxrank 0 //c:c 1 //b:b 2 //a:a 2 //b:b.cc 3 //a:a.cc

Her hedefin konumunu yazdırma

--output location

label_kind gibi bu seçenek de sonuçtaki her hedef için hedefin türünü ve etiketini yazdırır ancak bu hedefin konumunu açıklayan bir dize (dosya adı ve satır numarası olarak) ön ek olarak eklenir. Biçim, grep işlevinin çıktısına benzer. Böylece, ikincisini (Emacs veya vi gibi) ayrıştırabilen araçlar, bir dizi eşleşme arasında gezinmek için sorgu çıkışını da kullanabilir. Böylece, Bazel sorgu aracı, bağımlılık grafiğine duyarlı "BUILD dosyaları için grep" olarak kullanılabilir.

Konum bilgileri, hedef türüne göre değişiklik gösterir (tür operatörüne bakın). Kurallar için, kuralın BUILD dosyasındaki beyanının konumu yazdırılır. Kaynak dosyalar için asıl dosyanın 1. satırının konumu yazdırılır. Oluşturulan bir dosya için dosyayı oluşturan kuralın konumu yazdırılır. (Sorgu aracı, oluşturulan dosyanın gerçek konumunu bulmak için yeterli bilgiye sahip değildir ve her durumda, henüz bir derleme gerçekleştirilmemişse mevcut olmayabilir.)

Paket grubunu yazdırma

--output package

Bu seçenek, sonuç kümesinde bir hedefin ait olduğu tüm paketlerin adını yazdırır. Adlar alfabetik sırayla yazılır ve yinelenenler hariç tutulur. Resmi olarak bu, etiketler grubundan (paket, hedef) paketlere bir projeksiyondur.

Harici depolardaki paketler @repo//foo/bar olarak biçimlendirilirken ana depodaki paketler foo/bar olarak biçimlendirilir.

deps(...) sorgusuyla birlikte bu çıkış seçeneği, belirli bir hedef grubu oluşturmak için kontrol edilmesi gereken paket grubunu bulmak için kullanılabilir.

Sonucun grafiğini görüntüleme

--output graph

Bu seçenek, sorgu sonucunun popüler AT&T GraphViz biçiminde yönlendirilmiş bir grafik olarak yazdırılmasına neden olur. Genellikle sonuç .png veya .svg gibi bir dosyaya kaydedilir. (dot programı iş istasyonunuzda yüklü değilse sudo apt-get install graphviz komutunu kullanarak yükleyebilirsiniz.) Örnek bir çağrı için aşağıdaki örnek bölümüne bakın.

Bu çıkış biçimi, özellikle --output label gibi doğrusal bir biçimde oluşturulduğunda kolayca görselleştirilemeyen bir yol grubu içeren allpaths, deps veya rdeps sorguları için kullanışlıdır.

Varsayılan olarak, grafik faktörlü bir biçimde oluşturulur. Yani topolojik olarak eşdeğer düğümler, birden fazla etikete sahip tek bir düğümde birleştirilir. Bu, tipik sonuç grafikleri oldukça tekrar eden kalıplar içerdiğinden grafiği daha kompakt ve okunaklı hale getirir. Örneğin bir java_library kuralı, tümü aynı genrule tarafından oluşturulan yüzlerce Java kaynak dosyasına bağlı olabilir. Faktörlü grafikte bu dosyaların tamamı tek bir düğümle temsil edilir. Bu çalışma biçimi, --nograph:factored seçeneği ile devre dışı bırakılabilir.

--graph:node_limit n

Bu seçenek, çıkıştaki bir grafik düğümü için etiket dizesinin maksimum uzunluğunu belirtir. Daha uzun etiketler kısaltılır; -1, kısaltmayı devre dışı bırakır. Grafiklerin genellikle yazdırıldığı çarpanlara ayrılmış biçimden dolayı düğüm etiketleri çok uzun olabilir. GraphViz, bu seçeneğin varsayılan değeri olan 1024 karakteri aşan etiketleri işleyemez. --output=graph kullanılmadığı sürece bu seçeneğin hiçbir etkisi olmaz.

--[no]graph:factored

Varsayılan olarak, grafikler yukarıda açıklandığı gibi çarpanlarına ayrılmış biçimde görüntülenir. --nograph:factored belirtildiğinde grafikler faktöre ayırmadan yazdırılır. Bu, GraphViz'i kullanarak görselleştirmeyi pratik hale getirir ancak daha basit biçim, diğer araçlar (grep gibi) tarafından işlemeyi kolaylaştırabilir. --output=graph kullanılmadığı sürece bu seçeneğin etkisi yoktur.

XML

--output xml

Bu seçenek, elde edilen hedeflerin XML biçiminde yazdırılmasına neden olur. Çıkış şuna benzer bir XML üstbilgisiyle başlar:

  <?xml version="1.0" encoding="UTF-8"?>
  <query version="2">

ve ardından sonuç grafiğindeki her hedef için topolojik sırada (sıralı olmayan sonuçlar istenmediği sürece) bir XML öğesiyle devam eder ve ardından sonlandırıcı bir

</query>

Basit girişler file türündeki hedefler için yayınlanır:

  <source-file name='//foo:foo_main.cc' .../>
  <generated-file name='//foo:libfoo.so' .../>

Ancak kurallar için XML yapılandırılır ve değerinin kuralın BUILD dosyasında açıkça belirtilmediği özellikler de dahil olmak üzere kuralın tüm özelliklerinin tanımlarını içerir.

Buna ek olarak, sonuçta rule-input ve rule-output öğeleri bulunur. Böylece bağımlılık grafiği topolojisi, örneğin srcs özelliğindeki öğelerin ileriye yönelik bağımlılıklar (ön koşullar) ve outs özelliğinin içeriklerinin geriye dönük bağımlılıklar (tüketiciler) olduğunu bilmenize gerek kalmadan yeniden oluşturulabilir.

--noimplicit_deps belirtilirse örtülü bağımlılıklar için rule-input öğeleri atlanır.

  <rule class='cc_binary rule' name='//foo:foo' ...>
    <list name='srcs'>
      <label value='//foo:foo_main.cc'/>
      <label value='//foo:bar.cc'/>
      ...
    </list>
    <list name='deps'>
      <label value='//common:common'/>
      <label value='//collections:collections'/>
      ...
    </list>
    <list name='data'>
      ...
    </list>
    <int name='linkstatic' value='0'/>
    <int name='linkshared' value='0'/>
    <list name='licenses'/>
    <list name='distribs'>
      <distribution value="INTERNAL" />
    </list>
    <rule-input name="//common:common" />
    <rule-input name="//collections:collections" />
    <rule-input name="//foo:foo_main.cc" />
    <rule-input name="//foo:bar.cc" />
    ...
  </rule>

Bir hedefe ait her XML öğesi, değeri hedefin etiketi olan bir name özelliği ve değeri --output location tarafından yazdırılan hedefin konumu olan bir location özelliği içerir.

--[no]xml:line_numbers

XML çıkışında görüntülenen konumlar varsayılan olarak satır numaraları içerir. --noxml:line_numbers belirtildiğinde satır numaraları yazdırılmaz.

--[no]xml:default_values

Varsayılan olarak, XML çıkışı, değeri söz konusu özelliğin varsayılan değeri olan kural özelliğini içermez (örneğin, BUILD dosyasında belirtilmemişse veya varsayılan değer açıkça sağlanmışsa). Bu seçenek, bu tür özellik değerlerinin XML çıkışına eklenmesine neden olur.

Normal ifadeler

Sorgu dilindeki normal ifadeler Java normal ifade kitaplığını kullanır. Bu nedenle, java.util.regex.Pattern için tam söz dizimini kullanabilirsiniz.

Harici depolarla sorgu oluşturma

Derleme harici depolardaki kurallara dayanıyorsa sorgu sonuçları bu bağımlılıkları içerir. Örneğin, //foo:bar, @other-repo//baz:lib'e bağlıysa bazel query 'deps(//foo:bar)', @other-repo//baz:lib'ü bağımlılık olarak listeler.