Java và Bazel

Báo cáo sự cố Xem nguồn

Trang này chứa các tài nguyên giúp bạn sử dụng Bazel với các dự án Java. Hướng dẫn này liên kết đến hướng dẫn, quy tắc xây dựng và thông tin khác cụ thể về việc xây dựng các dự án Java bằng Bazel.

Làm việc với Bazel

Các tài nguyên sau sẽ giúp bạn xử lý Bazel trong các dự án Java:

Di chuyển sang Bazel

Nếu bạn đang xây dựng các dự án Java bằng Maven, hãy làm theo các bước trong hướng dẫn di chuyển để bắt đầu tạo các dự án Maven bằng Bazel:

Phiên bản Java

Có hai phiên bản Java có liên quan được đặt với cờ cấu hình:

  • phiên bản của các tệp nguồn trong kho lưu trữ
  • phiên bản thời gian chạy Java dùng để thực thi mã và kiểm thử mã

Định cấu hình phiên bản mã nguồn trong kho lưu trữ của bạn

Nếu không có cấu hình bổ sung, Bazel giả định rằng tất cả các tệp nguồn Java trong kho lưu trữ đều được ghi bằng một phiên bản Java duy nhất. Để chỉ định phiên bản của nguồn trong kho lưu trữ, hãy thêm build --java_language_version={ver} vào tệp .bazelrc, trong đó {ver} là ví dụ 11. Chủ sở hữu kho lưu trữ Bazel nên đặt cờ này để Bazel và người dùng có thể tham chiếu đến số phiên bản Java của mã nguồn. Để biết thêm thông tin chi tiết, hãy xem phần Gắn cờ phiên bản ngôn ngữ Java.

Định cấu hình JVM dùng để thực thi và kiểm thử mã

Bazel sử dụng một JDK để biên dịch và một JVM khác để thực thi và kiểm thử mã.

Theo mặc định, Bazel biên dịch mã bằng cách sử dụng JDK mà nó tải xuống, sau đó thực thi và kiểm thử mã bằng JVM được cài đặt trên máy cục bộ. Bazel tìm kiếm JVM bằng cách sử dụng JAVA_HOME hoặc đường dẫn.

Các tệp nhị phân thu được tương thích với JVM được cài đặt cục bộ trong thư viện hệ thống, nghĩa là các tệp nhị phân thu được phụ thuộc vào nội dung được cài đặt trên máy.

Để định cấu hình JVM dùng để thực thi và kiểm thử, hãy sử dụng cờ --java_runtime_version. Giá trị mặc định là local_jdk.

Kiểm thử và biên dịch tích hợp

Để tạo biên dịch ẩn, bạn có thể sử dụng cờ dòng lệnh --java_runtime_version=remotejdk_11. Mã được biên dịch, thực thi và kiểm thử trên JVM được tải xuống từ một kho lưu trữ từ xa. Để biết thêm thông tin, hãy xem bài viết Gắn cờ phiên bản thời gian chạy Java.

Định cấu hình biên dịch và thực thi công cụ xây dựng trong Java

Có một cặp JDK và JVM thứ hai dùng để tạo và thực thi các công cụ, được dùng trong quy trình xây dựng, nhưng không có trong kết quả bản dựng. JDK và JVM đó được kiểm soát bằng --tool_java_language_version và --tool_java_runtime_version. Giá trị mặc định lần lượt là 11 và remotejdk_11.

Biên dịch bằng JDK được cài đặt cục bộ

Theo mặc định, Bazel biên dịch bằng JDK từ xa, vì trình này sẽ ghi đè phần nội bộ của JDK. Các chuỗi công cụ biên dịch sử dụng JDK được cài đặt cục bộ sẽ được định cấu hình, tuy nhiên, không được sử dụng.

Để biên dịch bằng JDK được cài đặt cục bộ, tức là sử dụng chuỗi công cụ biên dịch cho JDK cục bộ, hãy sử dụng cờ bổ sung --extra_toolchains=@local_jdk//:all. Tuy nhiên, hãy lưu ý rằng tính năng này có thể không hoạt động trên JDK của các nhà cung cấp tuỳ ý.

Để biết thêm thông tin chi tiết, hãy xem phần định cấu hình chuỗi công cụ Java.

Các phương pháp hay nhất

Ngoài các phương pháp hay nhất chung về Bazel, dưới đây là các phương pháp hay nhất dành riêng cho dự án Java.

Cấu trúc thư mục

Ưu tiên bố cục thư mục chuẩn của Maven (các nguồn trong src/main/java, kiểm thử trong src/test/java).

XÂY DỰNG tệp

Hãy tuân theo các nguyên tắc sau khi tạo tệp BUILD:

  • Sử dụng một tệp BUILD trong mỗi thư mục chứa các nguồn Java vì điều này sẽ giúp cải thiện hiệu suất của bản dựng.

  • Mỗi tệp BUILD phải chứa một quy tắc java_library như sau:

    java_library(
    name = "directory-name",
    srcs = glob(["*.java"]),
    deps = [...],
)

  • Tên của thư viện phải là tên của thư mục chứa tệp BUILD. Thao tác này làm cho nhãn của thư viện ngắn hơn, sử dụng "//package" thay vì "//package:package".

  • Các nguồn phải là glob không đệ quy của tất cả tệp Java trong thư mục.

  • Các hoạt động kiểm thử phải nằm trong một thư mục trùng khớp trong src/test và phụ thuộc vào thư viện này.

Tạo quy tắc mới cho các bản dựng Java nâng cao

Lưu ý: Việc tạo quy tắc mới là dành cho các tình huống kiểm thử và bản dựng nâng cao. Bạn không cần dùng đến Bazel này khi bắt đầu sử dụng.

Các mô-đun, mảnh cấu hình và trình cung cấp sau đây sẽ giúp bạn mở rộng khả năng của Bazel khi xây dựng các dự án Java:

Định cấu hình chuỗi công cụ Java

Bazel sử dụng hai loại chuỗi công cụ Java: – thực thi, dùng để thực thi và kiểm thử các tệp nhị phân Java, được kiểm soát bằng cờ --java_runtime_version – biên dịch, dùng để biên dịch các nguồn Java, được kiểm soát bằng cờ --java_language_version

Định cấu hình chuỗi công cụ thực thi bổ sung

Chuỗi công cụ thực thi là JVM, cục bộ hoặc từ một kho lưu trữ, kèm theo một số thông tin bổ sung về phiên bản, hệ điều hành và cấu trúc CPU của nó.

Bạn có thể thêm chuỗi công cụ thực thi Java bằng cách sử dụng các quy tắc local_java_repository hoặc remote_java_repository trong tệp WORKSPACE. Việc thêm quy tắc sẽ giúp JVM hoạt động bằng cách sử dụng cờ. Khi bạn cung cấp nhiều định nghĩa cho cùng một hệ điều hành và cấu trúc CPU, thì định nghĩa đầu tiên sẽ được sử dụng.

Cấu hình mẫu của JVM cục bộ:

load("@bazel_tools//tools/jdk:local_java_repository.bzl", "local_java_repository")

local_java_repository(
  name = "additionaljdk",          # Can be used with --java_runtime_version=additionaljdk, --java_runtime_version=11 or --java_runtime_version=additionaljdk_11
  version = 11,                    # Optional, if not set it is autodetected
  java_home = "/usr/lib/jdk-15/",  # Path to directory containing bin/java
)

Cấu hình mẫu của JVM từ xa:

load("@bazel_tools//tools/jdk:remote_java_repository.bzl", "remote_java_repository")

remote_java_repository(
  name = "openjdk_canary_linux_arm",
  prefix = "openjdk_canary", # Can be used with --java_runtime_version=openjdk_canary_11
  version = "11",            # or --java_runtime_version=11
  target_compatible_with = [ # Specifies constraints this JVM is compatible with
    "@platforms//cpu:arm",
    "@platforms//os:linux",
  ],
  urls = ...,               # Other parameters are from http_repository rule.
  sha256 = ...,
  strip_prefix = ...
)

Định cấu hình chuỗi công cụ biên dịch bổ sung

Chuỗi công cụ biên dịch bao gồm JDK và nhiều công cụ mà Bazel sử dụng trong quá trình biên dịch, đồng thời cung cấp các tính năng bổ sung, chẳng hạn như: Error Prone, phần phụ thuộc Java nghiêm ngặt, biên dịch tiêu đề, đơn giản hoá Android, khả năng đo lường độ bao phủ và xử lý genclass cho IDE.

JavaBuilder là một công cụ theo gói Bazel thực thi quá trình biên dịch và cung cấp các tính năng nêu trên. Quá trình biên dịch thực tế được thực thi bằng trình biên dịch nội bộ của JDK. JDK dùng để biên dịch được chỉ định bằng thuộc tính java_runtime của chuỗi công cụ.

Bazel ghi đè một số thành phần JDK bên trong. Trong trường hợp phiên bản JDK > 9, các mô-đun java.compiler và jdk.compiler sẽ được vá bằng cờ --patch_module của JDK. Trong trường hợp JDK 8, trình biên dịch Java sẽ được vá bằng cờ -Xbootclasspath.

VanillaJavaBuilder là phương thức triển khai thứ hai của JavaBuilder, không sửa đổi trình biên dịch nội bộ của JDK và không có bất kỳ tính năng bổ sung nào. Không có chuỗi công cụ tích hợp sẵn nào sử dụng VanillaJavaBuilder.

Ngoài JavaBuilder, Bazel còn sử dụng một số công cụ khác trong quá trình biên dịch.

Công cụ ijar xử lý các tệp jar để xoá mọi nội dung ngoại trừ chữ ký lệnh gọi. Các ngăn kết quả được gọi là ngăn chứa tiêu đề. Chúng được dùng để cải thiện mức độ gia tăng trong quá trình biên dịch bằng cách chỉ biên dịch lại các phần phụ thuộc hạ nguồn khi phần nội dung của một hàm thay đổi.

Công cụ singlejar nhóm nhiều tệp jar lại với nhau thành một.

Công cụ genclass sẽ xử lý kết quả của quá trình biên dịch Java và tạo một jar chỉ chứa các tệp lớp cho các nguồn do trình xử lý chú giải tạo ra.

Công cụ JacocoRunner chạy Jacoco trên các tệp được đo lường và xuất ra kết quả ở định dạng LCOV.

Công cụ TestRunner thực thi chương trình kiểm thử JUnit 4 trong một môi trường được kiểm soát.

Bạn có thể định cấu hình lại quá trình biên dịch bằng cách thêm macro default_java_toolchain vào tệp BUILD và đăng ký bằng cách thêm quy tắc register_toolchains vào tệp WORKSPACE hoặc sử dụng cờ --extra_toolchains.

Chuỗi công cụ chỉ được sử dụng khi thuộc tính source_version khớp với giá trị do cờ --java_language_version chỉ định.

Ví dụ về cấu hình chuỗi công cụ:

load(
  "@bazel_tools//tools/jdk:default_java_toolchain.bzl",
  "default_java_toolchain", "DEFAULT_TOOLCHAIN_CONFIGURATION", "BASE_JDK9_JVM_OPTS", "DEFAULT_JAVACOPTS"
)

default_java_toolchain(
  name = "repository_default_toolchain",
  configuration = DEFAULT_TOOLCHAIN_CONFIGURATION,        # One of predefined configurations
                                                          # Other parameters are from java_toolchain rule:
  java_runtime = "@bazel_tools//tools/jdk:remote_jdk11", # JDK to use for compilation and toolchain's tools execution
  jvm_opts = BASE_JDK9_JVM_OPTS + ["--enable_preview"],   # Additional JDK options
  javacopts = DEFAULT_JAVACOPTS + ["--enable_preview"],   # Additional javac options
  source_version = "9",
)

Bạn có thể sử dụng API này bằng cách sử dụng --extra_toolchains=//:repository_default_toolchain_definition hoặc thêm register_toolchains("//:repository_default_toolchain_definition") vào không gian làm việc.

Cấu hình định sẵn:

  • DEFAULT_TOOLCHAIN_CONFIGURATION: tất cả các tính năng, hỗ trợ các phiên bản JDK >= 9
  • VANILLA_TOOLCHAIN_CONFIGURATION: không có tính năng bổ sung, hỗ trợ JDK của các nhà cung cấp tuỳ ý.
  • PREBUILT_TOOLCHAIN_CONFIGURATION: giống như mặc định, nhưng chỉ sử dụng các công cụ tạo sẵn (ijar, singlejar)
  • NONPREBUILT_TOOLCHAIN_CONFIGURATION: giống như mặc định, nhưng tất cả công cụ đều được tạo từ các nguồn (tuỳ chọn này có thể hữu ích trên hệ điều hành có libc khác nhau)

Định cấu hình cờ trình biên dịch JVM và Java

Bạn có thể định cấu hình cờ JVM và javac bằng cờ hoặc thuộc tính default_java_toolchain.

Cờ có liên quan là --jvmopt, --host_jvmopt, --javacopt và --host_javacopt.

Các thuộc tính default_java_toolchain có liên quan là javacopts, jvm_opts, javabuilder_jvm_opts và turbine_jvm_opts.

Cấu hình cờ của trình biên dịch Java cụ thể trong gói

Bạn có thể định cấu hình các cờ trình biên dịch Java khác nhau cho các tệp nguồn cụ thể bằng cách sử dụng thuộc tính package_configuration của default_java_toolchain. Vui lòng tham khảo ví dụ bên dưới.

load("@bazel_tools//tools/jdk:default_java_toolchain.bzl", "default_java_toolchain")

# This is a convenience macro that inherits values from Bazel's default java_toolchain
default_java_toolchain(
    name = "toolchain",
    package_configuration = [
        ":error_prone",
    ],
    visibility = ["//visibility:public"],
)

# This associates a set of javac flags with a set of packages
java_package_configuration(
    name = "error_prone",
    javacopts = [
        "-Xep:MissingOverride:ERROR",
    ],
    packages = ["error_prone_packages"],
)

# This is a regular package_group, which is used to specify a set of packages to apply flags to
package_group(
    name = "error_prone_packages",
    packages = [
        "//foo/...",
        "-//foo/bar/...", # this is an exclusion
    ],
)

Nhiều phiên bản mã nguồn Java trong một kho lưu trữ

Bazel chỉ hỗ trợ biên dịch một phiên bản nguồn Java duy nhất trong một bản dựng. Điều này có nghĩa là khi tạo kiểm thử Java hoặc ứng dụng, tất cả các phần phụ thuộc đều được xây dựng dựa trên cùng một phiên bản Java.

Tuy nhiên, các bản dựng riêng biệt có thể được thực thi bằng các cờ khác nhau.

Để dễ dàng thực hiện tác vụ sử dụng nhiều cờ khác nhau, bạn có thể nhóm các bộ cờ cho một phiên bản cụ thể với cấu hình .bazelrc":

build:java8 --java_language_version=8
build:java8 --java_runtime_version=local_jdk_8
build:java11 --java_language_version=11
build:java11 --java_runtime_version=remotejdk_11

Bạn có thể sử dụng các cấu hình này với cờ --config, ví dụ: bazel test --config=java11 //:java11_test.