BazelCon 2024 报名现已开放！

此页面由 Cloud Translation API 翻译。

Bazel 查询参考

报告问题查看源代码每夜 build · 8.0 . 7.4 。 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本页是 Bazel 查询语言的参考手册，供您在使用 bazel query 分析构建依赖项时参考。它还介绍了 bazel query 支持的输出格式。

如需了解实用用例，请参阅 Bazel 查询操作方法。

其他查询参考文档

除了在加载后阶段目标图上运行的 query 之外，Bazel 还包含操作图查询和可配置查询。

操作图查询

操作图查询 (aquery) 会对分析后的配置目标图进行操作，并公开有关操作、工件及其关系的信息。如果您对从已配置的目标图生成的操作/工件的属性感兴趣，aquery 会非常有用。例如，实际运行的命令及其输入、输出和助记符。

如需了解详情，请参阅 aquery 参考文档。

可配置的查询

传统的 Bazel 查询在加载后阶段的目标图上运行，因此不存在配置及其相关概念。值得注意的是，它无法正确解析 select 语句，而是会返回所有可能的 select 解析。不过，可配置的查询环境 cquery 会正确处理配置，但不提供此原始查询的所有功能。

如需了解详情，请参阅 cquery 参考文档。

示例

用户如何使用 bazel query？以下是一些典型示例：

为什么 //foo 树依赖于 //bar/baz？显示路径：

somepath(foo/..., //bar/baz:all)

所有 foo 测试都依赖于哪些 C++ 库，而 foo_bin 目标不依赖于这些库？

kind("cc_library", deps(kind(".*test rule", foo/...)) except deps(//foo:foo_bin))

令牌：词法语法

查询语言中的表达式由以下令牌组成：

关键字，例如 let。关键字是该语言的预留字，下面介绍了每种关键字。完整的关键字集如下：
- except
- in
- intersect
- let
- set
- union
字词，例如“foo/...”“.*test rule”或“//bar/baz:all”。如果字符序列是“带引号”（以英文单引号 ' 开头和结尾，或以英文双引号 " 开头和结尾），则属于字词。如果字符序列未加引号，系统可能仍会将其解析为一个字词。不带引号的字词是从字母 A-Za-z、数字 0-9 和特殊字符 */@.-_:$~[]（星号、正斜线、@、句号、连字符、下划线、冒号、美元符号、波浪线、左方括号、右方括号）中提取的字符序列。不过，不带英文引号的字词不得以连字符 - 或星号 * 开头，即使相对 [目标名称][(/concepts/labels#target-names) 可以以这些字符开头也是如此。

未加英文引号的字词也不得包含加号 + 或等号 = 字符，即使目标名称中允许使用这些字符也是如此。编写用于生成查询表达式的代码时，应对目标名称使用引号。

在编写用于根据用户提供的值构建 Bazel 查询表达式的脚本时，必须使用引号。
```
 //foo:bar+wiz    # WRONG: scanned as //foo:bar + wiz.
 //foo:bar=wiz    # WRONG: scanned as //foo:bar = wiz.
 "//foo:bar+wiz"  # OK.
 "//foo:bar=wiz"  # OK.
```
请注意，除了 shell 可能要求的任何引号之外，您还需要使用此引号，例如：
```
bazel query ' "//foo:bar=wiz" '   # single-quotes for shell, double-quotes for Bazel.
```
带引号的关键字会被视为普通字词。例如，some 是关键字，但“some”是字词。foo 和“foo”都是字词。

不过，在目标名称中使用单引号或双引号时，请务必小心。引用一个或多个目标名称时，请仅使用一种引号（全部使用单引号或全部使用双引号）。

以下是 Java 查询字符串的示例：
```
  'a"'a'         # WRONG: Error message: unclosed quotation.
  "a'"a"         # WRONG: Error message: unclosed quotation.
  '"a" + 'a''    # WRONG: Error message: unexpected token 'a' after query expression '"a" + '
  "'a' + "a""    # WRONG: Error message: unexpected token 'a' after query expression ''a' + '
  "a'a"          # OK.
  'a"a'          # OK.
  '"a" + "a"'    # OK
  "'a' + 'a'"    # OK
```
我们之所以选择这种语法，是为了让您在大多数情况下都无需使用引号。（不常见的）".*test rule" 示例需要引号：它以英文句号开头，并包含空格。引号 "cc_library" 是没有必要的，但无害。
标点符号，例如括号 ()、句号 . 和逗号 ,。包含标点符号的字词（上述例外情况除外）必须用引号括起来。

引号中文字以外的空格字符会被忽略。

Bazel 查询语言概念

Bazel 查询语言是一种表达式语言。每个表达式的计算结果都是目标的部分有序集，或等同于目标的图 (DAG)。这是唯一的数据类型。

“集合”和“图表”是指同一数据类型，但侧重点不同，例如：

集：目标的部分有序性不重要。
图表：目标的部分有序非常重要。

依赖关系图中的循环

构建依赖关系图应为无环图。

查询语言使用的算法适用于无环图，但对循环具有很强的鲁棒性。系统未指定如何处理周期的详细信息，因此不应依赖于这些信息。

隐式依赖项

除了在 BUILD 文件中明确定义的构建依赖项之外，Bazel 还会向规则添加其他隐式依赖项。例如，每个 Java 规则都隐式依赖于 JavaBuilder。使用以 $ 开头的属性建立隐式依赖项，并且无法在 BUILD 文件中替换这些依赖项。

默认情况下，bazel query 在计算查询结果时会将隐式依赖项考虑在内。您可以使用 --[no]implicit_deps 选项更改此行为。请注意，由于查询不会考虑配置，因此不会考虑潜在的工具链。

健全性

Bazel 查询语言表达式对构建依赖关系图进行操作，该图由所有 BUILD 文件中的所有规则声明隐式定义。请务必注意，此图表有些抽象，并不能完整说明如何执行构建的所有步骤。如需执行 build，还需要配置；如需了解详情，请参阅用户指南的配置部分。

在 Bazel 查询语言中评估表达式的结果对所有配置都为 true，这意味着该结果可能是保守的过度近似值，而不是完全精确的值。如果您使用查询工具计算构建期间所需的所有源文件集，则报告的文件数量可能会超出实际所需的数量，因为例如，查询工具会包含支持消息翻译所需的所有文件，即使您不打算在 build 中使用该功能也是如此。

关于图表顺序的保留

运算会保留从其子表达式继承的任何排序约束条件。您可以将其视为“部分有序的守恒定律”。举个例子：如果您发出查询来确定特定目标的依赖项的传递闭包，则生成的集合会按依赖项图排序。如果您过滤该集合，使其仅包含 file 类型的目标，则生成的子集中的每对目标之间都存在相同的传递部分有序关系，即使这些对目标在原始图中实际上并未直接连接也是如此。（构建依赖项图中没有文件到文件的边）。

不过，虽然所有运算符都会保留顺序，但某些运算（例如集合运算）不会引入任何自己的排序约束条件。请考虑以下表达式：

deps(x) union y

最终结果集的顺序保证会保留其子表达式的所有排序约束条件，即 x 的所有传递依赖项彼此之间具有正确的排序。不过，该查询无法保证 y 中的目标的排序，也无法保证 deps(x) 中的目标相对于 y 中的目标的排序（除了 y 中恰好也位于 deps(x) 中的目标外）。

引入排序约束条件的运算符包括：allpaths、deps、rdeps、somepath，以及目标模式通配符 package:*、dir/... 等。

Sky 查询

Sky 查询是一种在指定宇宙范围内运行的查询模式。

仅在 SkyQuery 中提供的特殊函数

Sky Query 模式具有额外的查询函数 allrdeps 和 rbuildfiles。这些函数在整个“宇宙”范围内运作（因此它们不适用于常规查询）。

指定“宇宙”范围

通过传递以下两个标志来启用 Sky Query 模式：(--universe_scope 或 --infer_universe_scope) 和 --order_output=no。--universe_scope=<target_pattern1>,...,<target_patternN> 会指示查询预加载目标模式（可以是加法模式，也可以是减法模式）指定的目标模式的传递闭包。然后，系统会在此“作用域”中评估所有查询。具体而言，allrdeps 和 rbuildfiles 运算符仅返回此范围内的结果。--infer_universe_scope 会指示 Bazel 根据查询表达式推断 --universe_scope 的值。此推断值是查询表达式中的唯一目标模式列表，但这可能不是您想要的。例如：

bazel query --infer_universe_scope --order_output=no "allrdeps(//my:target)"

此查询表达式中的唯一目标模式列表为 ["//my:target"]，因此 Bazel 会将其视为调用：

bazel query --universe_scope=//my:target --order_output=no "allrdeps(//my:target)"

但是，使用 --universe_scope 进行的查询的结果仅为 //my:target；由于构造方式，//my:target 的任何反向依赖项都不会出现在该宇宙中！另一方面，请考虑以下事项：

bazel query --infer_universe_scope --order_output=no "tests(//a/... + b/...) intersect allrdeps(siblings(rbuildfiles(my/starlark/file.bzl)))"

这是一个有意义的查询调用，它尝试计算某些目录下目标的 tests 展开中的测试目标，这些目标是传递依赖于定义使用特定 .bzl 文件的目标的目标。在这里，--infer_universe_scope 非常方便，尤其是在选择 --universe_scope 的情况下，您需要自行解析查询表达式。

因此，对于使用 allrdeps 和 rbuildfiles 等全局范围运算符的查询表达式，请务必仅在 --infer_universe_scope 的行为符合您的预期时使用 --infer_universe_scope。

与默认查询相比，Sky 查询有一些优点和缺点。主要缺点是，它无法按图表顺序对输出进行排序，因此禁止使用某些输出格式。它的优势在于，它提供了两个默认查询中不提供的运算符（allrdeps 和 rbuildfiles）。此外，Sky Query 会通过自省 Skyframe 图来执行其工作，而不是创建新图（默认实现会执行此操作）。因此，在某些情况下，它可以更快地运行，并且使用的内存更少。

表达式：语法的语法和语义

以下是 Bazel 查询语言的语法，采用 EBNF 表示法：

expr ::= word
       | let name = expr in expr
       | (expr)
       | expr intersect expr
       | expr ^ expr
       | expr union expr
       | expr + expr
       | expr except expr
       | expr - expr
       | set(word *)
       | word '(' int | word | expr ... ')'

以下各部分将按顺序介绍该语法的每个生成式。

目标模式

expr ::= word

从语法上讲，目标模式只是一个字词。它会被解释为一组（无序）目标。最简单的目标模式是标签，用于标识单个目标（文件或规则）。例如，目标模式 //foo:bar 会评估为包含一个元素（目标）的集合，即 bar 规则。

目标模式会对标签进行泛化，以便在软件包和目标上使用通配符。例如，foo/...:all（或仅 foo/...）是一个目标模式，其评估结果为包含 foo 目录下每个软件包中所有规则的集合；bar/baz:all 是一个目标模式，其评估结果为包含 bar/baz 软件包中所有规则（但不包括其子软件包）的集合。

同样，foo/...:* 是一个目标模式，其求值结果为包含 foo 目录下每个软件包中所有目标（规则和文件）的集合；bar/baz:* 的求值结果为包含 bar/baz 软件包中所有目标（但不包括其子软件包）的集合。

由于 :* 通配符可匹配文件和规则，因此在查询中，它通常比 :all 更实用。相反，:all 通配符（在 foo/... 等目标模式中隐式存在）通常更适用于 build。

bazel query 目标模式的运作方式与 bazel build 构建目标相同。如需了解详情，请参阅目标模式，或输入 bazel help target-syntax。

如果目标模式与任何目标都不匹配，则可能求值为单元素集（如果是标签），包含多个元素的集（如果是包含数千个元素的 foo/...），或者空集。

目标模式表达式的结果中的所有节点都根据依赖关系彼此正确排序。因此，foo:* 的结果不仅是软件包 foo 中的一组目标，也是这些目标的图。（我们不保证结果节点相对于其他节点的相对顺序。）如需了解详情，请参阅图表顺序部分。

变量

expr ::= let name = expr₁ in expr₂
       | $name

Bazel 查询语言允许定义和引用变量。let 表达式的求值结果与 expr₂ 的求值结果相同，其中变量 name 的所有自由出现都将替换为 expr₁ 的值。

例如，let v = foo/... in allpaths($v, //common) intersect $v 等同于 allpaths(foo/...,//common) intersect foo/...。

变量引用 name 出现在封闭 let name = ... 表达式之外的位置是错误的。换句话说，顶级查询表达式不能包含自由变量。

在上面的语法生成式中，name 类似于 word，但具有额外的约束条件，即它必须是 C 编程语言中的有效标识符。对变量的引用必须以“$”字符开头。

每个 let 表达式仅定义一个变量，但您可以嵌套这些变量。

目标模式和变量引用都仅由一个令牌（一个字词）组成，这会导致语法歧义。不过，不会出现语义歧义，因为合法变量名称的子集与合法目标模式的子集是互不相交的。

从技术层面来说，let 表达式不会增加查询语言的表达能力：该语言中可表达的任何查询都可以在不使用这些表达式的情况下表达。不过，它们可以提高许多查询的简洁性，还可能提高查询评估效率。

括号表达式

expr ::= (expr)

括号用于关联子表达式，以强制执行评估顺序。括号表达式会求值为其参数的值。

代数集运算：交集、并集、差集

expr ::= expr intersect expr
       | expr ^ expr
       | expr union expr
       | expr + expr
       | expr except expr
       | expr - expr

这三个运算符会对其参数计算常规的集合运算。每个运算符都有两种形式，即名词形式（例如 intersect）和符号形式（例如 ^）。这两种形式是等效的；符号形式的输入速度更快。（为方便起见，本页面的其余部分将使用名词形式。）

例如，

foo/... except foo/bar/...

的计算结果为与 foo/... 匹配但与 foo/bar/... 不匹配的一组目标。

您可以将相同的查询编写为：

foo/... - foo/bar/...

intersect (^) 和 union (+) 运算是可交换的（对称）；except (-) 是非对称的。解析器会将这三个运算符都视为左结合且优先级相同，因此您可能需要使用圆括号。例如，以下前两个表达式是等效的，但第三个表达式不等效：

x intersect y union z
(x intersect y) union z
x intersect (y union z)

从外部来源读取目标：set

expr ::= set(word *)

set(a b c ...) 运算符用于计算一组（零个或多个）目标模式的并集，这些模式之间由空格（而不是英文逗号）分隔。

结合使用 Bourne shell 的 $(...) 功能，set() 提供了一种将单个查询的结果保存在常规文本文件中的方法，使用其他程序（例如标准 UNIX shell 工具）操控该文本文件，然后将结果作为值重新引入查询工具以进行进一步处理。例如：

bazel query deps(//my:target) --output=label | grep ... | sed ... | awk ... > foo
bazel query "kind(cc_binary, set($(<foo)))"

在下一个示例中，kind(cc_library, deps(//some_dir/foo:main, 5)) 是通过使用 awk 程序过滤 maxrank 值计算得出的。

bazel query 'deps(//some_dir/foo:main)' --output maxrank | awk '($1 < 5) { print $2;} ' > foo
bazel query "kind(cc_library, set($(<foo)))"

在这些示例中，$(<foo) 是 $(cat foo) 的简写形式，但也可以使用 cat 以外的 Shell 命令，例如前面的 awk 命令。

函数

expr ::= word '(' int | word | expr ... ')'

该查询语言定义了多个函数。函数的名称决定了它所需参数的数量和类型。可使用以下函数：

allpaths
attr
buildfiles
rbuildfiles
deps
filter
kind
labels
loadfiles
rdeps
allrdeps
same_pkg_direct_rdeps
siblings
some
somepath
tests
visible

依赖项的传递闭包：deps

expr ::= deps(expr)
       | deps(expr, depth)

deps(x) 运算符的求值结果为由其参数集 x 的依赖项的传递闭包形成的图。例如，deps(//foo) 的值是根位于单个节点 foo 的依赖项图，包括其所有依赖项。deps(foo/...) 的值是依赖项图，其根是 foo 目录下每个软件包中的所有规则。在本上下文中，“依赖项”仅指规则和文件目标，因此创建这些目标所需的 BUILD 和 Starlark 文件不在此处包含。为此，您应使用 buildfiles 运算符。

生成的图会按依赖关系排序。如需了解详情，请参阅图表顺序部分。

deps 运算符接受一个可选的第二个参数，该参数是一个整数字面量，用于指定搜索深度的上限。因此，deps(foo:*, 0) 会返回 foo 软件包中的所有目标，而 deps(foo:*, 1) 还会进一步包含 foo 软件包中任何目标的直接前提条件，deps(foo:*, 2) 还会进一步包含可从 deps(foo:*, 1) 中的节点直接访问的节点，依此类推。（这些数字对应于 minrank 输出格式中显示的排名。）如果省略 depth 参数，则搜索将无限：它会计算前置条件的自反传递闭包。

反向依赖项的传递闭包：rdeps

expr ::= rdeps(expr, expr)
       | rdeps(expr, expr, depth)

rdeps(u, x) 运算符的求值结果为全局集 u 的传递闭包内参数集 x 的反向依赖项。

生成的图会按依赖关系排序。如需了解详情，请参阅图表顺序部分。

rdeps 运算符接受一个可选的第三个参数，该参数是一个整数字面量，用于指定搜索深度的上限。生成的图表仅包含与参数集中的任何节点相距指定深度的节点。因此，rdeps(//foo, //common, 1) 的求值结果为 //foo 的传递闭包中直接依赖于 //common 的所有节点。（这些数字对应于 minrank 输出格式中显示的排名。）如果省略 depth 参数，则搜索将无限期进行。

所有反向依赖项的传递闭包：allrdeps

expr ::= allrdeps(expr)
       | allrdeps(expr, depth)

allrdeps 运算符的行为与 rdeps 运算符完全相同，但“全集”是 --universe_scope 标志的评估结果，而不是单独指定的。因此，如果传递了 --universe_scope=//foo/...，则 allrdeps(//bar) 等同于 rdeps(//foo/..., //bar)。

同一软件包中的直接反向依赖项：same_pkg_direct_rdeps

expr ::= same_pkg_direct_rdeps(expr)

same_pkg_direct_rdeps(x) 运算符的求值结果是与参数集中的目标位于同一软件包中且直接依赖于该目标的全部目标。

处理目标的软件包：同级兄弟

expr ::= siblings(expr)

siblings(x) 运算符会评估为与参数集中的目标位于同一软件包中的一组完整目标。

任意选择：some

expr ::= some(expr)
       | some(expr, count )

some(x, k) 运算符会从其参数集 x 中任意选择最多 k 个目标，并求值为仅包含这些目标的集合。参数 k 是可选的；如果缺失，结果将是一个只包含一个任意选择的目标的单例集。如果参数集 x 的大小小于 k，则会返回整个参数集 x。

例如，表达式 some(//foo:main union //bar:baz) 的计算结果为包含 //foo:main 或 //bar:baz 的单例集，但未定义具体是哪个。表达式 some(//foo:main union //bar:baz, 2) 或 some(//foo:main union //bar:baz, 3) 会同时返回 //foo:main 和 //bar:baz。

如果实参是单例，则 some 会计算恒等函数：some(//foo:main) 等同于 //foo:main。

如果指定的参数集为空（如表达式 some(//foo:main intersect //bar:baz)），则会发生错误。

路径运算符：somepath、allpaths

expr ::= somepath(expr, expr)
       | allpaths(expr, expr)

somepath(S, E) 和 allpaths(S, E) 运算符用于计算两组目标之间的路径。这两个查询都接受两个参数，一个是起点集 S，另一个是终点集 E。somepath 会返回从 S 中的目标到 E 中的目标的某个任意路径上的节点图；allpaths 会返回从 S 中的任意目标到 E 中的任意目标的所有路径上的节点图。

生成的图表会按依赖关系排序。如需了解详情，请参阅图表顺序部分。

目标类型过滤：kind

expr ::= kind(word, expr)

kind(pattern, input) 运算符会对一组目标应用过滤条件，并舍弃不属于预期类型的目标。pattern 参数用于指定要匹配的目标类型。

例如，下表展示了 BUILD 文件（适用于软件包 p）定义的四个目标的类型：

代码	目标	种类
genrule( name = "a", srcs = ["a.in"], outs = ["a.out"], cmd = "...", )	`//p:a`	genrule 规则
	`//p:a.in`	源文件
	`//p:a.out`	生成的文件
	`//p:BUILD`	源文件

因此，kind("cc_.* rule", foo/...) 会评估为 foo 下的所有 cc_library、cc_binary 等规则目标的集合，而 kind("source file", deps(//foo)) 会评估为 //foo 目标依赖项的传递闭包中的所有源文件的集合。

通常需要对 pattern 参数进行引用，因为如果不进行引用，许多正则表达式（例如 source file 和 .*_test）都不会被解析器视为字词。

匹配 package group 时，以 :all 结尾的目标可能不会产生任何结果。请改用 :all-targets。

目标名称过滤：过滤

expr ::= filter(word, expr)

filter(pattern, input) 运算符会对一组目标应用过滤条件，并舍弃标签（以绝对形式）与模式不匹配的目标；其求值结果为其输入的一部分。

第一个参数 pattern 是一个字词，其中包含针对目标名称的正则表达式。filter 表达式的计算结果为包含所有目标 x 的集合，其中 x 是集合 input 的成员，并且 x 的标签（采用绝对形式，例如 //foo:bar）包含与正则表达式 pattern 的（未锚定）匹配项。由于所有目标名称都以 // 开头，因此它可以用作 ^ 正则表达式锚点的替代方案。

此运算符通常是 intersect 运算符的更快、更稳健的替代方案。例如，如需查看 //foo:foo 目标的所有 bar 依赖项，可以评估

deps(//foo) intersect //bar/...

不过，此语句需要解析 bar 树中的所有 BUILD 文件，这会导致速度缓慢，并且不相关的 BUILD 文件中也容易出错。另一种方法是：

filter(//bar, deps(//foo))

该命令会先计算一组 //foo 依赖项，然后仅过滤与所提供模式匹配的目标，也就是说，名称中包含 //bar 作为子字符串的目标。

filter(pattern, expr) 运算符的另一个常见用途是按名称或扩展名过滤特定文件。例如，

filter("\.cc$", deps(//foo))

将提供用于构建 //foo 的所有 .cc 文件的列表。

规则属性过滤：attr

expr ::= attr(word, word, expr)

attr(name, pattern, input) 运算符会对一组目标应用过滤条件，并舍弃非规则的目标、未定义属性 name 的规则目标，或属性值与所提供的正则表达式 pattern 不匹配的规则目标；它会评估为其输入的子集。

第一个参数 name 是规则属性的名称，应与提供的正则表达式模式进行匹配。第二个参数 pattern 是属性值的正则表达式。attr 表达式会求值为包含所有目标 x 的集合，其中 x 是集合 input 的成员，是具有已定义属性 name 的规则，并且属性值包含与正则表达式 pattern 的（未锚定）匹配项。如果 name 是可选属性，并且规则未明确指定该属性，则系统将使用默认属性值进行比较。例如，

attr(linkshared, 0, deps(//foo))

将选择允许具有 linkshared 属性的所有 //foo 依赖项（例如 cc_binary 规则），并将其明确设置为 0 或根本不设置，但默认值为 0（例如 cc_binary 规则）。

列表类型的属性（例如 srcs、data 等）会转换为 [value<sub>1</sub>, ..., value<sub>n</sub>] 格式的字符串，以 [ 括号开头，以 ] 括号结尾，并使用“,”（英文逗号、空格）来分隔多个值。系统会使用标签的绝对形式将标签转换为字符串。例如，属性 deps=[":foo", "//otherpkg:bar", "wiz"] 将转换为字符串 [//thispkg:foo, //otherpkg:bar, //thispkg:wiz]。括号始终存在，因此空列表将使用字符串值 [] 进行匹配。例如，

attr("srcs", "\[\]", deps(//foo))

将选择 //foo 依赖项中具有空 srcs 属性的所有规则，而

attr("data", ".{3,}", deps(//foo))

将从 //foo 依赖项中选择在 data 属性中指定至少一个值的所有规则（由于 // 和 :，每个标签的长度至少为 3 个字符）。

如需在列表类型属性中选择具有特定 value 的 //foo 依赖项中的所有规则，请使用

attr("tags", "[\[ ]value[,\]]", deps(//foo))

之所以能这样，是因为 value 前面的字符将是 [ 或空格，而 value 后面的字符将是逗号或 ]。

规则公开范围过滤：公开

expr ::= visible(expr, expr)

visible(predicate, input) 运算符会将过滤条件应用于一组目标，并舍弃不具有所需可见性的目标。

第一个参数 predicate 是一组目标，输出中的所有目标都必须对其可见。visible 表达式的求值结果为包含所有目标 x 的集合，其中 x 是集合 input 的成员，并且对于 predicate 中的所有目标 y，x 对 y 可见。例如：

visible(//foo, //bar:*)

将选择软件包 //bar 中 //foo 可以依赖的所有目标，且不会违反可见性限制。

对类型标签“标签”的规则属性的评估

expr ::= labels(word, expr)

labels(attr_name, inputs) 运算符会返回集合 inputs 中某个规则中类型为“标签”或“标签列表”的属性 attr_name 中指定的一组目标。

例如，labels(srcs, //foo) 会返回 //foo 规则的 srcs 属性中显示的一组目标。如果 inputs 集中有多个具有 srcs 属性的规则，则会返回其 srcs 的并集。

展开并过滤 test_suites: tests

expr ::= tests(expr)

tests(x) 运算符会返回集合 x 中的所有测试规则集，将任何 test_suite 规则展开为它们引用的各个测试集，并按 tag 和 size 应用过滤条件。

默认情况下，查询评估会忽略所有 test_suite 规则中的所有非测试目标。您可以使用 --strict_test_suite 选项将其更改为错误。

例如，查询 kind(test, foo:*) 会列出 foo 软件包中的所有 *_test 和 test_suite 规则。所有结果（根据定义）都是 foo 软件包的成员。与之相反，查询 tests(foo:*) 将返回 bazel test foo:* 将要执行的所有单个测试：这可能包括通过 test_suite 规则直接或间接引用的其他软件包中的测试。

软件包定义文件：buildfile

expr ::= buildfiles(expr)

buildfiles(x) 运算符会返回用于定义集 x 中每个目标的软件包的一组文件；换句话说，对于每个软件包，其 BUILD 文件以及它通过 load 引用的所有 .bzl 文件。请注意，这还会返回包含这些 load 文件的软件包的 BUILD 文件。

此运算符通常用于确定构建指定目标所需的文件或软件包，通常与 --output package 选项（见下文）结合使用。例如，

bazel query 'buildfiles(deps(//foo))' --output package

返回 //foo 传递依赖的所有软件包的集合。

软件包定义文件：rbuildfiles

expr ::= rbuildfiles(word, ...)

rbuildfiles 运算符接受以逗号分隔的路径片段列表，并返回对这些路径片段有传递依赖关系的一组 BUILD 文件。例如，如果 //foo 是软件包，则 rbuildfiles(foo/BUILD) 将返回 //foo:BUILD 目标。如果 foo/BUILD 文件包含 load('//bar:file.bzl'...，则 rbuildfiles(bar/file.bzl) 将返回 //foo:BUILD 目标，以及加载 //bar:file.bzl 的任何其他 BUILD 文件的目标

rbuildfiles 运算符的范围是 --universe_scope 标志指定的宇宙。与 BUILD 文件和 .bzl 文件不直接对应的文件不会影响结果。例如，源文件（如 foo.cc）会被忽略，即使它们在 BUILD 文件中明确提及也是如此。不过，系统会遵循符号链接，因此如果 foo/BUILD 是指向 bar/BUILD 的符号链接，则 rbuildfiles(bar/BUILD) 会在其结果中包含 //foo:BUILD。

rbuildfiles 运算符在逻辑上几乎与 buildfiles 运算符相反。不过，这种道德倒转在一个方向上更为明显：rbuildfiles 的输出与 buildfiles 的输入一样；前者仅在软件包中包含 BUILD 文件目标，而后者可能会包含此类目标。在另一个方向上，这种对应关系较弱。buildfiles 运算符的输出是与所有软件包和 .给定输入所需的 bzl 文件。不过，rbuildfiles 运算符的输入不是这些目标，而是与这些目标对应的路径片段。

软件包定义文件：loadfile

expr ::= loadfiles(expr)

loadfiles(x) 运算符会返回一组 Starlark 文件，这些文件用于加载集合 x 中的每个目标的软件包。换句话说，对于每个软件包，它都会返回从其 BUILD 文件引用的 .bzl 文件。

输出格式

bazel query 会生成一个图表。您可以使用 --output 命令行选项指定 bazel query 呈现此图表的内容、格式和排序。

使用 Sky Query 运行时，仅允许与无序输出兼容的输出格式。具体来说，禁止使用 graph、minrank 和 maxrank 输出格式。

某些输出格式接受额外的选项。每个输出选项的名称都带有适用的输出格式前缀，因此 --graph:factored 仅在使用 --output=graph 时才适用；如果使用 graph 以外的输出格式，则不会产生任何影响。同样，--xml:line_numbers 仅在使用 --output=xml 时适用。

关于结果的排序

虽然查询表达式始终遵循“图表有序性守恒定律”，但呈现结果可以按依赖项顺序或无序方式进行。这不会影响结果集中的目标或查询的计算方式。它只会影响将结果输出到标准输出流的方式。此外，在依赖项顺序中等效的节点不一定按字母顺序排序。--order_output 标志可用于控制此行为。（--[no]order_results 标志具有 --order_output 标志的部分功能，并且已废弃。）

此标志的默认值为 auto，表示按字典顺序输出结果。不过，使用 somepath(a,b) 时，结果将改为按 deps 顺序输出。

如果此标志为 no，并且 --output 为 build、label、label_kind、location、package、proto 或 xml 之一，则输出将按任意顺序输出。这通常是最快的选项。不过，如果 --output 为 graph、minrank 或 maxrank 之一，则不支持此功能：在这些格式下，Bazel 始终会按依赖项顺序或排名输出结果。

当此标志为 deps 时，Bazel 会按某种拓扑顺序输出结果，即先输出依赖项。不过，按依赖项顺序未排序的节点（因为没有从一个节点到另一个节点的路径）可以按任何顺序输出。

当此标志为 full 时，Bazel 会按完全确定性（总体）顺序输出节点。首先，所有节点都会按字母顺序排序。然后，列表中的每个节点都用作后序深度优先搜索的起点，在这种搜索中，系统会按后继节点的字母顺序遍历指向未访问节点的出边。最后，节点会按访问顺序的反向顺序输出。

按此顺序输出节点的速度可能会较慢，因此仅应在确定性很重要时使用此方法。

按 BUILD 中显示的方式输出目标的源代码形式

--output build

使用此选项时，每个目标的表示方式就像是用 BUILD 语言手写的一样。所有变量和函数调用（例如全局正则表达式、宏）都会展开，这对于查看 Starlark 宏的效果非常有用。此外，每个有效规则都会报告 generator_name 和/或 generator_function 值，提供用于生成有效规则的宏的名称。

虽然输出使用与 BUILD 文件相同的语法，但无法保证生成有效的 BUILD 文件。

输出每个目标的标签

--output label

使用此选项时，系统会按拓扑顺序输出生成图中每个目标的一组名称（或标签），每行一个标签（除非指定了 --noorder_results，请参阅有关结果排序的备注）。（拓扑排序是指图节点出现在其所有后继节点之前的排序。）当然，图有许多可能的拓扑排序（逆后序只是其中之一）；未指定选择哪种排序。

输出 somepath 查询的输出时，节点的输出顺序是路径的顺序。

注意：在某些极端情况下，可能有两个具有相同标签的不同目标；例如，一个 sh_binary 规则及其唯一的（隐式）srcs 文件都可能被称为 foo.sh。如果查询的结果包含这两个目标，输出（采用 label 格式）将看起来包含重复项。使用 label_kind 格式（见下文）时，区别就很明显了：两个目标具有相同的名称，但一个的类型为 sh_binary rule，另一个的类型为 source file。

输出每个目标的标签和类型

--output label_kind

与 label 一样，此输出格式会按拓扑顺序输出生成图中的每个目标的标签，但它还会在标签前面添加目标的类型。

按排名顺序输出每个目标的标签

--output minrank --output maxrank

与 label 一样，minrank 和 maxrank 输出格式会输出生成图中每个目标的标签，但它们的显示顺序不是按拓扑顺序，而是按排名顺序，前面带有排名编号。这些结果不受结果排序 --[no]order_results 标志的影响（请参阅关于结果排序的注意事项）。

此格式有两个变体：minrank 会按从根节点到每个节点的最短路径长度对每个节点进行排名。“根”节点（没有入边的节点）的排名为 0，其后继节点的排名为 1，依此类推（与往常一样，边从目标指向其前提条件：即目标所依赖的目标）。

maxrank 会按从根节点到该节点的最长路径长度对每个节点进行排名。再次说明，“根”的排名为 0，所有其他节点的排名都比其所有前驱的最大排名大 1。

一个周期中的所有节点都被视为具有相同的等级。（大多数图表都是无环的，但循环确实会发生，只因 BUILD 文件包含错误的循环。）

这些输出格式有助于了解图的深度。如果用于 deps(x)、rdeps(x) 或 allpaths 查询的结果，则排名编号等于从 x 到该排名中的某个节点的最短路径（使用 minrank）或最长路径（使用 maxrank）的长度。maxrank 可用于确定构建目标所需的最长构建步骤序列。

例如，当分别指定 --output minrank 和 --output maxrank 时，左侧的图表会生成右侧的输出。

      minrank

      0 //c:c
      1 //b:b
      1 //a:a
      2 //b:b.cc
      2 //a:a.cc

      maxrank

      0 //c:c
      1 //b:b
      2 //a:a
      2 //b:b.cc
      3 //a:a.cc

输出每个目标的位置

--output location

与 label_kind 一样，此选项会针对结果中的每个目标输出目标的类型和标签，但其前缀是一个字符串，用于描述该目标的位置（文件名和行号）。格式类似于 grep 的输出。因此，可以解析后者（例如 Emacs 或 vi）的工具也可以使用查询输出来逐个查看一系列匹配项，从而允许将 Bazel 查询工具用作感知依赖项图的“grep for BUILD files”。

位置信息因目标类型而异（请参阅 kind 运算符）。对于规则，系统会输出规则声明在 BUILD 文件中的位置。对于源文件，系统会输出实际文件第 1 行的所在位置。对于生成的文件，系统会输出生成该文件的规则的位置。（查询工具没有足够的信息来查找生成文件的实际位置，并且在任何情况下，如果尚未执行 build，该文件都可能不存在。）

打印一组软件包

--output package

此选项会输出结果集中某个目标所属的所有软件包的名称。名称会按字典顺序输出；重复项会被排除。从形式上讲，这是一种从一组标签（软件包、目标）投影到软件包的投影。

外部代码库中的软件包采用 @repo//foo/bar 格式，而主代码库中的软件包采用 foo/bar 格式。

此输出选项可与 deps(...) 查询结合使用，用于查找必须检出的软件包集，以便构建给定的一组目标。

显示结果图表

--output graph

此选项会导致查询结果以流行的 AT&T GraphViz 格式输出为有向图。通常，结果会保存到文件（例如 .png 或 .svg）。（如果您的工作站上未安装 dot 程序，您可以使用 sudo apt-get install graphviz 命令进行安装。）请参阅下文的示例部分，查看示例调用。

此输出格式对于 allpaths、deps 或 rdeps 查询特别有用，因为在这种情况下，结果包含一组路径，如果以线性形式（例如使用 --output label）呈现，则无法轻松直观地呈现。

默认情况下，图表会以分解形式呈现。也就是说，拓扑等效的节点会合并到具有多个标签的单个节点中。这会使图表更紧凑且更易于阅读，因为典型的结果图表包含高度重复的模式。例如，一个 java_library 规则可能依赖于由同一 genrule 生成的数百个 Java 源文件；在分解图中，所有这些文件都由一个节点表示。您可以使用 --nograph:factored 选项停用此行为。

`--graph:node_limit n`

此选项用于指定输出中图表节点的标签字符串的最大长度。较长的标签会被截断；-1 会停用截断功能。由于图通常以分解形式输出，因此节点标签可能会非常长。GraphViz 无法处理超过 1024 个字符的标签，这是此选项的默认值。除非正在使用 --output=graph，否则此选项无效。

`--[no]graph:factored`

默认情况下，图表会以分解形式显示，如上文所述。指定 --nograph:factored 后，系统会在不分解的情况下输出图表。这使得使用 GraphViz 进行可视化不切实际，但更简单的格式可能会简化其他工具（例如 grep）的处理。除非使用 --output=graph，否则此选项无效。

XML

--output xml

此选项会导致生成的目标以 XML 形式输出。输出以 XML 标头开头，如下所示

  <?xml version="1.0" encoding="UTF-8"?>
  <query version="2">

然后，继续在结果图中为每个目标添加 XML 元素，并按拓扑顺序排列（除非请求无序结果），最后以终止

</query>

系统会针对 file 类型的目标发出简单条目：

  <source-file name='//foo:foo_main.cc' .../>
  <generated-file name='//foo:libfoo.so' .../>

但对于规则，XML 是结构化的，并且包含规则的所有属性的定义，包括在规则的 BUILD 文件中未明确指定值的属性。

此外，结果还包含 rule-input 和 rule-output 元素，以便重建依赖项图的拓扑结构，而无需知道，例如 srcs 属性的元素是前向依赖项（前提条件），而 outs 属性的内容是后向依赖项（使用方）。

如果指定了 --noimplicit_deps，系统会抑制隐式依赖项的 rule-input 元素。

  <rule class='cc_binary rule' name='//foo:foo' ...>
    <list name='srcs'>
      <label value='//foo:foo_main.cc'/>
      <label value='//foo:bar.cc'/>
      ...
    </list>
    <list name='deps'>
      <label value='//common:common'/>
      <label value='//collections:collections'/>
      ...
    </list>
    <list name='data'>
      ...
    </list>
    <int name='linkstatic' value='0'/>
    <int name='linkshared' value='0'/>
    <list name='licenses'/>
    <list name='distribs'>
      <distribution value="INTERNAL" />
    </list>
    <rule-input name="//common:common" />
    <rule-input name="//collections:collections" />
    <rule-input name="//foo:foo_main.cc" />
    <rule-input name="//foo:bar.cc" />
    ...
  </rule>

每个目标的 XML 元素都包含一个 name 属性（其值为目标的标签）和一个 location 属性（其值为 --output location 输出的目标位置）。

`--[no]xml:line_numbers`

默认情况下，XML 输出中显示的位置包含行号。指定 --noxml:line_numbers 时，系统不会输出行号。

`--[no]xml:default_values`

默认情况下，XML 输出不包含值为该类型属性的默认值的规则属性（例如，如果未在 BUILD 文件中指定该值，或者明确提供了默认值）。此选项会导致此类属性值包含在 XML 输出中。

正则表达式

查询语言中的正则表达式使用 Java 正则表达式库，因此您可以使用 java.util.regex.Pattern 的完整语法。

使用外部代码库进行查询

如果 build 依赖于外部代码库中的规则（在 WORKSPACE 文件中定义），则查询结果将包含这些依赖项。例如，如果 //foo:bar 依赖于 //external:some-lib，而 //external:some-lib 绑定到 @other-repo//baz:lib，则 bazel query 'deps(//foo:bar)' 会将 @other-repo//baz:lib 和 //external:some-lib 都列为依赖项。

外部代码库本身不是 build 的依赖项。也就是说，在上面的示例中，//external:other-repo 不是依赖项。不过，您可以将其作为 //external 软件包的成员进行查询，例如：

  # Querying over all members of //external returns the repository.
  bazel query 'kind(http_archive, //external:*)'
  //external:other-repo

  # ...but the repository is not a dependency.
  bazel query 'kind(http_archive, deps(//foo:bar))'
  INFO: Empty results