ในที่นี้คุณจะพบกับกรณีการใช้งานที่พบบ่อยที่สุดบางส่วนสำหรับการสร้างโปรเจ็กต์ C++ ด้วย Bazel หากยังไม่มีการสร้างโปรเจ็กต์ C++ ด้วย Bazel โปรดดูบทแนะนำข้อมูลเบื้องต้นเกี่ยวกับ Bazel: สร้างโปรเจ็กต์ C++ ให้เสร็จสมบูรณ์
ดูข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs ได้ที่ cc_library
การรวมหลายไฟล์ไว้ในเป้าหมาย
คุณรวมหลายไฟล์ไว้ในเป้าหมายเดียวได้ด้วย glob เช่น
cc_library(
name = "build-all-the-files",
srcs = glob(["*.cc"]),
hdrs = glob(["*.h"]),
)
เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ไม่รวมไดเรกทอรีย่อย)
การใช้ทรานซิทีฟประกอบด้วย
หากไฟล์มีส่วนหัว กฎใดก็ตามที่มีไฟล์นั้นเป็นแหล่งที่มา (กล่าวคือ การมีไฟล์นั้นในแอตทริบิวต์ srcs, hdrs หรือ textual_hdrs) ควรขึ้นอยู่กับกฎไลบรารีของส่วนหัวที่รวมอยู่ ในทางกลับกัน เฉพาะการขึ้นต่อกันโดยตรงเท่านั้นที่จำเป็นต้องระบุเป็นทรัพยากร Dependency ตัวอย่างเช่น สมมติว่า sandwich.h มี bread.h และ bread.h มี flour.h sandwich.h ไม่ได้ใส่ flour.h (ใครอยากได้แป้งในแซนด์วิช) ไฟล์ BUILD จึงจะมีหน้าตาดังนี้
cc_library(
name = "sandwich",
srcs = ["sandwich.cc"],
hdrs = ["sandwich.h"],
deps = [":bread"],
)
cc_library(
name = "bread",
srcs = ["bread.cc"],
hdrs = ["bread.h"],
deps = [":flour"],
)
cc_library(
name = "flour",
srcs = ["flour.cc"],
hdrs = ["flour.h"],
)
ที่นี่ ไลบรารี sandwich จะขึ้นอยู่กับไลบรารี bread ซึ่งขึ้นอยู่กับไลบรารี flour
การเพิ่มเส้นทางรวม
บางครั้งคุณไม่สามารถ (หรือไม่ต้องการ) การรูทเส้นทางการรวมที่รูทของพื้นที่ทำงาน ไลบรารีที่มีอยู่อาจมีไดเรกทอรี "รวม" ที่ไม่ตรงกับเส้นทางในพื้นที่ทำงานอยู่แล้ว ตัวอย่างเช่น สมมติว่าคุณมีโครงสร้างไดเรกทอรี ต่อไปนี้
└── my-project
├── legacy
│ └── some_lib
│ ├── BUILD
│ ├── include
│ │ └── some_lib.h
│ └── some_lib.cc
└── WORKSPACE
Bazel คาดว่า some_lib.h จะรวมอยู่ใน legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc มี "some_lib.h" หากต้องการทำให้เส้นทางการรวมที่ถูกต้อง legacy/some_lib/BUILD จะต้องระบุว่าไดเรกทอรี some_lib/include เป็นไดเรกทอรี "รวม" ดังนี้
cc_library(
name = "some_lib",
srcs = ["some_lib.cc"],
hdrs = ["include/some_lib.h"],
copts = ["-Ilegacy/some_lib/include"],
)
วิธีนี้มีประโยชน์อย่างยิ่งสำหรับทรัพยากร Dependency ภายนอก เนื่องจากไฟล์ส่วนหัวต้องรวมอยู่ในคำนำหน้า /
รวมไลบรารีภายนอก
สมมติว่าคุณใช้ Google Test
คุณใช้ฟังก์ชันที่เก็บรายการใดรายการหนึ่งในไฟล์ WORKSPACE เพื่อดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บของคุณได้ โดยทำดังนี้
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
)
จากนั้นสร้าง gtest.BUILD ซึ่งเป็นไฟล์ BUILD ที่ใช้คอมไพล์ Google Test
Google Test มีข้อกำหนด "พิเศษ" หลายอย่างที่ทำให้กฎ cc_library ซับซ้อนขึ้น ดังนี้
googletest-release-1.10.0/src/gtest-all.cc#includeไฟล์อื่นๆ ทั้งหมดในgoogletest-release-1.10.0/src/: ยกเว้นไฟล์นั้นจากคอมไพล์เพื่อป้องกันข้อผิดพลาดของลิงก์สัญลักษณ์ที่ซ้ำกันโดยจะใช้ไฟล์ส่วนหัวที่สัมพันธ์กับไดเรกทอรี
googletest-release-1.10.0/include/("gtest/gtest.h") คุณจึงต้องเพิ่มไดเรกทอรีนั้นลงในเส้นทางการรวมต้องลิงก์ใน
pthreadดังนั้นโปรดเพิ่มเป็นlinkopt
ดังนั้น กฎสุดท้ายจะมีลักษณะดังนี้:
cc_library(
name = "main",
srcs = glob(
["googletest-release-1.10.0/src/*.cc"],
exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
),
hdrs = glob([
"googletest-release-1.10.0/include/**/*.h",
"googletest-release-1.10.0/src/*.h"
]),
copts = [
"-Iexternal/gtest/googletest-release-1.10.0/include",
"-Iexternal/gtest/googletest-release-1.10.0"
],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
วิธีนี้ค่อนข้างจะยุ่งเหยิง: ทุกสิ่งที่นำหน้าด้วย googletest-release-1.10.0 เป็นผลสืบเนื่องจากโครงสร้างของที่เก็บถาวร คุณทำให้ http_archive ตัดคำนำหน้านี้ได้โดยเพิ่มแอตทริบิวต์ strip_prefix ดังนี้
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
strip_prefix = "googletest-release-1.10.0",
)
gtest.BUILD จะมีหน้าตาแบบนี้
cc_library(
name = "main",
srcs = glob(
["src/*.cc"],
exclude = ["src/gtest-all.cc"]
),
hdrs = glob([
"include/**/*.h",
"src/*.h"
]),
copts = ["-Iexternal/gtest/include"],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
ตอนนี้กฎ cc_ ข้อจะขึ้นอยู่กับ @gtest//:main
การเขียนและทำการทดสอบ C++
ตัวอย่างเช่น คุณสร้างการทดสอบ ./test/hello-test.cc ได้ เช่น
#include "gtest/gtest.h"
#include "main/hello-greet.h"
TEST(HelloTest, GetGreet) {
EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}
จากนั้นสร้างไฟล์ ./test/BUILD ไฟล์สำหรับการทดสอบ
cc_test(
name = "hello-test",
srcs = ["hello-test.cc"],
copts = ["-Iexternal/gtest/include"],
deps = [
"@gtest//:main",
"//main:hello-greet",
],
)
หากต้องการให้ hello-test มองเห็น hello-greet คุณต้องเพิ่ม "//test:__pkg__", ลงในแอตทริบิวต์ visibility ใน ./main/BUILD
ตอนนี้คุณใช้ bazel test เพื่อทำการทดสอบได้แล้ว
bazel test test:hello-test
ซึ่งจะสร้างเอาต์พุตต่อไปนี้
INFO: Found 1 test target...
Target //test:hello-test up-to-date:
bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s
Executed 1 out of 1 tests: 1 test passes.
การเพิ่มทรัพยากร Dependency ในไลบรารีที่คอมไพล์ไว้ล่วงหน้า
หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (เช่น ส่วนหัวและไฟล์ .so) ให้ใช้กฎ cc_library ดังนี้
cc_library(
name = "mylib",
srcs = ["mylib.so"],
hdrs = ["mylib.h"],
)
วิธีนี้จะทำให้เป้าหมาย C++ อื่นๆ ในพื้นที่ทำงานขึ้นอยู่กับกฎนี้