BazelCon 2024 登録の受け付けを開始しました。

このページは Cloud Translation API によって翻訳されました。

一般的な C++ ビルドのユースケース

<ph type="x-smartling-placeholder"></ph> 問題を報告するソースを表示夜間 · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

ここでは、C++ プロジェクトをビルドする際の最も一般的なユースケースをいくつか紹介します。説明しますまだ C++ を構築していない場合は、まずはビルドを開始します。チュートリアルを完了し、Bazel を使用したプロジェクト Bazel の概要: C++ プロジェクトをビルドする。

cc_library と hdrs ヘッダーファイルについては、 cc_library。

ターゲットに複数のファイルを含める

単一のターゲットに複数のファイルを含める場合は、 glob。例:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

Bazel はこのターゲットを使用して、.cc と .h このターゲットを含む BUILD ファイルと同じディレクトリ（格納されます。

推移的インクルードの使用

ファイルにヘッダーが含まれている場合、そのファイルをソースとするルール（つまり、そのファイルを srcs、hdrs、または textual_hdrs 属性に含める）は、インクルードされるヘッダーのライブラリルールによります。逆に、直接依存関係として指定する必要があります。たとえば sandwich.h には bread.h が含まれ、bread.h には flour.h が含まれます。sandwich.h flour.h（サンドイッチに小麦粉が欲しい人）が含まれていないため、BUILD はファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここで、sandwich ライブラリは bread ライブラリに依存しており、これは flour ライブラリにあります。

インクルードパスの追加

ワークスペースでインクルードパスをルート化できない（またはルート化したくない）場合がある含まれます。既存のライブラリには、含まれていないインクルードディレクトリがすでに存在している可能性があります。ワークスペース内のパスと一致させます。たとえば、次のようなコードがあるとします。ディレクトリ構造:

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel では、some_lib.h が次のように含まれていると想定されます。 legacy/some_lib/include/some_lib.h。ただし、some_lib.cc に以下が含まれているとします。 "some_lib.h"。インクルードパスを有効にするには legacy/some_lib/BUILD は、some_lib/include がインクルードディレクトリです。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

特に、外部依存関係のヘッダーファイルとなるため、それ以外の場合は、/ 接頭辞を含める必要があります。

外部ライブラリのインクルード

Google Test を使用しているとします。 WORKSPACE ファイル内のリポジトリ関数のいずれかを使用して、次のことができます。 Google Test をダウンロードしてリポジトリで使用できるようにします。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

次に、gtest.BUILD（Google Test のコンパイルに使用する BUILD ファイル）を作成します。 Google Test にはcc_library ルールを構成する要件複雑になります。

googletest-release-1.10.0/src/gtest-all.cc #include（その他すべて） googletest-release-1.10.0/src/ 内のファイル: コンパイルすることで、シンボルの重複エラーを防止できます。
対応するヘッダーファイルを使用して、 googletest-release-1.10.0/include/ ディレクトリ（"gtest/gtest.h"）であるため、次のことを行う必要があります。そのディレクトリをインクルードパスに追加します。
pthread でリンクする必要があるため、これを linkopt として追加します。

最終的なルールは次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

やや複雑で、すべての先頭に googletest-release-1.10.0 が付きます。これは、アーカイブ構造の副産物として認識されます。「http_archive」をストリップできますこの接頭辞を使用するには、strip_prefix 属性を追加します。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD は次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

cc_ ルールが @gtest//:main に依存できるようになりました。

C++ テストの作成と実行

たとえば、次のようにテスト用の ./test/hello-test.cc を作成できます。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

次に、テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test に公開するには、以下を追加する必要があります "//test:__pkg__", を ./main/BUILD の visibility 属性に追加します。

これで、bazel test を使用してテストを実行できるようになりました。

bazel test test:hello-test

これにより、次の出力が生成されます。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

プリコンパイルされたライブラリへの依存関係の追加

コンパイル済みバージョン（ヘッダーと .so ファイルなど）を cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

これにより、ワークスペース内の他の C++ ターゲットがこのルールに依存できるようになります。