一般的な C++ ビルドのユースケース

ここでは、Bazel を使用して C++ プロジェクトをビルドする最も一般的なユースケースをいくつか紹介します。まだ行っていない場合は、Bazel の概要: C++ プロジェクトをビルドするチュートリアルを完了して、Bazel で C++ プロジェクトのビルドを開始します。

cc_library と hdrs ヘッダーファイルの詳細については、cc_library をご覧ください。

ターゲットに複数のファイルを含める

glob を使用して、1 つのターゲットに複数のファイルを含めることができます。例:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

このターゲットを使用すると、Bazel は、このターゲットを含む BUILD ファイルと同じディレクトリ（サブディレクトリを除く）で見つかったすべての .cc ファイルと .h ファイルをビルドします。

伝播インクルードの使用

ファイルにヘッダーが含まれている場合、そのファイルをソースとするルール（つまり、srcs、hdrs、または textual_hdrs 属性にそのファイルが含まれているルール）は、含まれているヘッダーのライブラリルールに依存する必要があります。逆に、依存関係として指定する必要があるのは直接的な依存関係のみです。たとえば、sandwich.h に bread.h が含まれ、bread.h に flour.h が含まれているとします。sandwich.h には flour.h が含まれていません（サンドイッチに小麦粉を入れたい人はいないでしょう）。そのため、BUILD ファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここで、sandwich ライブラリは、flour ライブラリに依存する bread ライブラリに依存します。

インクルードパスの追加

ワークスペースのルートでインクルードパスをルート化できない（またはルート化したくない）場合があります。既存のライブラリには、ワークスペース内のパスと一致しないインクルードディレクトリがすでに存在している可能性があります。たとえば、ディレクトリ構造が次のとおりであるとします。

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── MODULE.bazel

Bazel は some_lib.h が legacy/some_lib/include/some_lib.h として含まれていることを想定していますが、some_lib.cc に "some_lib.h" が含まれているとします。このインクルードパスを有効にするには、legacy/some_lib/BUILD で、some_lib/include ディレクトリがインクルードディレクトリであることを指定する必要があります。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

これは、ヘッダーファイルに / 接頭辞を付けて含める必要がある外部依存関係で特に便利です。

外部ライブラリを含める

Google Test {: .external} を使用しているとします。MODULE.bazel ファイルに依存関係を追加して、Google Test をダウンロードし、リポジトリで利用できるようにすることができます。

bazel_dep(name = "googletest", version = "1.15.2")

C++ テストの作成と実行

たとえば、次のようにテスト用の ./test/hello-test.cc を作成できます。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

次に、テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    deps = [
        "@googletest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test に表示するには、./main/BUILD の visibility 属性に "//test:__pkg__", を追加する必要があります。

これで、bazel test を使用してテストを実行できます。

bazel test test:hello-test

出力は次のようになります。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

事前コンパイル済みライブラリの依存関係を追加する

コンパイル済みバージョンのみが存在するライブラリ（ヘッダーや .so ファイルなど）を使用する場合は、それを cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

これにより、ワークスペース内の他の C++ ターゲットがこのルールに依存できるようになります。