创建宏

假设您需要在构建过程中运行工具。例如,您可能希望生成或预处理源文件,或者压缩二进制文件。在本教程中,您将创建一个用于调整图片大小的宏。

宏适用于简单的任务。如果您想执行更复杂的操作,例如添加对新的编程语言的支持,请考虑创建规则。规则为您提供了更大的控制力和灵活性。

如需创建用于调整图片大小的宏,最简单的方法是使用 genrule

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

如果您需要调整更多图片的大小,则可能需要重复使用该代码。为此,请在单独的 .bzl 文件中定义函数,然后调用文件 miniature.bzl

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

备注:

  • 按照惯例,宏具有 name 参数,就像规则一样。

  • 如需记录宏的行为,请像在 Python 中那样使用 docstring

  • 要调用 genrule 或任何其他原生规则,请使用 native.

  • 使用 **kwargs 将额外的参数转发到底层 genrule(其工作原理与 Python 类似)。这很有用,因此用户可以使用 visibilitytags 等标准属性。

现在,使用 BUILD 文件中的宏:

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)