Hướng dẫn di chuyển Bzlmod

Do những thiếu sót của WORKSPACE, Bzlmod sẽ thay thế hệ thống WORKSPACE cũ trong các bản phát hành Bazel sau này. Hướng dẫn này giúp bạn di chuyển dự án sang Bzlmod và loại bỏ WORKSPACE để tìm nạp các phần phụ thuộc bên ngoài.

WORKSPACE so với Bzlmod

WORKSPACE và Bzlmod của Bazel cung cấp các tính năng tương tự nhau nhưng có cú pháp khác nhau. Phần này giải thích cách di chuyển từ các chức năng WORKSPACE cụ thể sang Bzlmod.

Xác định thư mục gốc của không gian làm việc Bazel

Tệp WORKSPACE đánh dấu thư mục gốc của dự án Bazel, trách nhiệm này được thay thế bằng MODULE.bazel trong Bazel phiên bản 6.3 trở lên. Với phiên bản Bazel trước 6.3, bạn vẫn sẽ thấy tệp WORKSPACE hoặc WORKSPACE.bazel tại thư mục gốc của không gian làm việc, có thể kèm theo các nhận xét như:

• WORKSPACE

  # This file marks the root of the Bazel workspace.
  # See MODULE.bazel for external dependencies setup.
  

Bật Bzlmod trong bazelrc

.bazelrc cho phép bạn đặt cờ áp dụng mỗi khi chạy Bazel. Để bật Bzlmod, hãy sử dụng cờ --enable_bzlmod và áp dụng cờ này cho lệnh common để áp dụng cho mọi lệnh:

• .bazelrc

  # Enable Bzlmod for every Bazel command
  common --enable_bzlmod
  

Chỉ định tên kho lưu trữ cho không gian làm việc

• WORKSPACE

  Hàm workspace dùng để chỉ định tên kho lưu trữ cho không gian làm việc. Điều này cho phép tham chiếu //foo:bar mục tiêu trong không gian làm việc dưới dạng @<workspace name>//foo:bar. Nếu bạn không chỉ định, tên kho lưu trữ mặc định cho không gian làm việc của bạn sẽ là __main__.

  ## WORKSPACE
  workspace(name = "com_foo_bar")
  

• Bzlmod

  Bạn nên tham chiếu các mục tiêu trong cùng một không gian làm việc bằng cú pháp //foo:bar không có @<repo name>. Tuy nhiên, nếu cần cú pháp cũ, bạn có thể sử dụng tên mô-đun do hàm module chỉ định làm tên kho lưu trữ. Nếu tên mô-đun khác với tên kho lưu trữ cần thiết, bạn có thể sử dụng thuộc tính repo_name của hàm module để ghi đè tên kho lưu trữ.

  ## MODULE.bazel
  module(
      name = "bar",
      repo_name = "com_foo_bar",
  )
  

Tìm nạp các phần phụ thuộc bên ngoài dưới dạng mô-đun Bazel

Nếu phần phụ thuộc của bạn là một dự án Bazel, thì bạn có thể phụ thuộc vào dự án đó dưới dạng mô-đun Bazel khi dự án đó cũng sử dụng Bzlmod.

• WORKSPACE

  Với WORKSPACE, bạn thường sử dụng các quy tắc kho lưu trữ http_archive hoặc git_repository để tải các nguồn của dự án Bazel xuống.

  ## WORKSPACE
  load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
  
  http_archive(
      name = "bazel_skylib",
      urls = ["https://github.com/bazelbuild/bazel-skylib/releases/download/1.4.2/bazel-skylib-1.4.2.tar.gz"],
      sha256 = "66ffd9315665bfaafc96b52278f57c7e2dd09f5ede279ea6d39b2be471e7e3aa",
  )
  load("@bazel_skylib//:workspace.bzl", "bazel_skylib_workspace")
  bazel_skylib_workspace()
  
  http_archive(
      name = "rules_java",
      urls = ["https://github.com/bazelbuild/rules_java/releases/download/6.1.1/rules_java-6.1.1.tar.gz"],
      sha256 = "76402a50ae6859d50bd7aed8c1b8ef09dae5c1035bb3ca7d276f7f3ce659818a",
  )
  load("@rules_java//java:repositories.bzl", "rules_java_dependencies", "rules_java_toolchains")
  rules_java_dependencies()
  rules_java_toolchains()
  

  Như bạn có thể thấy, đây là một mẫu phổ biến mà người dùng cần tải các phần phụ thuộc bắc cầu từ một macro của phần phụ thuộc. Giả sử cả bazel_skylib và rules_java đều phụ thuộc vào platform, phiên bản chính xác của phần phụ thuộc platform được xác định theo thứ tự của các macro.

• Bzlmod

  Với Bzlmod, miễn là phần phụ thuộc của bạn có trong Cơ sở đăng ký trung tâm của Bazel hoặc Cơ sở đăng ký Bazel tuỳ chỉnh, bạn chỉ cần phụ thuộc vào phần phụ thuộc đó bằng lệnh bazel_dep.

  ## MODULE.bazel
  bazel_dep(name = "bazel_skylib", version = "1.4.2")
  bazel_dep(name = "rules_java", version = "6.1.1")
  

  Bzlmod phân giải các phần phụ thuộc của mô-đun Bazel theo cách bắc cầu bằng thuật toán MVS. Do đó, phiên bản platform tối đa bắt buộc sẽ được chọn tự động.

Ghi đè phần phụ thuộc dưới dạng mô-đun Bazel

Là mô-đun gốc, bạn có thể ghi đè các phần phụ thuộc mô-đun Bazel theo nhiều cách.

Vui lòng đọc phần ghi đè để biết thêm thông tin.

Bạn có thể tìm thấy một số ví dụ về cách sử dụng trong kho lưu trữ ví dụ.

Tìm nạp các phần phụ thuộc bên ngoài bằng tiện ích mô-đun

Nếu phần phụ thuộc của bạn không phải là một dự án Bazel hoặc chưa có trong bất kỳ hệ thống đăng ký Bazel nào, bạn có thể giới thiệu phần phụ thuộc đó bằng cách sử dụng use_repo_rule hoặc phần mở rộng mô-đun.

• WORKSPACE

  Tải tệp xuống bằng quy tắc kho lưu trữ http_file.

  ## WORKSPACE
  load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
  
  http_file(
      name = "data_file",
      url = "http://example.com/file",
      sha256 = "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855",
  )
  

• Bzlmod

  Với Bzlmod, bạn có thể sử dụng lệnh use_repo_rule trong tệp MODULE.bazel để trực tiếp tạo thực thể cho các kho lưu trữ:

  ## MODULE.bazel
  http_file = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
  http_file(
      name = "data_file",
      url = "http://example.com/file",
      sha256 = "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855",
  )
  

  Về cơ bản, việc này được triển khai bằng cách sử dụng tiện ích mô-đun. Nếu cần thực hiện logic phức tạp hơn thay vì chỉ gọi một quy tắc kho lưu trữ, bạn cũng có thể tự triển khai tiện ích mô-đun. Bạn cần di chuyển định nghĩa vào tệp .bzl. Tệp này cũng cho phép bạn chia sẻ định nghĩa giữa WORKSPACE và Bzlmod trong thời gian di chuyển.

  ## repositories.bzl
  load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
  def my_data_dependency():
      http_file(
          name = "data_file",
          url = "http://example.com/file",
          sha256 = "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855",
      )
  

  Triển khai tiện ích mô-đun để tải macro phần phụ thuộc. Bạn có thể xác định trong cùng một tệp .bzl của macro, nhưng để duy trì khả năng tương thích với các phiên bản Bazel cũ, bạn nên xác định trong một tệp .bzl riêng.

  ## extensions.bzl
  load("//:repositories.bzl", "my_data_dependency")
  def _non_module_dependencies_impl(_ctx):
      my_data_dependency()
  
  non_module_dependencies = module_extension(
      implementation = _non_module_dependencies_impl,
  )
  

  Để hiển thị kho lưu trữ cho dự án gốc, bạn nên khai báo cách sử dụng tiện ích mô-đun và kho lưu trữ trong tệp MODULE.bazel.

  ## MODULE.bazel
  non_module_dependencies = use_extension("//:extensions.bzl", "non_module_dependencies")
  use_repo(non_module_dependencies, "data_file")
  

Giải quyết xung đột phần phụ thuộc bên ngoài bằng tiện ích mô-đun

Một dự án có thể cung cấp macro giới thiệu kho lưu trữ bên ngoài dựa trên dữ liệu đầu vào từ phương thức gọi. Nhưng nếu có nhiều phương thức gọi trong biểu đồ phần phụ thuộc và các phương thức gọi đó gây ra xung đột thì sao?

Giả sử dự án foo cung cấp macro sau đây, lấy version làm đối số.

## repositories.bzl in foo {:#repositories.bzl-foo}
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
def data_deps(version = "1.0"):
    http_file(
        name = "data_file",
        url = "http://example.com/file-%s" % version,
        # Omitting the "sha256" attribute for simplicity
    )

• WORKSPACE

  Với WORKSPACE, bạn có thể tải macro từ @foo và chỉ định phiên bản của phần phụ thuộc dữ liệu mà bạn cần. Giả sử bạn có một phần phụ thuộc khác @bar, cũng phụ thuộc vào @foo nhưng yêu cầu một phiên bản khác của phần phụ thuộc dữ liệu.

  ## WORKSPACE
  
  # Introduce @foo and @bar.
  ...
  
  load("@foo//:repositories.bzl", "data_deps")
  data_deps(version = "2.0")
  
  load("@bar//:repositories.bzl", "bar_deps")
  bar_deps() # -> which calls data_deps(version = "3.0")
  

  Trong trường hợp này, người dùng cuối phải điều chỉnh cẩn thận thứ tự của các macro trong WORKSPACE để có được phiên bản họ cần. Đây là một trong những khó khăn lớn nhất với WORKSPACE vì công cụ này không thực sự đưa ra cách hợp lý để giải quyết các phần phụ thuộc.

• Bzlmod

  Với Bzlmod, tác giả của dự án foo có thể sử dụng tiện ích mô-đun để giải quyết các xung đột. Ví dụ: giả sử bạn luôn chọn phiên bản tối đa bắt buộc của phần phụ thuộc dữ liệu trong số tất cả các mô-đun Bazel.

  ## extensions.bzl in foo
  load("//:repositories.bzl", "data_deps")
  
  data = tag_class(attrs={"version": attr.string()})
  
  def _data_deps_extension_impl(module_ctx):
      # Select the maximal required version in the dependency graph.
      version = "1.0"
      for mod in module_ctx.modules:
          for data in mod.tags.data:
              version = max(version, data.version)
      data_deps(version)
  
  data_deps_extension = module_extension(
      implementation = _data_deps_extension_impl,
      tag_classes = {"data": data},
  )
  

  ## MODULE.bazel in bar
  bazel_dep(name = "foo", version = "1.0")
  
  foo_data_deps = use_extension("@foo//:extensions.bzl", "data_deps_extension")
  foo_data_deps.data(version = "3.0")
  use_repo(foo_data_deps, "data_file")
  

  ## MODULE.bazel in root module
  bazel_dep(name = "foo", version = "1.0")
  bazel_dep(name = "bar", version = "1.0")
  
  foo_data_deps = use_extension("@foo//:extensions.bzl", "data_deps_extension")
  foo_data_deps.data(version = "2.0")
  use_repo(foo_data_deps, "data_file")
  

  Trong trường hợp này, mô-đun gốc yêu cầu phiên bản dữ liệu 2.0, trong khi phần phụ thuộc bar yêu cầu 3.0. Tiện ích mô-đun trong foo có thể giải quyết chính xác xung đột này và tự động chọn phiên bản 3.0 cho phần phụ thuộc dữ liệu.

Tích hợp trình quản lý gói của bên thứ ba

Tiếp theo phần cuối, vì tiện ích mô-đun cung cấp cách thức để thu thập thông tin từ biểu đồ phần phụ thuộc, thực hiện logic tuỳ chỉnh để phân giải các phần phụ thuộc và gọi quy tắc kho lưu trữ để giới thiệu các kho lưu trữ bên ngoài, nên đây là một cách hay để tác giả quy tắc cải thiện tập quy tắc tích hợp trình quản lý gói cho các ngôn ngữ cụ thể.

Vui lòng đọc trang phần mở rộng về mô-đun để tìm hiểu thêm về cách sử dụng phần mở rộng của mô-đun.

Dưới đây là danh sách các bộ quy tắc đã sử dụng Bzlmod để tìm nạp các phần phụ thuộc từ nhiều trình quản lý gói:

• rules_jvm_external
• rules_go
• rules_python

Bạn có thể xem ví dụ tối giản tích hợp trình quản lý gói giả lập tại kho lưu trữ ví dụ.

Phát hiện chuỗi công cụ trên máy chủ lưu trữ

Khi các quy tắc bản dựng Bazel cần phát hiện chuỗi công cụ nào có trên máy chủ lưu trữ, các quy tắc này sẽ sử dụng quy tắc kho lưu trữ để kiểm tra máy chủ lưu trữ và tạo thông tin chuỗi công cụ dưới dạng kho lưu trữ bên ngoài.

• WORKSPACE

  Cho quy tắc kho lưu trữ sau đây để phát hiện chuỗi công cụ shell.

  ## local_config_sh.bzl
  def _sh_config_rule_impl(repository_ctx):
      sh_path = get_sh_path_from_env("SH_BIN_PATH")
  
      if not sh_path:
          sh_path = detect_sh_from_path()
  
      if not sh_path:
          sh_path = "/shell/binary/not/found"
  
      repository_ctx.file("BUILD", """
  load("@bazel_tools//tools/sh:sh_toolchain.bzl", "sh_toolchain")
  sh_toolchain(
      name = "local_sh",
      path = "{sh_path}",
      visibility = ["//visibility:public"],
  )
  toolchain(
      name = "local_sh_toolchain",
      toolchain = ":local_sh",
      toolchain_type = "@bazel_tools//tools/sh:toolchain_type",
  )
  """.format(sh_path = sh_path))
  
  sh_config_rule = repository_rule(
      environ = ["SH_BIN_PATH"],
      local = True,
      implementation = _sh_config_rule_impl,
  )
  

  Bạn có thể tải quy tắc kho lưu trữ trong WORKSPACE.

  ## WORKSPACE
  load("//:local_config_sh.bzl", "sh_config_rule")
  sh_config_rule(name = "local_config_sh")
  

• Bzlmod

  Với Bzlmod, bạn có thể giới thiệu cùng một kho lưu trữ bằng cách sử dụng tiện ích mô-đun, tương tự như việc giới thiệu kho lưu trữ @data_file trong phần cuối cùng.

  ## local_config_sh_extension.bzl
  load("//:local_config_sh.bzl", "sh_config_rule")
  
  sh_config_extension = module_extension(
      implementation = lambda ctx: sh_config_rule(name = "local_config_sh"),
  )
  

  Sau đó, sử dụng đuôi tệp trong tệp MODULE.bazel.

  ## MODULE.bazel
  sh_config_ext = use_extension("//:local_config_sh_extension.bzl", "sh_config_extension")
  use_repo(sh_config_ext, "local_config_sh")
  

Đăng ký chuỗi công cụ và nền tảng thực thi

Tiếp theo phần cuối cùng, sau khi giới thiệu thông tin về chuỗi công cụ lưu trữ kho lưu trữ (ví dụ: local_config_sh), bạn có thể muốn đăng ký chuỗi công cụ.

• WORKSPACE

  Với WORKSPACE, bạn có thể đăng ký chuỗi công cụ theo các cách sau.

  1. Bạn có thể đăng ký chuỗi công cụ tệp .bzl và tải macro trong tệp WORKSPACE.

     ## local_config_sh.bzl
     def sh_configure():
         sh_config_rule(name = "local_config_sh")
         native.register_toolchains("@local_config_sh//:local_sh_toolchain")
     

     ## WORKSPACE
     load("//:local_config_sh.bzl", "sh_configure")
     sh_configure()
     

  2. Hoặc đăng ký trực tiếp chuỗi công cụ trong tệp WORKSPACE.

     ## WORKSPACE
     load("//:local_config_sh.bzl", "sh_config_rule")
     sh_config_rule(name = "local_config_sh")
     register_toolchains("@local_config_sh//:local_sh_toolchain")
     

• Bzlmod

  Với Bzlmod, các API register_toolchains và register_execution_platforms chỉ có trong tệp MODULE.bazel. Bạn không thể gọi native.register_toolchains trong phần mở rộng mô-đun.

  ## MODULE.bazel
  sh_config_ext = use_extension("//:local_config_sh_extension.bzl", "sh_config_extension")
  use_repo(sh_config_ext, "local_config_sh")
  register_toolchains("@local_config_sh//:local_sh_toolchain")
  

Chuỗi công cụ và nền tảng thực thi được đăng ký trong WORKSPACE, WORKSPACE.bzlmod và tệp MODULE.bazel của mỗi mô-đun Bazel tuân theo thứ tự ưu tiên này trong quá trình lựa chọn chuỗi công cụ (từ cao nhất đến thấp nhất):

1. chuỗi công cụ và nền tảng thực thi được đăng ký trong tệp MODULE.bazel của mô-đun gốc.
2. chuỗi công cụ và nền tảng thực thi được đăng ký trong tệp WORKSPACE hoặc WORKSPACE.bzlmod.
3. chuỗi công cụ và nền tảng thực thi do các mô-đun là phần phụ thuộc (chuyển đổi) của mô-đun gốc đăng ký.
4. khi không sử dụng WORKSPACE.bzlmod: các chuỗi công cụ được đăng ký trong hậu tố WORKSPACE.

Giới thiệu kho lưu trữ cục bộ

Bạn có thể cần phải giới thiệu một phần phụ thuộc dưới dạng kho lưu trữ cục bộ khi cần phiên bản cục bộ của phần phụ thuộc để gỡ lỗi hoặc bạn muốn kết hợp một thư mục trong không gian làm việc dưới dạng kho lưu trữ bên ngoài.

• WORKSPACE

  Với WORKSPACE, bạn có thể thực hiện việc này bằng hai quy tắc kho lưu trữ gốc là local_repository và new_local_repository.

  ## WORKSPACE
  local_repository(
      name = "rules_java",
      path = "/Users/bazel_user/workspace/rules_java",
  )
  

• Bzlmod

  Với Bzlmod, bạn có thể sử dụng local_path_override để ghi đè một mô-đun bằng đường dẫn cục bộ.

  ## MODULE.bazel
  bazel_dep(name = "rules_java")
  local_path_override(
      module_name = "rules_java",
      path = "/Users/bazel_user/workspace/rules_java",
  )
  

  Lưu ý: Với local_path_override, bạn chỉ có thể giới thiệu một thư mục cục bộ dưới dạng mô-đun Bazel, tức là thư mục đó phải có tệp MODULE.bazel và các phần phụ thuộc bắc cầu của nó sẽ được xem xét trong quá trình phân giải phần phụ thuộc. Ngoài ra, tất cả các lệnh ghi đè mô-đun chỉ có thể được mô-đun gốc sử dụng.

  Bạn cũng có thể giới thiệu kho lưu trữ cục bộ có tiện ích mô-đun. Tuy nhiên, bạn không thể gọi native.local_repository trong phần mở rộng mô-đun. Chúng tôi đang nỗ lực làm rõ tất cả các quy tắc về kho lưu trữ gốc (xem #18285 để biết tiến trình). Sau đó, bạn có thể gọi local_repository starlark tương ứng trong một tiện ích mô-đun. Bạn cũng có thể triển khai phiên bản tuỳ chỉnh của quy tắc kho lưu trữ local_repository nếu đây là vấn đề chặn bạn.

Liên kết mục tiêu

Quy tắc bind trong WORKSPACE không còn được dùng nữa và không được hỗ trợ trong Bzlmod. Phương thức này được giới thiệu để cung cấp cho mục tiêu một bí danh trong gói //external đặc biệt. Tất cả người dùng phụ thuộc vào tính năng này phải di chuyển.

Ví dụ: Nếu bạn có

## WORKSPACE
bind(
    name = "openssl",
    actual = "@my-ssl//src:openssl-lib",
)

Điều này cho phép các mục tiêu khác phụ thuộc vào //external:openssl. Bạn có thể di chuyển khỏi chế độ này bằng cách:

• Thay thế tất cả các cách sử dụng //external:openssl bằng @my-ssl//src:openssl-lib.

• Hoặc sử dụng quy tắc tạo alias

  • Xác định mục tiêu sau trong một gói (ví dụ: //third_party)

    ## third_party/BUILD
    alias(
        name = "openssl,
        actual = "@my-ssl//src:openssl-lib",
    )
    

  • Thay thế mọi cách sử dụng của //external:openssl bằng //third_party:openssl-lib.

Di chuyển

Phần này cung cấp thông tin và hướng dẫn hữu ích cho quy trình di chuyển Bzlmod của bạn.

Tìm hiểu về các phần phụ thuộc trong WORKSPACE

Bước đầu tiên của quá trình di chuyển là tìm hiểu những phần phụ thuộc mà bạn có. Bạn khó có thể tìm ra phần phụ thuộc chính xác nào được đưa vào tệp WORKSPACE vì các phần phụ thuộc bắc cầu thường được tải bằng macro *_deps.

Kiểm tra phần phụ thuộc bên ngoài bằng tệp đã giải quyết không gian làm việc

May mắn thay, cờ --experimental_repository_resolved_file có thể giúp ích cho bạn. Về cơ bản, cờ này tạo một "tệp khoá" của tất cả các phần phụ thuộc bên ngoài đã tìm nạp trong lệnh Bazel gần đây nhất của bạn. Bạn có thể tìm thêm thông tin chi tiết trong bài đăng trên blog này.

Có thể sử dụng theo hai cách:

1. Để tìm nạp thông tin về các phần phụ thuộc bên ngoài cần thiết cho việc tạo một số mục tiêu nhất định.

   bazel clean --expunge
   bazel build --nobuild --experimental_repository_resolved_file=resolved.bzl //foo:bar
   

2. Để tìm nạp thông tin của tất cả phần phụ thuộc bên ngoài được xác định trong tệp WORKSPACE.

   bazel clean --expunge
   bazel sync --experimental_repository_resolved_file=resolved.bzl
   

   Với lệnh bazel sync, bạn có thể tìm nạp tất cả các phần phụ thuộc được xác định trong tệp WORKSPACE, bao gồm:

   • bind lượt sử dụng
   • Cách sử dụng register_toolchains và register_execution_platforms

   Tuy nhiên, nếu dự án của bạn chạy trên nhiều nền tảng, tính năng đồng bộ hoá bazel có thể bị lỗi trên một số nền tảng nhất định vì một số quy tắc kho lưu trữ có thể chỉ chạy chính xác trên các nền tảng được hỗ trợ.

Sau khi chạy lệnh, bạn sẽ có thông tin về các phần phụ thuộc bên ngoài trong tệp resolved.bzl.

Kiểm tra phần phụ thuộc bên ngoài bằng bazel query

Bạn cũng có thể biết bazel query có thể được dùng để kiểm tra các quy tắc của kho lưu trữ bằng

bazel query --output=build //external:<repo name>

Mặc dù thuận tiện và nhanh hơn nhiều, nhưng truy vấn bazel có thể dựa trên phiên bản phần phụ thuộc bên ngoài, vì vậy, hãy cẩn thận khi sử dụng truy vấn này! Bạn có thể truy vấn và kiểm tra các phần phụ thuộc bên ngoài bằng Bzlmod thông qua một lệnh phụ mới.

Các phần phụ thuộc mặc định tích hợp sẵn

Nếu kiểm tra tệp do --experimental_repository_resolved_file tạo, bạn sẽ thấy nhiều phần phụ thuộc không được xác định trong WORKSPACE. Lý do là Bazel thực sự thêm tiền tố và hậu tố vào nội dung tệp WORKSPACE của người dùng để chèn một số phần phụ thuộc mặc định, thường là bắt buộc theo quy tắc gốc (ví dụ: @bazel_tools, @platforms và @remote_java_tools). Với Bzlmod, các phần phụ thuộc đó được giới thiệu bằng một mô-đun tích hợp sẵn bazel_tools, đây là phần phụ thuộc mặc định cho mọi mô-đun Bazel khác.

Chế độ kết hợp để di chuyển dần

Bzlmod và WORKSPACE có thể hoạt động song song, cho phép di chuyển các phần phụ thuộc từ tệp WORKSPACE sang Bzlmod theo một quy trình dần dần.

WORKSPACE.bzlmod

Trong quá trình di chuyển, người dùng Bazel có thể cần phải chuyển đổi giữa các bản dựng có và không bật Bzlmod. Hỗ trợ WORKSPACE.bzlmod được triển khai để giúp quy trình diễn ra suôn sẻ hơn.

WORKSPACE.bzlmod có cú pháp giống hệt như WORKSPACE. Khi Bzlmod được bật, nếu tệp WORKSPACE.bzlmod cũng tồn tại ở thư mục gốc của không gian làm việc:

• WORKSPACE.bzlmod có hiệu lực và nội dung của WORKSPACE bị bỏ qua.
• Không có tiền tố hoặc hậu tố nào được thêm vào tệp WORKSPACE.bzlmod.

Việc sử dụng tệp WORKSPACE.bzlmod có thể giúp quá trình di chuyển dễ dàng hơn vì:

• Khi Bzlmod bị tắt, bạn sẽ quay lại phương thức tìm nạp phần phụ thuộc từ tệp WORKSPACE ban đầu.
• Khi bật Bzlmod, bạn có thể theo dõi tốt hơn những phần phụ thuộc còn lại cần di chuyển bằng WORKSPACE.bzlmod.

Lưu ý: WORKSPACE.bzlmod KHÔNG thay thế chức năng của WORKSPACE để xác định thư mục gốc của không gian làm việc, do đó, bạn vẫn cần một tệp WORKSPACE ở thư mục gốc của không gian làm việc.

Chế độ hiển thị kho lưu trữ

Bzlmod có thể kiểm soát những kho lưu trữ khác hiển thị từ một kho lưu trữ nhất định, hãy kiểm tra tên kho lưu trữ và phần phụ thuộc nghiêm ngặt để biết thêm chi tiết.

Dưới đây là bản tóm tắt về chức năng của kho lưu trữ qua nhiều loại kho lưu trữ khi xem xét cả WORKSPACE.

	Từ kho lưu trữ chính	Từ kho lưu trữ mô-đun Bazel	Từ kho lưu trữ phần mở rộng mô-đun	Từ kho lưu trữ WORKSPACE
Kho lưu trữ chính	Hiển thị	Nếu mô-đun gốc là phần phụ thuộc trực tiếp	Nếu mô-đun gốc là phần phụ thuộc trực tiếp của mô-đun lưu trữ tiện ích mô-đun	Hiển thị
Kho lưu trữ mô-đun Bazel	Phần phụ thuộc Direct	Phần phụ thuộc trực tiếp	Phần phụ thuộc trực tiếp của mô-đun lưu trữ phần mở rộng mô-đun	Phần phụ thuộc trực tiếp của mô-đun gốc
Kho lưu trữ phần mở rộng mô-đun	Phần phụ thuộc trực tiếp	Phần phụ thuộc trực tiếp	Phần phụ thuộc trực tiếp của mô-đun lưu trữ phần mở rộng mô-đun + tất cả kho lưu trữ do cùng một phần mở rộng mô-đun tạo ra	Phần phụ thuộc trực tiếp của mô-đun gốc
Kho lưu trữ WORKSPACE	Tất cả đều hiển thị	Không hiển thị	Không hiển thị	Tất cả đều hiển thị

Lưu ý: Đối với mô-đun gốc, nếu @foo được xác định trong WORKSPACE và @foo cũng được dùng làm tên kho lưu trữ rõ ràng trong MODULE.bazel, thì @foo sẽ tham chiếu đến tên kho lưu trữ được giới thiệu trong MODULE.bazel.

Lưu ý: Đối với kho lưu trữ @bar do tiện ích mô-đun tạo, nếu @foo được dùng làm tên kho lưu trữ rõ ràng của một kho lưu trữ khác do cùng một tiện ích mô-đun tạo và các phần phụ thuộc trực tiếp của mô-đun lưu trữ tiện ích mô-đun, thì đối với kho lưu trữ @bar, @foo sẽ tham chiếu đến kho lưu trữ sau.

Quá trình di chuyển

Quy trình di chuyển Bzlmod điển hình có thể có dạng như sau:

1. Tìm hiểu những phần phụ thuộc bạn có trong WORKSPACE.
2. Thêm một tệp MODULE.bazel trống vào thư mục gốc của dự án.
3. Thêm một tệp WORKSPACE.bzlmod trống để ghi đè nội dung tệp WORKSPACE.
4. Tạo các mục tiêu của bạn bằng cách bật Bzlmod và kiểm tra xem thư viện nào bị thiếu.
5. Kiểm tra định nghĩa về kho lưu trữ bị thiếu trong tệp phần phụ thuộc đã được phân giải.
6. Hãy đưa phần phụ thuộc bị thiếu dưới dạng mô-đun Bazel, thông qua một tiện ích mô-đun hoặc để phần phụ thuộc đó trong WORKSPACE.bzlmod để di chuyển sau này.
7. Quay lại 4 và lặp lại cho đến khi tất cả phần phụ thuộc đều xuất hiện.

Công cụ di chuyển

Có một tập lệnh trợ giúp di chuyển Bzlmod tương tác có thể giúp bạn bắt đầu.

Tập lệnh thực hiện những việc sau:

• Tạo và phân tích cú pháp tệp đã giải quyết WORKSPACE.
• In thông tin kho lưu trữ từ tệp đã phân giải theo cách mà con người có thể đọc được.
• Chạy lệnh bản dựng bazel, phát hiện thông báo lỗi được nhận dạng và đề xuất cách di chuyển.
• Kiểm tra xem một phần phụ thuộc đã có trong BCR hay chưa.
• Thêm phần phụ thuộc vào tệp MODULE.bazel.
• Thêm phần phụ thuộc thông qua tiện ích mô-đun.
• Thêm phần phụ thuộc vào tệp WORKSPACE.bzlmod.

Để sử dụng tính năng này, hãy đảm bảo bạn đã cài đặt bản phát hành Bazel mới nhất và chạy lệnh sau:

git clone https://github.com/bazelbuild/bazel-central-registry.git
cd <your workspace root>
<BCR repo root>/tools/migrate_to_bzlmod.py -t <your build targets>

Lưu ý: Tập lệnh di chuyển không hoàn hảo và có thể chưa được cập nhật vì Bzlmod đang phát triển, hãy luôn kiểm tra kỹ xem giải pháp được đề xuất có chính xác hay không.

Xuất bản các mô-đun Bazel

Nếu dự án Bazel của bạn là phần phụ thuộc của các dự án khác, thì bạn có thể xuất bản dự án trong Bazel Central Registry (Sổ đăng ký trung tâm Bazel).

Để có thể kiểm tra dự án của mình trong BCR, bạn cần có URL lưu trữ nguồn của dự án. Hãy lưu ý một vài điều khi tạo bản lưu trữ nguồn:

• Đảm bảo tệp lưu trữ trỏ đến một phiên bản cụ thể.

  BCR chỉ có thể chấp nhận các bản lưu trữ nguồn có phiên bản vì Bzlmod cần tiến hành so sánh phiên bản trong quá trình phân giải phần phụ thuộc.

• Đảm bảo rằng URL lưu trữ ổn định.

  Bazel xác minh nội dung của tệp lưu trữ bằng giá trị băm, vì vậy, bạn nên đảm bảo tổng kiểm của tệp đã tải xuống không bao giờ thay đổi. Nếu URL là từ GitHub, vui lòng tạo và tải bản lưu trữ bản phát hành lên trang phát hành. GitHub sẽ không đảm bảo tổng kiểm tra các bản lưu trữ nguồn được tạo theo yêu cầu. Tóm lại, URL ở dạng https://github.com/<org>/<repo>/releases/download/... được coi là ổn định còn https://github.com/<org>/<repo>/archive/... thì không. Hãy xem bài viết Tình trạng ngừng hoạt động của Checksum lưu trữ GitHub để biết thêm thông tin.

• Đảm bảo cây nguồn tuân theo bố cục của kho lưu trữ ban đầu.

  Trong trường hợp kho lưu trữ của bạn rất lớn và bạn muốn tạo một bản lưu trữ phân phối có kích thước giảm bằng cách loại bỏ các nguồn không cần thiết, vui lòng đảm bảo rằng cây nguồn đã loại bỏ là một tập hợp con của cây nguồn ban đầu. Điều này giúp người dùng cuối dễ dàng ghi đè mô-đun thành phiên bản không phát hành bằng archive_override và git_override.

• Thêm mô-đun kiểm thử trong một thư mục con để kiểm thử những API phổ biến nhất.

  Mô-đun kiểm thử là một dự án Bazel có tệp WORKSPACE và MODULE.bazel riêng nằm trong một thư mục con của bản lưu trữ nguồn, tuỳ thuộc vào mô-đun thực tế sẽ được phát hành. Tài liệu này phải chứa các ví dụ hoặc một số bài kiểm thử tích hợp bao gồm các API phổ biến nhất của bạn. Hãy xem mô-đun kiểm thử để tìm hiểu cách thiết lập.

Khi bạn đã có URL lưu trữ nguồn, hãy làm theo nguyên tắc đóng góp cho BCR để gửi mô-đun của bạn đến BCR bằng Yêu cầu lấy GitHub.

Bạn nên thiết lập Ứng dụng GitHub Xuất bản lên BCR cho kho lưu trữ của mình để tự động hoá quy trình gửi mô-đun đến BCR.

Các phương pháp hay nhất

Phần này trình bày một số phương pháp hay nhất mà bạn nên làm theo để quản lý tốt hơn các phần phụ thuộc bên ngoài.

Chia các mục tiêu thành nhiều gói để tránh tìm nạp các phần phụ thuộc không cần thiết.

Kiểm tra #12835, trong đó các phần phụ thuộc của nhà phát triển dành cho kiểm thử buộc phải tìm nạp một cách không cần thiết để tạo các mục tiêu không cần đến phần phụ thuộc đó. Đây không phải là vấn đề cụ thể của Bzlmod, nhưng việc làm theo phương pháp này giúp bạn dễ dàng chỉ định chính xác các phần phụ thuộc của nhà phát triển.

Chỉ định các phần phụ thuộc dành cho nhà phát triển

Bạn có thể đặt thuộc tính dev_dependency thành true cho các lệnh bazel_dep và use_extension để các lệnh này không truyền đến các dự án phụ thuộc. Là mô-đun gốc, bạn có thể sử dụng cờ --ignore_dev_dependency để xác minh xem các mục tiêu của bạn có vẫn tạo bản dựng mà không cần phần phụ thuộc phát triển hay không.

Tiến trình di chuyển cộng đồng

Bạn có thể kiểm tra Sổ đăng ký Bazel Central Registry (Sổ đăng ký trung tâm Bazel) để tìm hiểu xem các phần phụ thuộc của bạn đã có sẵn hay chưa. Nếu không, vui lòng tham gia cuộc thảo luận này trên GitHub để tán thành hoặc đăng những phần phụ thuộc đang cản trở quá trình di chuyển của bạn.

Báo cáo sự cố

Vui lòng kiểm tra danh sách vấn đề GitHub của Bazel để biết các vấn đề đã biết về Bzlmod. Bạn có thể gửi các vấn đề mới hoặc yêu cầu về tính năng có thể giúp bạn tiếp tục di chuyển!