平台

报告问题 查看源代码

Bazel 可以使用许多不同版本的构建工具（例如链接器和编译器）在各种硬件、操作系统和系统配置上构建和测试代码。为了帮助管理这种复杂性，Bazel 有一个“限制条件”和“平台”的概念。限制条件是构建或生产环境可能不同的维度，例如 CPU 架构、是否存在 GPU 或系统安装的编译器的版本。平台是这些限制条件的选项集合，表示某些环境中可用的特定资源。

将环境建模为平台有助于 Bazel 自动为构建操作选择合适的工具链。平台还可与 config_setting 规则结合使用，以编写可配置属性。

Bazel 可识别平台可以提供服务的三种角色：

  • 主机 - 运行 Bazel 本身的平台。
  • Execution - 构建工具在此平台上执行构建操作以生成中间输出和最终输出。
  • 目标 - 最终输出驻留和执行的平台。

Bazel 支持以下关于平台的构建场景：

  • 单平台构建（默认）- 主机、执行和目标平台相同。例如，在 Ubuntu 上构建在 Intel x64 CPU 上运行的 Linux 可执行文件。

  • 交叉编译 build - 主机和执行平台相同，但目标平台不同。例如，在 MacBook Pro 上运行的 macOS 上构建 iOS 应用。

  • 多平台构建 - 主机、执行和目标平台各不相同。

定义限制条件和平台

可能的平台选择空间是使用 BUILD 文件中的 constraint_setting 和 constraint_value 规则定义的。constraint_setting 用于创建新维度，而 constraint_value 用于为给定维度创建新值；它们共同有效地定义枚举及其可能值。例如，BUILD 文件的以下代码段针对系统的 glibc 版本引入了一个限制条件，该限制条件包含两个可能的值。

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

您可以在工作区中的不同软件包中定义限制条件及其值。它们通过标签进行引用，并受常规可见性控制的约束。如果可见性允许，您可以通过定义自己的值来扩展现有限制条件设置。

platform 规则引入了一个新平台，其中包含某些限制条件值选项。以下命令创建了一个名为 linux_x86 的平台，并指明它描述了所有在 x86_64 架构上运行 Linux 操作系统且采用 glibc 2.25 版本的环境。（有关 Bazel 内置限制条件的详情，请参阅下文。）

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

普遍有用的限制条件和平台

为了使生态系统保持一致，Bazel 团队维护了一个代码库，其中包含最常用的 CPU 架构和操作系统的限制条件定义。所有这些工具都位于 https://github.com/bazelbuild/platforms。

Bazel 附带了以下特殊的平台定义：@local_config_platform//:host。这是自动检测的主机平台值，表示运行 Bazel 的系统自动检测的平台。

为构建指定平台

您可以使用以下命令行标志为 build 指定主机和目标平台：

  • --host_platform - 默认值为 @local_config_platform//:host
    • @local_config_platform 是用于检测主机操作系统和 CPU 并写入平台目标的代码库规则。
    • 此外，它还会创建 @local_config_platform//:constraintz.bzl，用于公开一个名为 HOST_CONSTRAINTS 的数组，该数组可用于其他 BUILD 和 Starlark 文件中。
  • --platforms - 默认为主机平台
    • 这意味着，如果未设置其他标志，则 @local_config_platform//:host 为目标平台。
    • 如果设置了 --host_platform 而不是 --platforms，则 --host_platform 的值同时是主机和目标平台。

跳过不兼容的目标

在针对特定目标平台构建应用时，通常希望跳过永远无法在该平台上运行的目标。例如，在使用 //... 的 Linux 计算机上进行构建时，您的 Windows 设备驱动程序可能会产生大量编译器错误。使用 target_compatible_with 属性告知 Bazel 您的代码具有哪些目标平台限制条件。

此属性最简单的用法会将目标限制为单个平台。系统不会针对不满足所有限制条件的任何平台构建目标。以下示例将 win_driver_lib.cc 限制为 64 位 Windows。

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib 仅兼容使用 64 位 Windows 进行构建，与所有其他操作系统不兼容。不兼容具有传递性。任何传递依赖于不兼容目标的目标本身都被视为不兼容。

何时跳过目标？

如果目标被视为不兼容，并且作为目标模式扩展的一部分包含在 build 中，则会跳过目标。例如，以下两个调用会跳过在目标模式扩展中找到的任何不兼容的目标。

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

同样，如果在命令行中使用 --expand_test_suites 指定了 test_suite，则会跳过 test_suite 中不兼容的测试。换句话说，命令行上的 test_suite 目标的行为类似于 :all 和 ...。使用 --noexpand_test_suites 可防止扩展，并会导致带有不兼容测试的 test_suite 目标也不兼容。

在命令行上明确指定不兼容的目标会导致错误消息和构建失败。

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

如果启用了 --skip_incompatible_explicit_targets，系统会以静默方式跳过不兼容的显式目标。

更具表现力的限制

为了更灵活地表示约束条件，请使用平台都不满足的 @platforms//:incompatible constraint_value。

将 select() 与 @platforms//:incompatible 结合使用可表达更复杂的限制。例如，可以使用它实现基本 OR 逻辑。以下代码标记的库与 macOS 和 Linux 兼容，但不适用于其他平台。

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

上述内容可解释为：

  1. 以 macOS 为目标平台时，目标没有限制。
  2. 以 Linux 为目标平台时，目标没有任何限制。
  3. 否则，目标具有 @platforms//:incompatible 约束条件。由于 @platforms//:incompatible 不属于任何平台，因此目标被视为不兼容。

如需使约束条件更易于阅读，请使用 skylib 的 selects.with_or()。

您可以使用类似的方式表示反向兼容性。以下示例介绍的库与除 ARM 之外的所有组件都兼容。

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

使用 bazel cquery 检测不兼容的目标

您可以使用 bazel cquery 的 Starlark 输出格式中的 IncompatiblePlatformProvider 来区分不兼容和兼容的目标。

此参数可用于滤除不兼容的目标。以下示例将仅输出兼容目标的标签。系统不会输出不兼容的目标。

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

已知问题

不兼容的目标会忽略可见性限制。