Bzlmod Taşıma Kılavuzu

7.3 · 7.2 · 7.1 · 7.0 · 6.5

WORKSPACE'in yetersiz olması nedeniyle Bzlmod, gelecekteki Bazel sürümlerinde eski WORKSPACE sisteminin yerini alacaktır. Bu kılavuz, projenizi Bzlmod'a taşımanıza ve harici bağımlılıkları getirmek için WORKSPACE'i bırakmanıza yardımcı olur.

WORKSPACE - Bzlmod

Bazel'in WORKSPACE ve Bzlmod farklı söz dizimiyle benzer özellikler sunar. Bu bölümde, belirli WORKSPACE işlevlerinden Bzlmod'a nasıl geçiş yapılacağı açıklanmaktadır.

Bazel çalışma alanının kökünü tanımlama

WORKSPACE dosyası, bir Bazel projesinin kaynak kökünü işaretler. Bu sorumluluk, Bazel 6.3 ve sonraki sürümlerde MODULE.bazel ile değiştirilir. 6.3'ten önceki Bazel sürümlerinde, çalışma alanınızın kökünde WORKSPACE veya WORKSPACE.bazel dosyası hâlâ mevcuttur. Bu dosyada aşağıdaki gibi yorumlar bulunabilir:

  • WORKSPACE

    # This file marks the root of the Bazel workspace.
# See MODULE.bazel for external dependencies setup.

bazelrc dosyanızda Bzlmod'u etkinleştirin

.bazelrc, Bazel'i her çalıştırdığınızda geçerli olacak işaretler ayarlamanıza olanak tanır. Bzlmod'u etkinleştirmek için --enable_bzlmod işaretini kullanın ve her komut için geçerli olması amacıyla common komutuna uygulayın:

  • .bazelrc

    # Enable Bzlmod for every Bazel command
common --enable_bzlmod

Çalışma alanınız için depo adını belirtin

  • WORKSPACE

    workspace işlevi, çalışma alanınız için bir depo adı belirtmek amacıyla kullanılır. Bu sayede, çalışma alanındaki bir //foo:bar hedefine @<workspace name>//foo:bar olarak referans verilebilir. Belirtilmemişse çalışma alanınızın varsayılan depo adı __main__ olur.

    ## WORKSPACE
workspace(name = "com_foo_bar")

  • Bzlmod

    Aynı çalışma alanındaki hedeflere @<repo name> olmadan //foo:bar söz dizimini kullanarak referans vermeniz önerilir. Ancak eski söz dizimine ihtiyacınız varsa depo adı olarak module işleviyle belirtilen modül adını kullanabilirsiniz. Modül adı, gerekli depolama alanı adından farklıysa depolama alanı adını geçersiz kılmak için module işlevinin repo_name özelliğini kullanabilirsiniz.

    ## MODULE.bazel
module(
    name = "bar",
    repo_name = "com_foo_bar",
)

Dış bağımlılıkları Bazel modülleri olarak getirin

Bağımlılığınız bir Bazel projesiyse Bzlmod'u da benimsediğinde ona Bazel modülü olarak bağımlı olabilirsiniz.

  • ÇALIŞMA ALANI

    WORKSPACE'te, Bazel projesinin kaynaklarını indirmek için http_archive veya git_repository depo kurallarının kullanılması yaygındır.

    ## WORKSPACE
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "bazel_skylib",
    urls = ["https://github.com/bazelbuild/bazel-skylib/releases/download/1.4.2/bazel-skylib-1.4.2.tar.gz"],
    sha256 = "66ffd9315665bfaafc96b52278f57c7e2dd09f5ede279ea6d39b2be471e7e3aa",
)
load("@bazel_skylib//:workspace.bzl", "bazel_skylib_workspace")
bazel_skylib_workspace()

http_archive(
    name = "rules_java",
    urls = ["https://github.com/bazelbuild/rules_java/releases/download/6.1.1/rules_java-6.1.1.tar.gz"],
    sha256 = "76402a50ae6859d50bd7aed8c1b8ef09dae5c1035bb3ca7d276f7f3ce659818a",
)
load("@rules_java//java:repositories.bzl", "rules_java_dependencies", "rules_java_toolchains")
rules_java_dependencies()
rules_java_toolchains()

    Gördüğünüz gibi, kullanıcıların geçişli bağımlılıkları bağımlılık makrosundan yüklemesi yaygın bir kalıptır. Hem bazel_skylib hem de rules_java'un platform'ye bağlı olduğunu varsayalım. platform bağımlılığının tam sürümü, makroların sırasına göre belirlenir.

  • Bzlmod

    Bzlmod ile bağımlılığınız Bazel Central Registry'de veya özel Bazel kayıt otoritenizde bulunduğu sürece, bir bazel_dep yönergesiyle bağımlılığınıza güvenebilirsiniz.

    ## MODULE.bazel
bazel_dep(name = "bazel_skylib", version = "1.4.2")
bazel_dep(name = "rules_java", version = "6.1.1")

    Bzlmod, MVS algoritmasını kullanarak Bazel modül bağımlılıklarını geçişli olarak çözer. Bu nedenle, platform için gereken en yüksek sürüm otomatik olarak seçilir.

Bir bağımlılık için Bazel modülü olarak geçersiz kılma

Kök modül olarak Bazel modülü bağımlılıkları farklı şekillerde geçersiz kılabilirsiniz.

Daha fazla bilgi için lütfen üstlenmeler bölümünü okuyun.

Bazı örnek kullanımları examples deposunda bulabilirsiniz.

Modül uzantılarıyla harici bağımlılıkları getirme

Bağımlılığınız bir Bazel projesi değilse veya henüz herhangi bir Bazel kayıt defterinde yoksa modül uzantılarını kullanarak bağımlılığı tanıtabilirsiniz.

  • WORKSPACE

    http_file depolama alanı kuralını kullanarak bir dosya indirin.

    ## WORKSPACE
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")

http_file(
    name = "data_file",
    url = "http://example.com/file",
    sha256 = "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855",
)

  • Bzlmod

    Bzlmod ile tanımı bir .bzl dosyasına taşımanız gerekir. Bu sayede, taşıma sürecinde WORKSPACE ve Bzlmod arasında tanımı paylaşabilirsiniz.

    ## repositories.bzl
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
def my_data_dependency():
    http_file(
        name = "data_file",
        url = "http://example.com/file",
        sha256 = "e3b0c44298fc1c149afbf4c8996fb92427ae41e4649b934ca495991b7852b855",
    )

    Bağımlılıklar makrosunu yüklemek için bir modül uzantısı uygulayın. Bunu, makronun aynı .bzl dosyasında tanımlayabilirsiniz. Ancak, eski Bazel sürümleriyle uyumluluğu korumak için ayrı bir .bzl dosyasında tanımlamak daha iyidir.

    ## extensions.bzl
load("//:repositories.bzl", "my_data_dependency")
def _non_module_dependencies_impl(_ctx):
    my_data_dependency()

non_module_dependencies = module_extension(
    implementation = _non_module_dependencies_impl,
)

    Deponun kök proje tarafından görülebilmesi için modül uzantısının ve deponun kullanımlarını MODULE.bazel dosyasında beyan etmeniz gerekir.

    ## MODULE.bazel
non_module_dependencies = use_extension("//:extensions.bzl", "non_module_dependencies")
use_repo(non_module_dependencies, "data_file")

Modül uzantısıyla dış bağımlılıkların çakışmasını çözme

Bir proje, arayanlardan gelen girişlere göre harici depoları tanıtan bir makro sağlayabilir. Ancak bağımlılık grafiğinde birden fazla arayan varsa ve bunlar bir çakışmaya neden oluyorsa ne olur?

foo projesinin, version bağımsız değişkenini alan aşağıdaki makroyu sağladığını varsayalım.

## repositories.bzl in foo {:#repositories.bzl-foo}
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
def data_deps(version = "1.0"):
    http_file(
        name = "data_file",
        url = "http://example.com/file-%s" % version,
        # Omitting the "sha256" attribute for simplicity
    )

  • WORKSPACE

    WORKSPACE ile makroyu @foo'ten yükleyebilir ve ihtiyacınız olan veri bağımlılığının sürümünü belirtebilirsiniz. Yine @foo öğesine bağlı olan ancak veri bağımlılığının farklı bir sürümünü gerektiren başka bir @bar bağımlınızın olduğunu varsayalım.

    ## WORKSPACE

# Introduce @foo and @bar.
...

load("@foo//:repositories.bzl", "data_deps")
data_deps(version = "2.0")

load("@bar//:repositories.bzl", "bar_deps")
bar_deps() # -> which calls data_deps(version = "3.0")

    Bu durumda, son kullanıcının ihtiyacı olan sürümü almak için WORKSPACE'teki makroların sırasını dikkatlice ayarlaması gerekir. Bağımlılıkları çözmek için mantıklı bir yöntem sunmadığından bu, Workspace'in en büyük sorunlarından biridir.

  • Bzlmod

    foo projesinin yazarı, Bzlmod ile çakışmaları çözmek için modül uzantısını kullanabilir. Örneğin, tüm Bazel modülleri arasında veri bağımlılığının her zaman en yüksek gerekli sürümünü seçmenin mantıklı olduğunu varsayalım.

    ## extensions.bzl in foo
load("//:repositories.bzl", "data_deps")

data = tag_class(attrs={"version": attr.string()})

def _data_deps_extension_impl(module_ctx):
    # Select the maximal required version in the dependency graph.
    version = "1.0"
    for mod in module_ctx.modules:
        for data in mod.tags.data:
            version = max(version, data.version)
    data_deps(version)

data_deps_extension = module_extension(
    implementation = _data_deps_extension_impl,
    tag_classes = {"data": data},
)

    ## MODULE.bazel in bar
bazel_dep(name = "foo", version = "1.0")

foo_data_deps = use_extension("@foo//:extensions.bzl", "data_deps_extension")
foo_data_deps.data(version = "3.0")
use_repo(foo_data_deps, "data_file")

    ## MODULE.bazel in root module
bazel_dep(name = "foo", version = "1.0")
bazel_dep(name = "bar", version = "1.0")

foo_data_deps = use_extension("@foo//:extensions.bzl", "data_deps_extension")
foo_data_deps.data(version = "2.0")
use_repo(foo_data_deps, "data_file")

    Bu durumda, kök modül 2.0 veri sürümünü, bağımlılık modülü bar ise 3.0 sürümünü gerektirir. foo ürünündeki modül uzantısı bu çakışmayı doğru şekilde çözebilir ve veri bağımlılığı için 3.0 sürümünü otomatik olarak seçebilir.

Üçüncü taraf paket yöneticisini entegre etme

Son bölümde de belirtildiği gibi, modül uzantısı, bağımlılık grafiğinden bilgi toplama, bağımlılıklarını çözmek için özel mantık yürütme ve harici depoları tanıtmak için depo kurallarını çağırma olanağı sunar. Bu, kural yazarlarının belirli diller için paket yöneticilerini entegre eden kural kümelerini geliştirmesi için mükemmel bir yoldur.

Modül uzantılarının nasıl kullanılacağı hakkında daha fazla bilgi edinmek için lütfen modül uzantıları sayfasını okuyun.

Farklı paket yöneticilerinden bağımlılık almak için Bzlmod'u halihazırda benimsemiş kural kümelerinin listesi aşağıda verilmiştir:

Sözde paket yöneticisi entegre eden en basit örneği examples deposunda bulabilirsiniz.

Ana makinede araç zincirlerini algılama

Bazel derleme kurallarının, ana makinenizde hangi araç zincirlerinin mevcut olduğunu tespit etmesi gerektiğinde ana makineyi incelemek ve araç zinciri bilgilerini harici depo olarak oluşturmak için depo kurallarını kullanır.

  • WORKSPACE

    Kabuk araç zincirini algılamak için aşağıdaki depo kuralı verilmiştir.

    ## local_config_sh.bzl
def _sh_config_rule_impl(repository_ctx):
    sh_path = get_sh_path_from_env("SH_BIN_PATH")

    if not sh_path:
        sh_path = detect_sh_from_path()

    if not sh_path:
        sh_path = "/shell/binary/not/found"

    repository_ctx.file("BUILD", """
load("@bazel_tools//tools/sh:sh_toolchain.bzl", "sh_toolchain")
sh_toolchain(
    name = "local_sh",
    path = "{sh_path}",
    visibility = ["//visibility:public"],
)
toolchain(
    name = "local_sh_toolchain",
    toolchain = ":local_sh",
    toolchain_type = "@bazel_tools//tools/sh:toolchain_type",
)
""".format(sh_path = sh_path))

sh_config_rule = repository_rule(
    environ = ["SH_BIN_PATH"],
    local = True,
    implementation = _sh_config_rule_impl,
)

    Depo kuralını WORKSPACE'e yükleyebilirsiniz.

    ## WORKSPACE
load("//:local_config_sh.bzl", "sh_config_rule")
sh_config_rule(name = "local_config_sh")

  • Bzlmod

    Bzlmod ile aynı depoyu modül uzantısı kullanarak tanıtabilirsiniz. Bu işlem, son bölümde @data_file deposunu kullanıma sunmaya benzer.

    ## local_config_sh_extension.bzl
load("//:local_config_sh.bzl", "sh_config_rule")

sh_config_extension = module_extension(
    implementation = lambda ctx: sh_config_rule(name = "local_config_sh"),
)

    Ardından MODULE.bazel dosyasında uzantıyı kullanın.

    ## MODULE.bazel
sh_config_ext = use_extension("//:local_config_sh_extension.bzl", "sh_config_extension")
use_repo(sh_config_ext, "local_config_sh")

Araç zincirlerini ve yürütme platformlarını kaydetme

Son bölümde, araç zinciri bilgilerini barındıran bir depo (ör. local_config_sh) tanıttıktan sonra araç zincirini kaydetmek isteyebilirsiniz.

  • WORKSPACE

    WORKSPACE ile araç zincirini aşağıdaki yöntemlerle kaydedebilirsiniz.

    1. .bzl dosyasına araç zincirini kaydedebilir ve makroyu WORKSPACE dosyasına yükleyebilirsiniz.

      ## local_config_sh.bzl
def sh_configure():
    sh_config_rule(name = "local_config_sh")
    native.register_toolchains("@local_config_sh//:local_sh_toolchain")

      ## WORKSPACE
load("//:local_config_sh.bzl", "sh_configure")
sh_configure()

    2. Alternatif olarak, araç zincirini doğrudan WORKSPACE dosyasına kaydedin.

      ## WORKSPACE
load("//:local_config_sh.bzl", "sh_config_rule")
sh_config_rule(name = "local_config_sh")
register_toolchains("@local_config_sh//:local_sh_toolchain")

  • Bzlmod

    Bzlmod ile register_toolchains ve register_execution_platforms API'leri yalnızca MODULE.bazel dosyasında kullanılabilir. Bir modül uzantısında native.register_toolchains yöntemini çağıramazsınız.

    ## MODULE.bazel
sh_config_ext = use_extension("//:local_config_sh_extension.bzl", "sh_config_extension")
use_repo(sh_config_ext, "local_config_sh")
register_toolchains("@local_config_sh//:local_sh_toolchain")

WORKSPACE, WORKSPACE.bzlmod ve her Bazel modülünün MODULE.bazel dosyasında kayıtlı araç zincirleri ve yürütme platformları, araç zinciri seçiminde aşağıdaki öncelik sırasını izler (en yüksekten en düşüğe):

  1. kök modülün MODULE.bazel dosyasına kaydedilen araç zincirleri ve yürütme platformları.
  2. WORKSPACE veya WORKSPACE.bzlmod dosyasına kayıtlı araç zincirleri ve yürütme platformları.
  3. kök modülün bağımlılığı olan modüller tarafından kayıtlı araç zincirleri ve yürütme platformları.
  4. WORKSPACE.bzlmod kullanılmadığında: WORKSPACE son ekte kayıtlı araç zincirleri bulunur.

Yerel depolar sunun

Hata ayıklama için bağımlılığın yerel bir sürümüne ihtiyacınız olduğunda veya çalışma alanınıza harici depo olarak bir dizin eklemek istediğinizde, bağımlılığı yerel depo olarak eklemeniz gerekebilir.

  • ÇALIŞMA ALANI

    WORKSPACE ile bu, local_repository ve new_local_repository adlı iki yerel depo kuralıyla sağlanır.

    ## WORKSPACE
local_repository(
    name = "rules_java",
    path = "/Users/bazel_user/workspace/rules_java",
)

  • Bzlmod

    Bzlmod ile bir modülü yerel yolla geçersiz kılmak için local_path_override aracını kullanabilirsiniz.

    ## MODULE.bazel
bazel_dep(name = "rules_java")
local_path_override(
    module_name = "rules_java",
    path = "/Users/bazel_user/workspace/rules_java",
)

    Modül uzantısına sahip yerel bir depo sunmak da mümkündür. Ancak, modül uzantısında native.local_repository yöntemini çağıramazsınız. Tüm yerel depo kurallarına yıldız eklemek için devam eden çalışmalar devam etmektedir (ilerleme durumu için #18285'e bakın). Ardından, modül uzantısında ilgili starlark local_repository öğesini çağırabilirsiniz. Sizin için engelleyici bir sorunsa local_repository depolama alanı kuralının özel bir sürümünü uygulamak da kolaydır.

Hedefleri bağlama

WORKSPACE'teki bind kuralı kullanımdan kaldırıldı ve Bzlmod'da desteklenmiyor. Özel //external paketinde bir hedefe takma ad vermek için kullanıma sunulmuştur. Bu API'ye bağlı tüm kullanıcılar taşıma işlemi yapmalıdır.

Örneğin, abone sayınız

## WORKSPACE
bind(
    name = "openssl",
    actual = "@my-ssl//src:openssl-lib",
)

Bu sayede diğer hedefler //external:openssl'e bağlı olabilir. Bundan başka bir yere taşıma işlemini şu şekilde yapabilirsiniz:

  • //external:openssl ifadesinin tüm kullanımlarını @my-ssl//src:openssl-lib ile değiştirin.

  • İsterseniz alias derleme kuralını da kullanabilirsiniz

    • Aşağıdaki hedefi bir pakette tanımlayın (ör. //third_party)

      ## third_party/BUILD
alias(
    name = "openssl,
    actual = "@my-ssl//src:openssl-lib",
)

    • Tüm //external:openssl kullanımlarını //third_party:openssl-lib ile değiştirin.

Taşıma

Bu bölümde, Bzlmod taşıma işleminizle ilgili yararlı bilgiler ve rehberlik sunulmaktadır.

WORKSPACE'te bağımlılıklarınızı öğrenin

Taşıma işleminin ilk adımı, hangi bağımlılıklara sahip olduğunuzu anlamaktır. Geçişli bağımlılıklar genellikle *_deps makrolarıyla yüklendiğinden WORKSPACE dosyasında tam bağımlılıkların ortaya çıktığını anlamak zor olabilir.

Çalışma alanı çözümlenen dosyayla harici bağımlılığı inceleyin

Neyse ki işaret --experimental_repository_resolved_file bu konuda yardımcı olabilir. Bu işaret, temelde son Bazel komutunuzda getirilen tüm harici bağımlılıkların bir "kilit dosyasını" oluşturur. Daha fazla bilgiyi bu blog yayınında bulabilirsiniz.

İki şekilde kullanılabilir:

  1. Belirli hedefleri oluştururken gereken dış bağımlılıklarla ilgili bilgileri getirmek.

    bazel clean --expunge
bazel build --nobuild --experimental_repository_resolved_file=resolved.bzl //foo:bar

  2. WORKSPACE dosyasında tanımlanan tüm harici bağımlılıkların bilgilerini getirmek için.

    bazel clean --expunge
bazel sync --experimental_repository_resolved_file=resolved.bzl

    bazel sync komutuyla, WORKSPACE dosyasında tanımlanan tüm bağımlılıkları getirebilirsiniz. Bu bağımlılıklar şunları içerir:

    • bind kullanım
    • register_toolchains ve register_execution_platforms kullanımları

    Ancak projeniz platformlar arasıysa bazı depo kuralları yalnızca desteklenen platformlarda düzgün şekilde çalışabileceğinden bazel senkronizasyonu belirli platformlarda bozulabilir.

Komutu çalıştırdıktan sonra, harici bağımlılıklarınızla ilgili bilgileri resolved.bzl dosyasında bulabilirsiniz.

bazel query ile harici bağımlılığı inceleme

bazel query işlevinin depo kurallarını incelemek için kullanılabileceğini

bazel query --output=build //external:<repo name>

Daha pratik ve çok daha hızlı olsa da bazel sorgusu dış bağımlılık sürümü hakkında yalan beyanda bulunabilir. Bu nedenle bu sürümü kullanırken dikkatli olun. Bzlmod ile harici bağımlılıkları sorgulamak ve incelemek için yeni bir alt komut kullanılacak.

Yerleşik varsayılan bağımlılıklar

--experimental_repository_resolved_file tarafından oluşturulan dosyayı kontrol ederseniz WORKSPACE'inizde tanımlanmayan birçok bağımlılık görürsünüz. Bunun nedeni, Bazel'in genellikle yerel kuralların (ör. @bazel_tools, @platforms ve @remote_java_tools) gerektirdiği bazı varsayılan bağımlılıkları yerleştirmek için kullanıcının WORKSPACE dosya içeriğine önek ve sonek eklemesidir. Bzlmod ile bu bağımlılıklar, diğer tüm Bazel modülleri için varsayılan bir bağımlılık olan bazel_tools yerleşik bir modülle oluşturulur.

Kademeli taşıma için karma mod

Bzlmod ve WORKSPACE yan yana çalışarak WORKSPACE dosyasından Bzlmod'a bağımlılıkların taşınmasını aşamalı bir süreç haline getirir.

WORKSPACE.bzlmod

Taşıma sırasında Bazel kullanıcılarının Bzlmod'un etkin olduğu ve etkin olmadığı derlemeler arasında geçiş yapması gerekebilir. Süreci daha sorunsuz hale getirmek için WORKSPACE.bzlmod desteği uygulanır.

WORKSPACE.bzlmod, WORKSPACE ile tam olarak aynı söz dizimine sahiptir. Bzlmod etkinleştirildiğinde, çalışma alanı kökünde bir WORKSPACE.bzlmod dosyası da mevcutsa:

  • WORKSPACE.bzlmod geçerlilik kazanır ve WORKSPACE içeriği yoksayılır.
  • WORKSPACE.bzlmod dosyasına herhangi bir önek veya sonek eklenmez.

WORKSPACE.bzlmod dosyasını kullanmak taşıma işlemini kolaylaştırabilir, çünkü:

  • Bzlmod devre dışı bırakıldığında, bağımlılıkları orijinal WORKSPACE dosyasından getirmeye geri dönersiniz.
  • Bzlmod etkinleştirildiğinde, WORKSPACE.bzlmod ile taşınmak için kalan bağımlılıkları daha iyi takip edebilirsiniz.

Depo görünürlüğü

Bzlmod, belirli bir depodan hangi diğer depoların görülebileceğini kontrol edebilir. Daha fazla ayrıntı için depo adlarını ve katı derinleri kontrol edin.

Aşağıda, WORKSPACE da dikkate alınarak farklı türdeki depolardan depo görünürlüğüne dair bir özet verilmiştir.

Ana depodan Bazel modül depolarından Modül uzantısı depolarından WORKSPACE depolarından
Ana depo Gösteriliyor Kök modül doğrudan bağımlılıksa Kök modül, modül uzantısını barındıran modülün doğrudan bağımlılığıysa Gösteriliyor
Bazel modülü depoları Doğrudan deps Doğrudan deps Modül uzantısını barındıran modülün doğrudan açıklamaları Kök modülün doğrudan bağımlılıkları
Modül uzantısı depoları Doğrudan deps Doğrudan satış Modül uzantısını barındıran modülün doğrudan bağımlılıkları ve aynı modül uzantısı tarafından oluşturulan tüm depolar Kök modülün doğrudan açıklamaları
WORKSPACE Depoları Tümünü göster Görünmez Görünmez Tümü görünür durumda
@bar@bar

Taşıma süreci

Tipik bir Bzlmod taşıma işlemi aşağıdaki gibi görünebilir:

  1. WORKSPACE'te hangi bağımlılıklarınızın olduğunu anlayın.
  2. Projenizin kök dizinine boş bir MODULE.bazel dosyası ekleyin.
  3. WORKSPACE dosya içeriğini geçersiz kılmak için boş bir WORKSPACE.bzlmod dosyası ekleyin.
  4. Bzlmod etkin olacak şekilde hedeflerinizi oluşturun ve hangi depoda eksiklik olduğunu kontrol edin.
  5. Çözüme ulaştırılan bağımlılık dosyasında eksik deponun tanımını kontrol edin.
  6. Eksik bağımlılığı bir modül uzantısı aracılığıyla Bazel modülü olarak ekleyin veya daha sonra taşımak için WORKSPACE.bzlmod dosyasında bırakın.
  7. 4. adıma geri dönün ve tüm bağımlılıklar kullanılabilir hale gelene kadar işlemi tekrarlayın.

Taşıma aracı

Başlamanıza yardımcı olabilecek etkileşimli bir Bzlmod taşıma yardımcı komut dosyası vardır.

Komut dosyası şunları yapar:

  • WORKSPACE çözümlenen dosyayı oluşturun ve ayrıştırın.
  • Çözümlenen dosyadaki depo bilgilerini insanlar tarafından okunabilecek şekilde yazdırın.
  • Bazel derleme komutunu çalıştırın, tanınan hata mesajlarını algılayın ve taşıma için bir yöntem önerin.
  • Bağımlılığın BCR'de mevcut olup olmadığını kontrol edin.
  • MODULE.bazel dosyasına bağımlılık ekleyin.
  • Modül uzantısı aracılığıyla bağımlılık ekleyin.
  • WORKSPACE.bzlmod dosyasına bağımlılık ekleyin.

Bu aracı kullanmak için en son Bazel sürümünün yüklü olduğundan emin olun ve aşağıdaki komutu çalıştırın:

git clone https://github.com/bazelbuild/bazel-central-registry.git
cd <your workspace root>
<BCR repo root>/tools/migrate_to_bzlmod.py -t <your build targets>

Bazel modüllerini yayınlama

Bazel projeniz başka projelere bağımlıysa projenizi Bazel Central Registry'de yayınlayabilirsiniz.

Projenizi BCR'de kontrol edebilmek için projenin kaynak arşiv URL'sine ihtiyacınız vardır. Kaynak arşivi oluştururken dikkat etmeniz gereken birkaç nokta vardır:

  • Arşivin belirli bir sürümü işaret ettiğinden emin olun.

    Bzlmod'un bağımlılık çözümlemesi sırasında sürüm karşılaştırması yapması gerektiğinden, BCR yalnızca sürümü oluşturulmuş kaynak arşivleri kabul edebilir.

  • Arşiv URL'sinin sabit olduğundan emin olun.

    Bazel, arşiv içeriğini bir karma değeriyle doğrular. Bu nedenle, indirilen dosyanın sağlamasının hiçbir zaman değişmediğinden emin olmanız gerekir. URL GitHub'dan geliyorsa lütfen sürüm sayfasında bir sürüm arşivi oluşturup yükleyin. GitHub, istek üzerine oluşturulan kaynak arşivlerinin sağlama toplamını garanti etmez. Kısacası, https://github.com/<org>/<repo>/releases/download/... biçimindeki URL'ler kararlı kabul edilirken https://github.com/<org>/<repo>/archive/... biçimindeki URL'ler kararlı kabul edilmez. Daha fazla içerik için GitHub Arşiv Denetimi Toplamı Kesinti'yi kontrol edin.

  • Kaynak ağacın, orijinal deponun düzenine uyduğundan emin olun.

    Deponuzdan gereksiz kaynakları kaldırarak boyutu küçültülmüş bir dağıtım arşivi oluşturmak istiyorsanız lütfen kaldırdığınız kaynak ağacının orijinal kaynak ağacının bir alt kümesi olduğundan emin olun. Bu, son kullanıcıların archive_override ve git_override ile modülü yayın dışı bir sürümle geçersiz kılmalarını kolaylaştırır.

  • En yaygın API'lerinizi test eden bir alt dizine bir test modülü ekleyin.

    Test modülü, yayınlanacak gerçek modüle bağlı olan kaynak arşivin bir alt dizininde yer alan ve kendi WORKSPACE ve MODULE.bazel dosyalarının bulunduğu bir Bazel projesidir. Bu kısımda, en yaygın API'lerinizi kapsayan örnekler veya bazı entegrasyon testleri bulunmalıdır. Nasıl ayarlayacağınızı öğrenmek için test modülünü kontrol edin.

Kaynak arşiv URL'niz hazır olduğunda, GitHub pull isteğiyle modülünüzü BCR'ye göndermek için BCR katkı yönergelerini uygulayın.

Modülünüzü BCR'ye gönderme işlemini otomatikleştirmek için deponuzda BCR'de Yayınla GitHub uygulamasını ayarlamanız önemle önerilir.

En iyi uygulamalar

Bu bölümde dış bağımlılıklarınızı daha iyi yönetmek için izlemeniz gereken birkaç en iyi uygulama yer almaktadır.

Gereksiz bağımlılıkları getirmekten kaçınmak için hedefleri farklı paketlere bölün.

Gerekli olmayan hedefler oluşturmak için testlere yönelik geliştirme bağımlılıklarının gereksiz yere getirilmeye zorlandığı #12835'i kontrol edin. Bu aslında Bzlmod'a özgü değildir ancak bu uygulamaları takip etmek, geliştirme bağımlılıklarını doğru şekilde belirtmeyi kolaylaştırır.

Geliştirici bağımlılıklarını belirleme

Bağımlı projelere uygulanmaması için bazel_dep ve use_extension yönergelerinde dev_dependency özelliğini "true" olarak ayarlayabilirsiniz. Kök modül olarak hedeflerinizin geliştirici bağımlıları olmadan hâlâ derleme durumunu doğrulamak için --ignore_dev_dependency işaretini kullanabilirsiniz.

Topluluk taşıma işleminin ilerleme durumu

Bağımlılıklarınızın mevcut olup olmadığını öğrenmek için Bazel Merkezi Sicil Dairesi'ni kontrol edebilirsiniz. Aksi takdirde, taşıma işleminizi engelleyen bağımlılıkları olumlu oy vermek veya yayınlamak için bu GitHub tartışmasına katılabilirsiniz.

Sorun bildirme

Bilinen Bzlmod sorunları için lütfen Bazel GitHub sorun listesini inceleyin. Taşıma işleminizin engelini kaldırmaya yardımcı olabilecek yeni sorunlar veya özellik istekleri gönderebilirsiniz.