平台

Bazel 可以使用链接器和编译器等多种不同的构建工具,基于各种硬件、操作系统和系统配置构建和测试代码。为了帮助管理这种复杂性,Bazel 有一个概念叫做限制条件平台。限制条件是一个构建或生产环境可能不同的维度,例如 CPU 架构、是否存在 GPU,或系统安装的编译器的版本。平台是这些限制条件的命名集合,表示可在某些环境中使用的特定资源。

将环境建模为平台有助于 Bazel 自动为构建操作选择合适的工具链。平台还可以与 config_setting 规则结合使用,以编写可配置属性

Bazel 可识别平台可以充当的三种角色:

  • Host - 运行 Bazel 的平台。
  • Execution - 一个平台,构建工具可在该平台上执行构建操作,以生成中间输出和最终输出。
  • Target - 用于存放和执行最终输出的平台。

Bazel 支持下列与平台相关的构建场景:

  • 单平台 build(默认)- 托管平台、执行平台和目标平台相同。例如,在 Intel x64 CPU 上运行的 Ubuntu 上构建 Linux 可执行文件。

  • 交叉编译 build - 托管平台和执行平台相同,但目标平台不同。例如,在 MacBook Pro 上运行的 macOS 上构建 iOS 应用。

  • 多平台 build - 托管平台、执行平台和目标平台都是不同的。

定义限制条件和平台

通过在 BUILD 文件中使用 constraint_settingconstraint_value 规则来定义可能的平台选择空间。constraint_setting 可创建新维度,而 constraint_value 则可为给定维度创建新值;它们共同有效定义枚举及其可能的值。例如,BUILD 文件的以下代码段引入了针对系统的 glibc 版本的约束条件,包含两个可能的值。

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

您可以在工作区中的不同软件包中定义限制条件及其值。它们通过标签引用,并受到常规可见性控制的约束。如果可见性允许,您可以通过定义自己的值来扩展现有限制条件设置。

platform 规则引入了一个新的平台,该平台具有特定的限制条件值选择。以下代码会创建一个名为 linux_x86 的平台,并表示它描述了任何在 x86_64 架构上运行 Linux 操作系统且 glibc 版本为 2.25 的环境。(如需详细了解 Bazel 的内置限制条件,请参阅下文。)

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

通常有用的限制条件和平台

为了确保生态系统的一致性,Bazel 团队会维护一个代码库,其中含有最常见的 CPU 架构和操作系统的限制条件定义。这些示例均位于 https://github.com/bazelbuild/platforms 中。

Bazel 附带以下特殊的平台定义:@local_config_platform//:host。这是自动检测到的主机平台值,表示系统针对运行 Bazel 的系统自动检测到的平台。

为构建指定平台

您可以使用以下命令行标志为构建指定主机和目标平台:

  • --host_platform - 默认为 @bazel_tools//platforms:host_platform
  • --platforms - 默认为 @bazel_tools//platforms:target_platform

跳过不兼容的目标

在针对特定目标平台进行构建时,通常最好跳过那些永远无法在该平台上工作的目标。例如,在使用 //... 的 Linux 计算机上进行编译时,您的 Windows 设备驱动程序可能会生成大量的编译器错误。使用 target_compatible_with 属性告知 Bazel,您的代码具有哪些目标平台限制条件。

最简单的用法是将目标限制为单个平台。系统不会为任何不满足所有限制条件的平台构建目标。以下示例将 win_driver_lib.cc 限制为在 64 位 Windows 上运行。

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib 兼容在 64 位 Windows 系统上进行构建,而与其他所有组件不兼容。不兼容具有传递性。任何传递性依赖于不兼容目标的目标本身都被视为不兼容。

何时会跳过目标?

如果目标被视为不兼容,并作为目标模式扩展的一部分包含在 build 中,则会跳过。例如,以下两个调用会跳过在目标模式扩展中发现的任何不兼容的目标。

$ bazel build --platforms=//:myplatform //...
$ bazel build --platforms=//:myplatform //:all

同样,如果在命令行中使用 --expand_test_suites 指定 test_suite,则 test_suite 中不兼容的测试也会被跳过。换句话说,命令行中的 test_suite 目标的行为类似于 :all...。使用 --noexpand_test_suites 可以防止扩展,还会导致具有不兼容测试的 test_suite 目标也不兼容。

在命令行中明确指定不兼容的目标会导致错误消息和构建失败。

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

更具表现力的约束条件

为了更灵活地表示限制条件,请使用任何平台无法满足的 @platforms//:incompatible constraint_value

select()@platforms//:incompatible 结合使用可以表示更复杂的限制。例如,可以使用它来实现基本的 OR 逻辑。以下命令标记了一个与 macOS 和 Linux 兼容的库,但与其他平台不兼容。

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

上述内容可解释为:

  1. 以 macOS 为目标平台时,目标没有限制条件。
  2. 以 Linux 为目标平台时,目标没有限制条件。
  3. 否则,目标具有 @platforms//:incompatible 约束条件。由于 @platforms//:incompatible 不属于任何平台,因此目标被视为不兼容。

为了使约束条件更易于阅读,请使用 skylibselects.with_or()

您可以通过类似的方式表示反向兼容性。以下示例介绍了与除 ARM 以外的所有内容兼容的库。

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    ],
)

使用 bazel cquery 检测不兼容的目标

您可以使用 bazel cqueryStarlark 输出格式中的 IncompatiblePlatformProvider,将不兼容的目标与兼容的目标区分开来。

这可用于滤除不兼容的目标。以下示例将仅输出兼容的目标的标签。系统不会输出不兼容的目标。

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

已知问题

不兼容的目标会忽略可见性限制