本页面介绍了使用切面的基础知识和好处，并提供了简单和高级的示例。
您可以通过添加方面来增强 build 依赖关系图，并提供额外的信息和操作。切面可以使用的一些典型场景：
- 集成了 Bazel 的 IDE 可以使用切面来收集项目的相关信息。
- 代码生成工具可以利用切面，以与目标无关的方式对其输入执行。例如，
BUILD文件可以指定 protobuf 库定义的层次结构，而特定语言的规则可以使用切面来附加为特定语言生成 protobuf 支持代码的操作。
Aspect 基础知识
BUILD 文件提供项目源代码的说明：项目包含哪些源文件、应根据这些文件构建哪些工件（目标）、这些文件之间的依赖关系等等。Bazel 使用这些信息来执行构建，也就是说，它会确定生成工件所需的一组操作（例如运行编译器或链接器），并执行这些操作。为了实现此目的，Bazel 会在目标之间构建一个依赖关系图，并访问此图以收集这些操作。
请参考以下 BUILD 文件：
java_library(name = 'W', ...)
java_library(name = 'Y', deps = [':W'], ...)
java_library(name = 'Z', deps = [':W'], ...)
java_library(name = 'Q', ...)
java_library(name = 'T', deps = [':Q'], ...)
java_library(name = 'X', deps = [':Y',':Z'], runtime_deps = [':T'], ...)
此 BUILD 文件定义了下图所示的依赖关系图：
图 1. BUILD 文件依赖关系图。
Bazel 会分析此依赖关系图，方法是为上例中的每个目标调用相应规则（在本例中为“java_library”）的实现函数。规则实现函数会生成操作，用于构建工件（如 .jar 文件），并将信息（如这些工件的位置和名称）传递给提供程序中这些目标的反向依赖项。
方面与规则类似，因为它们具有可生成操作并返回提供程序的实现函数。不过，它们的强大功能来自为它们构建依赖关系图的方式。切面包含一个实现及其传播的所有属性的列表。假设有一个方面 A，它沿名为“deps”的属性进行传播。该切面可应用于目标 X，从而产生切面应用节点 A(X)。在应用期间，方面 A 以递归方式应用于 X 在其“deps”属性（A 的传播列表中的所有属性）中引用的所有目标。
因此，将切面 A 应用于目标 X 这一操作会生成目标的原始依赖关系图的“影子图”，如下图所示：
图 2. 利用切面构建图表。
唯一被覆盖的边缘是沿传播集中属性的边缘，因此在此示例中，runtime_deps 边缘不会被覆盖。然后，在影子图中的所有节点上调用切面实现函数，类似于在原始图的节点上调用规则实现的方式。
简单示例
此示例演示了如何递归输出规则及其所有具有 deps 属性的所有依赖项的源文件。其中显示了一个切面实现、一个切面定义，以及如何从 Bazel 命令行调用该切面。
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
我们把这个示例分成几个部分，逐一分析每个部分。
切面定义
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
方面定义与规则定义类似，都是使用 aspect 函数定义的。
就像规则一样，切面有一个实现函数，在本例中为 _print_aspect_impl。
attr_aspects 是规则属性列表，切面将沿该属性传播。在这种情况下，切面将沿其所应用到的规则的 deps 属性传播。
attr_aspects 的另一个常见参数是 ['*']，该参数会将参数传播到规则的所有属性。
Aspect 实现
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
方面实现函数与规则实现函数类似。它们会返回提供程序，可以生成操作，并采用两个参数：
实现函数可以通过 ctx.rule.attr 访问目标规则的属性。它可以检查由它的应用目标提供的提供程序（通过 target 参数）。
必须提供方面才能返回提供商列表。在此示例中，该切面不提供任何内容，因此返回一个空列表。
使用命令行调用切面
应用切面的最简单方法是使用 --aspects 参数从命令行运行。假设上述方面在名为 print.bzl 的文件中定义，如下所示：
bazel build //MyExample:example --aspects print.bzl%print_aspect
会将 print_aspect 应用于目标 example 以及可通过 deps 属性以递归方式访问的所有目标规则。
--aspects 标志接受一个参数，该参数是切面的规范，格式为 <extension file label>%<aspect top-level name>。
高级示例
以下示例演示了如何使用目标规则中的一个方面，该切面对目标中的文件进行计数，并可能会按扩展名对这些文件进行过滤。它展示了如何使用提供程序来返回值、如何使用参数将参数传递到切面实现中，以及如何从规则调用切面。
file_count.bzl 文件：
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
BUILD.bazel 文件：
load('//:file_count.bzl', 'file_count_rule')
cc_library(
name = 'lib',
srcs = [
'lib.h',
'lib.cc',
],
)
cc_binary(
name = 'app',
srcs = [
'app.h',
'app.cc',
'main.cc',
],
deps = ['lib'],
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
切面定义
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
以下示例展示了切面如何通过 deps 属性传播。
attrs 为一个切面定义一组属性。公共切面属性的类型为 string，称为参数。必须为参数指定 values 属性。此示例中有一个名为 extension 的参数，该参数可以使用“*”“h”或“cc”作为值。
切面的参数值从与请求切面的规则名称相同的字符串属性中获取（请参阅 file_count_rule 的定义）。不能通过命令行使用带参数的切面，因为没有用于定义参数的语法。
切面还可以具有 label 或 label_list 类型的私有属性。私有标签属性可用于指定执行切面生成的操作所需的工具或库的依赖关系。此示例中没有定义私有属性，但以下代码段展示了如何将工具传递给切面：
...
attrs = {
'_protoc' : attr.label(
default = Label('//tools:protoc'),
executable = True,
cfg = "exec"
)
}
...
Aspect 实现
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
与规则实现函数一样，切面实现函数会返回可供其依赖项访问的提供程序的结构。
在此示例中，FileCountInfo 被定义为具有一个字段 count 的提供程序。最佳做法是使用 fields 属性明确定义提供程序的字段。
方面应用 A(X) 的提供程序集由目标 X 的规则的实现和方面 A 的实现的提供程序所组成。规则实现传播的提供程序在应用切面之前创建并冻结，不能从某一方面进行修改。如果目标和应用于它的切面分别提供相同类型的提供程序，但 OutputGroupInfo（只要规则和切面指定不同的输出组，就会合并）和 InstrumentedFilesInfo（取自切面）除外，则会引发错误。这意味着，切面实现可能永远不会返回 DefaultInfo。
参数和 private 属性通过 ctx 的属性传递。此示例引用了 extension 参数并确定要统计的文件。
对于返回提供程序，传播切面（来自 attr_aspects 列表）的属性的值将替换为对其应用切面的应用结果。例如，如果目标 X 的依赖项中包含 Y 和 Z，则 A(X) 的 ctx.rule.attr.deps 将为 [A(Y), A(Z)]。在此示例中，ctx.rule.attr.deps 是 Target 对象，它是将切面应用于原始目标的“deps”的结果。
在该示例中，切面从目标的依赖项访问 FileCountInfo 提供程序以累积传递文件总数。
从规则中调用切面
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
规则实现演示了如何通过 ctx.attr.deps 访问 FileCountInfo。
规则定义演示了如何定义参数 (extension) 并为其提供默认值 (*)。请注意，由于对切面定义中的参数施加的限制，如果默认值不是“cc”“h”或“*”中的任何一个，都会出错。
通过目标规则调用切面
load('//:file_count.bzl', 'file_count_rule')
cc_binary(
name = 'app',
...
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
这演示了如何通过规则将 extension 参数传递给切面。由于 extension 参数在规则实现中具有默认值，因此 extension 将被视为可选参数。
构建 file_count 目标后，系统会自动评估切面，并且所有目标都可以通过 deps 以递归方式访问。