目录
包裹
package(default_deprecation, default_package_metadata, default_testonly, default_visibility, features)
此函数声明适用于软件包中的每个规则的元数据。它在软件包（BUILD 文件）中最多只能使用一次。
对于声明将应用于整个代码库中每条规则的元数据的副本，请使用代码库根目录下的 REPO.bazel 文件中的 repo() 函数。repo() 函数所采用的参数与 package() 完全相同。
应在文件顶部的所有 load() 语句之后、任何规则之前调用 package() 函数。
参数
| 属性 | 说明 |
|---|---|
default_applicable_licenses |
|
default_visibility |
标签列表；默认值为 此软件包中规则的默认可见性。 除非在规则的 |
default_deprecation |
字符串；默认值为 为此软件包中的所有规则设置默认的 |
default_package_metadata |
标签列表；默认值为 设置适用于软件包中所有其他目标的默认元数据目标列表。 这些通常是与 OSS 软件包和许可声明相关的目标。 有关示例，请参阅 rules_license。 |
default_testonly |
布尔值；默认值为 为此软件包中的所有规则设置默认
在 |
features |
列表字符串；默认值为 设置影响此 BUILD 文件语义的各种标志。 此功能主要供构建系统开发者用来标记需要某种特殊处理的软件包。除非构建系统工作者明确请求，否则请勿使用此属性。 |
示例
以下声明声明，此软件包中的规则仅对软件包组//foo:target 的成员可见。规则的个别可见性声明（如果存在）会替换此规范。
package(default_visibility = ["//foo:target"])
package_group
package_group(name, packages, includes)
此函数定义一组软件包，并将标签与该组相关联。可以在 visibility 属性中引用该标签。
软件包组主要用于控制可见性。源代码树中的每个软件包都可以引用公开可见的目标。私有可见的目标只能在其自己的软件包（而非子软件包）中引用。在这两种极端之间，目标可能会允许访问自己的软件包以及一个或多个软件包组所描述的任何软件包。如需详细了解可见性系统，请参阅 visibility 属性。
如果给定软件包与 packages 属性匹配，或已包含在 includes 属性中提及的其他软件包组，则被视为包含在组内。
软件包组在技术上是目标，但不是由规则创建的，本身没有任何可见性保护。
参数
| 属性 | 说明 |
|---|---|
name |
名称；必需 此目标的唯一名称。 |
packages |
字符串列表；默认值为 零个或多个软件包规范的列表。 每个软件包规范字符串可以采用以下任一形式：
此外，前两种软件包规范还可以加上 软件包组包含与其至少一个正向规范匹配而未符合其任何负面规范的任何软件包。例如，值 除了公开可见之外，无法直接指定当前代码库之外的软件包。 如果缺少此属性，则等同于将其设置为空列表，也与将其设为仅包含 注意：在 Bazel 6.0 之前的版本中，规范 注意：在 Bazel 6.0 之前，如果此属性作为 |
includes |
标签列表；默认值为 此软件包组中包含的其他软件包组。 此属性中的标签必须引用其他软件包组。
引用的软件包组中的软件包会被视为此软件包组的一部分。这种关系是传递性的：如果软件包组 请注意，与否定软件包规范搭配使用时，系统会先独立计算每个组的软件包集，然后将结果联接在一起。这意味着，一个组中的否定规范不会影响另一个组中的规范。 |
示例
以下 package_group 声明指定了一个名为“tropical”的软件包组，其中包含热带水果。
package_group(
name = "tropical",
packages = [
"//fruits/mango",
"//fruits/orange",
"//fruits/papaya/...",
],
)
以下声明指定虚构应用的软件包组：
package_group(
name = "fooapp",
includes = [
":controller",
":model",
":view",
],
)
package_group(
name = "model",
packages = ["//fooapp/database"],
)
package_group(
name = "view",
packages = [
"//fooapp/swingui",
"//fooapp/webui",
],
)
package_group(
name = "controller",
packages = ["//fooapp/algorithm"],
)
exports_files
exports_files([label, ...], visibility, licenses)
exports_files() 指定属于此软件包并导出到其他软件包的文件列表。
软件包的 BUILD 文件只有在使用 exports_files() 语句明确导出的情况下，才能直接引用属于其他软件包的源文件。详细了解文件的公开范围。
作为旧版行为，在 --incompatible_no_implicit_file_export 标志被翻转之前，系统还会以默认可见性导出作为规则输入提及的文件。不过，不应依赖此行为，并应积极迁移。
参数
该参数是当前软件包中的文件名称列表。您也可以指定可见性声明；在这种情况下，文件将对指定的目标可见。如果未指定可见性，则文件将对每个软件包可见，即使在 package 函数中指定了软件包默认可见性也是如此。您还可以指定许可。
示例
以下示例会从 test_data 软件包中导出 golden.txt（一个文本文件），以便其他软件包可以使用它，例如在测试的 data 属性中使用。
# from //test_data/BUILD exports_files(["golden.txt"])
glob
glob(include, exclude=[], exclude_directories=1, allow_empty=True)
Glob 是一个辅助函数，用于查找与特定路径模式匹配的所有文件，并返回一个可变的、排序的路径新列表。Glob 仅搜索其自身软件包中的文件，并且只会查找源文件（而非生成的文件或其他目标）。
如果源文件的软件包相对路径与任何 include 格式匹配，但不匹配任何 exclude 格式，则结果中会包含源文件的标签。
include 和 exclude 列表包含相对于当前软件包的路径模式。每个模式都可能由一个或多个路径片段组成。与 Unix 路径一样，这些段由 / 分隔。段可以包含 * 通配符：这与路径段中的任何子字符串（即使是空子字符串）匹配，不包括目录分隔符 /。此通配符可以在一个路径段中多次使用。此外，** 通配符可以与零个或多个完整路径段匹配，但必须声明为独立路径段。
foo/bar.txt与此软件包中的foo/bar.txt文件完全匹配- 如果文件以
.txt结尾，foo/*.txt会匹配foo/目录中的每个文件（除非foo/是子软件包） foo/a*.htm*匹配foo/目录中以a开头、包含任意字符串（可以为空）、包含.htm且以另一个任意字符串结尾的每个文件；例如foo/axx.htm和foo/a.html或foo/axxx.html**/a.txt会匹配此软件包的每个子目录中的每个a.txt文件- 如果生成的路径上至少有一个目录名为
bar，例如xxx/bar/yyy/zzz/a.txt或bar/a.txt（请注意，**也与零个段匹配）或bar/zzz/a.txt，则**/bar/**/*.txt会匹配此软件包的每个子目录中的每个.txt文件。 **会匹配此软件包的每个子目录中的每个文件foo**/a.txt是一个无效的模式，因为**必须作为一个片段独立存在
如果 exclude_directories 参数已启用（设置为 1），则结果中会忽略目录类型的文件（默认值为 1）。
如果 allow_empty 参数设置为 False，且结果为空列表，则 glob 函数将出错。
存在以下几个重要的限制和注意事项：
-
由于
glob()在 BUILD 文件评估期间运行，因此glob()仅与源代码树中的文件匹配，绝不会与生成的文件匹配。如果您要构建的目标同时需要源文件和生成的文件，则必须将生成的文件明确列表附加到 glob。请参见以下有关:mylib和:gen_java_srcs的示例。 -
如果某条规则与匹配的源文件同名，则该规则将“覆盖”该文件。
为理解这一点，请记住
glob()会返回路径列表，因此在其他规则的属性（例如srcs = glob(["*.cc"])）中使用glob()与明确列出匹配的路径具有相同的效果。例如，如果glob()生成["Foo.java", "bar/Baz.java"]，但软件包中还有一个名为“Foo.java”的规则（允许这样，但 Bazel 会发出警告），则glob()的使用方将使用“Foo.java”规则（其输出）而非“Foo.java”文件。如需了解详情，请参阅 GitHub 问题 #10395。 - glob 可能会与子目录中的文件匹配。子目录名称可以使用通配符。不过…
-
标签不得跨越软件包边界，并且 glob 与子软件包中的文件不匹配。
例如，如果
x/y作为软件包（作为x/y/BUILD或在软件包路径的其他位置）存在，则软件包x中的全局正则表达式**/*.cc不包含x/y/z.cc。这意味着，正则表达式的结果实际上取决于 BUILD 文件的存在性，也就是说，如果不存在名为x/y的软件包，或者该软件包已使用 --deleted_packages 标志标记为已删除，则相同的正则表达式将包含x/y/z.cc。 - 上述限制适用于所有全局通配表达式，无论它们使用哪种通配符。
-
文件名以
.开头的隐藏文件与**和*通配符完全匹配。如果您想将隐藏文件与复合模式相匹配，则模式必须以.开头。例如，*和.*.txt将与.foo.txt匹配，但*.txt不匹配。 系统也会以相同的方式匹配隐藏目录。隐藏目录可能包含并不需要作为输入的文件，并且可能会增加不必要的全球文件数量和内存消耗。如需排除隐藏目录，请将其添加到“exclude”列表参数中。 -
“**”通配符有一个极端情况：模式
"**"与软件包的目录路径不匹配。也就是说，glob(["**"], exclude_directories = 0)会严格地递归匹配当前软件包目录下的所有文件和目录（但当然不会进入子软件包的目录 - 请参阅上文中的相关说明）。
通常，您应尝试提供适当的扩展名（例如 *.html），而不是使用裸“*”作为全局通配模式。更明确的名称不仅是自记录文件，还能确保您不会意外匹配备份文件（即 emacs/vi/... 自动保存文件）。
编写 build 规则时，您可以枚举正则表达式的元素。这样，您就可以为每个输入生成单独的规则。请参阅下面的展开后的 glob 示例部分。
Glob 示例
创建一个 Java 库，该库由此目录中的所有 Java 文件以及 :gen_java_srcs 规则生成的所有文件构建而成。
java_library(
name = "mylib",
srcs = glob(["*.java"]) + [":gen_java_srcs"],
deps = "...",
)
genrule(
name = "gen_java_srcs",
outs = [
"Foo.java",
"Bar.java",
],
...
)
将目录 testdata 中的所有 txt 文件（experimental.txt 除外）包含在内。 请注意，testdata 的子目录中的文件不包括在内。如果您想包含这些文件，请使用递归正则表达式 (**)。
sh_test(
name = "mytest",
srcs = ["mytest.sh"],
data = glob(
["testdata/*.txt"],
exclude = ["testdata/experimental.txt"],
),
)
递归 glob 示例
使测试依赖于 testdata 目录及其任何子目录（以及其子目录等）中的所有 txt 文件。 系统会忽略包含 BUILD 文件的子目录。（请参阅上文中的限制和注意事项。）
sh_test(
name = "mytest",
srcs = ["mytest.sh"],
data = glob(["testdata/**/*.txt"]),
)
创建一个库，该库由此目录和所有子目录中的所有 Java 文件构建而成，但路径中包含名为 testing 的目录的文件除外。应尽可能避免使用这种模式，因为它可以减少构建增量，从而增加构建时间。
java_library(
name = "mylib",
srcs = glob(
["**/*.java"],
exclude = ["**/testing/**"],
),
)
扩展的 Glob 示例
在当前目录中为 *_test.cc 创建一个单独的 genrule，用于统计文件中的行数。
# Conveniently, the build language supports list comprehensions.
[genrule(
name = "count_lines_" + f[:-3], # strip ".cc"
srcs = [f],
outs = ["%s-linecount.txt" % f[:-3]],
cmd = "wc -l $< >$@",
) for f in glob(["*_test.cc"])]
如果上面的 BUILD 文件位于软件包 //foo 中，且软件包包含三个匹配文件（a_test.cc、b_test.cc 和 c_test.cc），则运行 bazel query '//foo:all' 将列出已生成的所有规则：
$ bazel query '//foo:all' | sort //foo:count_lines_a_test //foo:count_lines_b_test //foo:count_lines_c_test
选择
select(
{conditionA: valuesA, conditionB: valuesB, ...},
no_match_error = "custom message"
)
select() 是一个辅助函数，用于使规则属性可配置。它可以取代几乎任何属性分配的右侧，因此其值取决于命令行 Bazel 标志。例如，您可以使用此方法定义平台专用依赖项，或根据规则是在“开发者”模式还是“发布”模式下构建来嵌入不同的资源。
基本用法如下：
sh_binary(
name = "mytarget",
srcs = select({
":conditionA": ["mytarget_a.sh"],
":conditionB": ["mytarget_b.sh"],
"//conditions:default": ["mytarget_default.sh"]
})
)
这会使 sh_binary 的 srcs 属性可配置，方法是将其常规标签列表分配替换为 select 调用，该调用将配置条件映射到匹配值。每个条件都是对 config_setting 或 constraint_value 的标签引用，如果目标的配置与预期的一组值匹配，则为“匹配”。然后，mytarget#srcs 的值将变为与当前调用匹配的标签列表。
注意：
- 在任何调用中，系统都会选择恰好一个条件。
- 如果有多个条件匹配，并且有一个是其他条件的专门化条件，则优先选择专用条件。如果条件 B 具有与条件 A 相同的所有标志和限制条件值以及一些额外的标志或限制条件值，则条件 B 会被视为条件 A 的特化。这也意味着，专精解析并非旨在创建排序，如以下示例 2 所示。
- 如果多个条件匹配，并且其中一个条件不是所有其他条件的特殊化，则 Bazel 会失败并显示错误，除非所有条件都解析为相同的值。
- 如果没有匹配的其他条件，系统会将特殊伪标签
//conditions:default视为匹配。如果省略此条件，则必须匹配某些其他规则，以免出现错误。 select可以嵌入到更大的属性赋值中。因此，srcs = ["common.sh"] + select({ ":conditionA": ["myrule_a.sh"], ...})和srcs = select({ ":conditionA": ["a.sh"]}) + select({ ":conditionB": ["b.sh"]})是有效的表达式。select适用于大多数（但不是全部）属性。不兼容的属性在文档中会标记为nonconfigurable。子软件包
subpackages(include, exclude=[], allow_empty=True)
subpackages()是一个辅助函数，类似于glob()，用于列出子软件包（而非文件和目录）。它使用与glob()相同的路径模式，并且可以与当前正在加载的 BUILD 文件的直接子孙级子软件包匹配。如需详细了解包含和排除模式以及相关示例，请参阅 glob。返回的子软件包列表按排序顺序排列，其中包含与
include中的给定模式（而非exclude中的模式）匹配的相对当前加载软件包的路径。示例
以下示例列出了软件包
foo/BUILD的所有直接子软件包# The following BUILD files exist: # foo/BUILD # foo/bar/baz/BUILD # foo/sub/BUILD # foo/sub/deeper/BUILD # # In foo/BUILD a call to subs = subpackages(include = ["**"]) # results in subs == ["sub", "bar/baz"] # # 'sub/deeper' is not included because it is a subpackage of 'foo/sub' not of # 'foo'
一般而言，用户最好使用 skylib 的“子软件包”模块，而不是直接调用此函数。