巨集

回報問題 查看來源

本頁將介紹巨集的基本概念，並包含一般用途、偵錯和慣例。

巨集是從 BUILD 檔案呼叫的函式，可用來建立規則例項。巨集主要用於封裝及重複使用現有規則和其他巨集。在載入階段結束時，巨集就不會再存在，而 Bazel 只會看見一組例項化規則的具體規則。

用量

巨集的常見用途是重複使用規則。

舉例來說，BUILD 檔案中的 genrule 會使用 //:generator，透過指令中的 some_arg 引數產生檔案：

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

如要產生更多採用不同引數的檔案，建議您將這段程式碼擷取至巨集函式。我們呼叫 file_generator 巨集，其中包含 name 和 arg 參數。將 genrule 替換為下列內容：

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

這裡，您可以從 //path 套件中的 .bzl 檔案載入 file_generator 符號。將巨集函式定義放在獨立的 .bzl 檔案中，可確保 BUILD 檔案乾淨且宣告式，這樣就能從工作區中的任何套件載入 .bzl 檔案。

最後，在 path/generator.bzl 中編寫巨集的定義，封裝原始 Genrule 定義並參數化：

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

您也可以使用巨集將規則鏈結在一起。這個範例顯示鏈結的 Genrule，其中 Genrule 使用先前 Genrule 的輸出內容做為輸入內容：

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

這個範例只會將瀏覽權限值指派給第二個 Genrule。這樣一來，巨集作者就能隱藏中繼規則的輸出內容，以免受到工作區中的其他目標依賴。

展開巨集

如果您想要調查巨集的功能，請將 query 指令與 --output=build 搭配使用，以查看展開的形式：

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

將原生規則例項化

原生規則 (不需要 load() 陳述式的規則) 可透過原生模組執行個體化：

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

如果您需要知道套件名稱 (例如，哪一個 BUILD 檔案會呼叫巨集)，請使用 native.package_name() 函式。請注意，native 只能用於 .bzl 檔案，無法用於 WORKSPACE 或 BUILD 檔案。

巨集中的標籤解析度

由於巨集是在載入階段接受評估，因此系統會解讀巨集中發生的標籤字串 (例如 "//foo:bar")，而不是使用巨集的 BUILD 檔案進行解讀，而不是相對於定義巨集的 .bzl 檔案。這種行為通常不適合要在其他存放區中使用的巨集，例如其屬於已發布 Starlark 規則集的巨集。

如要取得與 Starlark 規則相同的行為，請使用 Label 建構函式納入標籤字串：

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main workspace, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

偵錯

  • bazel query --output=build //my/path:all 會顯示 BUILD 檔案在評估後的外觀。所有巨集、glob、迴圈已展開。已知限制：select 運算式目前未顯示在輸出內容中。

  • 您可以根據 generator_function (產生規則的函式) 或 generator_name (巨集的名稱屬性) 篩選輸出內容：bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'

  • 如要瞭解 foo 規則在 BUILD 檔案中產生的位置，您可以嘗試下列技巧。在 BUILD 檔案頂端附近插入這一行：cc_library(name = "foo")。執行 Bazel。規則 foo 建立時 (因為名稱衝突)，您會收到例外狀況，其中會顯示完整的堆疊追蹤。

  • 您也可以使用 print 進行偵錯。並在載入階段將訊息顯示為 DEBUG 記錄行。除非在極少數情況下，否則請移除 print 呼叫，或是在 debugging 參數 (預設為 False) 下進行條件式，再將程式碼提交至 Depot。

錯誤

如要擲回錯誤，請使用 fail 函式。向使用者清楚說明發生錯誤的原因，以及如何修正 BUILD 檔案。無法擷取錯誤。

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

慣例

  • 所有以底線開頭的公開函式 (不以底線開頭的函式) 都必須具有 name 引數。這個引數不應該是選用項目 (請勿提供預設值)。

  • 公開函式應使用遵循 Python 慣例的 docstring。

  • 在 BUILD 檔案中，巨集的 name 引數必須是關鍵字引數 (而非位置引數)。

  • 巨集產生的規則的 name 屬性應包含名稱引數做為前置字元。例如，macro(name = "foo") 可以產生 cc_library foo 和 Genrule foo_gen。

  • 在大多數情況下，選用參數應有預設值 None。None 可直接傳遞至原生規則，這就像您尚未在任何引數中傳遞一樣。因此，您不需要為此將其替換為 0、False 或 []。巨集應遵循所建立規則，因為預設值可能很複雜，或會隨時間而改變。此外，明確設為其預設值的參數，在透過查詢語言或建構系統內部存取時，該參數看起來會與從未設定 (或設為 None) 的參數不同。

  • 巨集應有選用的 visibility 引數。