Bazel で Android Native Development Kit を使用する

<ph type="x-smartling-placeholder"></ph> 問題を報告する ソースを表示 夜間 · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Bazel を初めて使用する場合は、「Building Android with Bazel のチュートリアルをご覧ください。

概要

Bazel はさまざまなビルド構成で実行できます。その中のいくつかは、 Android Native Development Kit（NDK）ツールチェーン。これは、通常の cc_library ルールと cc_binary ルールは、Android 用に直接コンパイルできます。 Bazel。Bazel では、android_ndk_repository リポジトリを使用してこれを実現します 適用できます。

前提条件

Android SDK と NDK がインストールされていることを確認してください。

SDK と NDK をセットアップするには、次のスニペットを WORKSPACE に追加します。

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

android_ndk_repository ルールの詳細については、ビルド 百科事典のエントリ。

最新バージョンの Android NDK（r22 以降）を使用している場合は、 android_ndk_repository の Starlark 実装。 以下の手順に従います。 その README を参照してください。

クイック スタート

Android 用 C++ をビルドするには、cc_library 依存関係を android_binary ルールまたは android_library ルール。

たとえば、Android アプリの次の BUILD ファイルがあるとします。

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

この BUILD ファイルにより、次のターゲットグラフが生成されます。

図 1. cc_library の依存関係を持つ Android プロジェクトのビルドグラフ。

アプリをビルドするには、次のコマンドを実行します。

bazel build //app/src/main:app

bazel build コマンドは、Java ファイル、Android リソース ファイル、 cc_library ルールを使用し、すべてを APK にパッケージ化します。

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel は、すべての cc_ライブラリを単一の共有オブジェクト（.so）ファイルにコンパイルします。 デフォルトでは armeabi-v7a ABI をターゲットとします。変更やビルドの対象とする 複数の ABI を同時に使用することはできません。詳しくは、ターゲットの ABI。

設定例

この例は Bazel の例で入手できます。 リポジトリをご覧ください。

BUILD.bazel ファイルでは、android_binary を使用して 3 つのターゲットが定義されています。 android_library、cc_library ルール。

android_binary トップレベル ターゲットが APK をビルドします。

cc_library ターゲットに、JNI 関数を含む C++ ソースファイルが 1 つ含まれている 実装:

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library ターゲットには、Java ソース、リソース ファイル、 cc_library ターゲットへの依存関係があります。この例では、MainActivity.java が読み込まれます。 共有オブジェクト ファイル libapp.so。JNI のメソッド シグネチャを定義します。 関数:

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

注: ネイティブ ライブラリの名前は、 レベル android_binary の目標。この例では app です。

STL の設定

C++ STL を構成するには、--android_crosstool_top フラグを使用します。

bazel build //:app --android_crosstool_top=target label

@androidndk で利用可能な STL は次のとおりです。

STL	ターゲット ラベル
STLport	@androidndk//:toolchain-stlport
libc++	@androidndk//:toolchain-libcpp
GNustl	@androidndk//:toolchain-gnu-libstdcpp

r16 以前では、デフォルトの STL は gnustl です。r17 以降の場合、次のようになります。 libc++。便宜上、ターゲット @androidndk//:default_crosstool は次のようになります。 各デフォルト STL にエイリアスが設定されます。

r18 以降では、STLport と gnustl は 削除 libc++ が NDK 内の唯一の STL になります。

NDK ドキュメント をご覧ください。

ターゲット ABI を構成する

ターゲット ABI を構成するには、次のように --fat_apk_cpu フラグを使用します。

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

デフォルトでは、Bazel は armeabi-v7a のネイティブ Android コードをビルドします。x86 用のビルド （エミュレータの場合など）は、--fat_apk_cpu=x86 を渡します。1 つの軽量な APK を作成して複数の 複数の CPU を指定できます（--fat_apk_cpu=armeabi-v7a,x86）。

複数の ABI が指定されている場合、Bazel は共有 ABI を含む APK をビルドします。 自動的に作成します。

NDK のリビジョンと Android API レベルに応じて、以下の ABI が適用されます。 使用可能:

NDK リビジョン	ABI
16 以下	armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 歳以上	armeabi-v7a、arm64-v8a、x86、x86_64

NDK のドキュメントをご覧ください。 ご覧ください

マルチ ABI Fat APK は増加するため、リリースビルドには推奨されません APK のサイズは変わりませんが、開発や QA ビルドに役立ちます。

C++ 標準の選択

C++ 標準に従ってビルドするには、次のフラグを使用します。

C++ 標準	フラグ
C++98	デフォルト。フラグは不要
C++11	--cxxopt=-std=c++11
C++14	--cxxopt=-std=c++14

例:

bazel build //:app --cxxopt=-std=c++11

--cxxopt、--copt を使用してコンパイラ フラグとリンカーフラグを渡す方法の詳細をご確認ください。 ユーザー マニュアルの --linkopt。

コンパイラ フラグとリンカーフラグは cc_library で属性として指定することもできます。 copts と linkopts を使用します。例:

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

プラットフォームとツールチェーンとの統合

Bazel の構成モデルは、 プラットフォームと ツールチェーン。お使いの ビルドで --platforms フラグを使用してアーキテクチャまたはオペレーティング システムを選択する ビルドするには、--extra_toolchains フラグを Bazel に渡す必要があります。 使用する必要があります。

たとえば、Google Cloud で提供される android_arm64_cgo ツールチェーンと統合するには、 Go ルールでは、引数として --extra_toolchains=@androidndk//:all を、 --platforms フラグ。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

WORKSPACE ファイルで直接登録することもできます。

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

これらのツールチェーンを登録すると、NDK BUILD でツールチェーンを検索するよう Bazel に指示します ファイル（NDK 20 の場合）を以下の方法で解決します。

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

仕組み: Android 構成の移行の概要

android_binary ルールは、依存関係をビルドするよう Bazel に明示的に指示できます。 Android 互換の構成により、Bazel ビルドが 任意の特殊フラグ（--fat_apk_cpu と --android_crosstool_top を除く）は、 ABI と STL の構成。

この自動構成は、バックグラウンドで Android の構成を使用して 効果があります。

互換性のあるルール（android_binary など）により、 依存関係が Android 設定にマッピングされるため、 ビルドの Android 固有のサブツリーが影響を受けます。ビルドの他の部分 最上位のターゲット構成を使用して処理されます。さらに、 両方の構成で単一のターゲットを処理する場合、 グラフを構築します

Bazel が Android 互換構成になったら、 上位レベルの移行ポイントがある場合や、 構成はそれ以上変更されません。

Android への移行をトリガーする唯一の組み込み場所 構成は android_binary の deps 属性です。

注: android_binary の data 属性は意図的には含めません。 遷移をトリガーしますさらに、android_local_test と android_library 移行をまったく意図的に行わないでください。

たとえば、cc_library で android_library ターゲットをビルドしようとした場合です。 フラグなしで依存関係を作成すると、JNI が見つからないというエラーが発生する可能性があります。 header:

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

理想的には、こうした自動移行により Bazel が 発生していますただし、Bazel コマンドラインのターゲットがすでに たとえば、C++ デベロッパーは特定のタスクをテストするなど、 cc_library の場合は、カスタムの --crosstool_top を使用する必要があります。

android_binary を使用せずに Android 用の cc_library をビルドする

以下を使用せずに、Android 用のスタンドアロンの cc_binary または cc_library をビルドするには、 android_binary、--crosstool_top、--cpu、--host_crosstool_top を使用 使用できます。

例:

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

この例では、トップレベルの cc_library ターゲットと cc_binary ターゲットがビルドされます。 NDK ツールチェーンを使用できます。ただし、これにより Bazel 独自のホストツールがビルドされ、 NDK ツールチェーンを使用すると（Android の場合は）より複雑になります。これは、ホスト ツールチェーンが ターゲット ツールチェーンからコピーされます。これを回避するには、環境変数の値を --host_crosstool_top を @bazel_tools//tools/cpp:toolchain に設定 ホストの C++ ツールチェーンを明示的に設定する。

この方法では、ビルドツリー全体が影響を受けます。

注: コマンドラインのすべてのターゲットは、 これらのフラグを指定する際に Android 用にビルドされるため、 次のような Bazel ワイルドカードを使用します /... と :all。

これらのフラグは、bazelrc 構成（ABI ごとに 1 つ）に含めることができます。 project/.bazelrc:

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

次に、たとえば x86 の cc_library をビルドするには、次のコマンドを実行します。

bazel build //my/cc/jni:target --config=android_x86

一般に、この方法は低レベルのターゲット（cc_library など）に対して、または 構築するものを正確に把握できます自動的に設定されるため、 予想される大まかな目標の android_binary からの移行 多くのターゲットを 構築することは困難です