常见 C++ build 使用场景

报告问题 查看源代码

在这里,您将发现使用 Bazel 构建 C++ 项目的一些最常见用例。如果您尚未使用 Bazel 构建 C++ 项目,请先完成 Bazel 简介:构建 C++ 项目教程。

如需了解 cc_library 和 hdrs 头文件,请参阅 cc_library

在目标中包含多个文件

您可以使用 glob 在单个目标中包含多个文件。例如:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

使用此目标时,Bazel 将在包含此目标的 BUILD 文件所在的目录中构建找到的所有 .cc.h 文件(子目录除外)。

使用传递包含

如果文件包含标头,则以该文件作为来源的任何规则(即在 srcshdrstextual_hdrs 属性中包含该文件)都应依赖于所包含头文件的库规则。相反,只有直接依赖项需要指定为依赖项。例如,假设 sandwich.h 包含 bread.h,而 bread.h 包含 flour.hsandwich.h 不包含 flour.h(谁想在三明治中添加面粉?),因此 BUILD 文件将如下所示:

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

在这里,sandwich 库依赖于 bread 库,而后者依赖于 flour 库。

添加包含路径

有时,您不能(或不想)在工作区根目录中生成根 include 路径。现有库可能已具有与其在工作区中的路径不匹配的 include 目录。例如,假设您具有以下目录结构:

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel 会将 some_lib.h 包含为 legacy/some_lib/include/some_lib.h,但假设 some_lib.cc 包含 "some_lib.h"。如需使该 include 路径有效,legacy/some_lib/BUILD 需要将 some_lib/include 目录指定为 include 目录:

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

这对于外部依赖项尤其有用,因为其头文件必须以其他方式包含 / 前缀。

包含外部库

假设您正在使用 Google Test {: .external}。您可以使用 WORKSPACE 文件中的其中一个代码库函数下载 Google Test 并使其在您的代码库中可用:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

然后,创建 gtest.BUILD,这是用于编译 Google Test 的 BUILD 文件。Google Test 有几项“特殊”要求,这使其 cc_library 规则变得更加复杂:

  • googletest-release-1.10.0/googletest/src/gtest-all.cc 会对 googletest-release-1.10.0/googletest/src/ 中的所有其他文件执行 #include 操作:将其从编译中排除,以防止出现重复符号的链接错误。

  • 它使用相对于 googletest-release-1.10.0/googletest/include/ 目录 ("gtest/gtest.h") 的头文件,因此您必须将该目录添加到 include 路径中。

  • 它需要关联 pthread,因此请将其添加为 linkopt

因此,最终规则如下所示:

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/googletest/src/*.cc"],
        exclude = ["googletest-release-1.10.0/googletest/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/googletest/include/**/*.h",
        "googletest-release-1.10.0/googletest/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/googletest/include",
        "-Iexternal/gtest/googletest-release-1.10.0/googletest"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

这有点混乱:所有内容都以 googletest-release-1.10.0 为前缀,这是归档文件结构的副产物。您可以通过添加 strip_prefix 属性让 http_archive 去除此前缀:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

那么 gtest.BUILD 将如下所示:

cc_library(
    name = "main",
    srcs = glob(
        ["googletest/src/*.cc"],
        exclude = ["googletest/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest/include/**/*.h",
        "googletest/src/*.h"
    ]),
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

现在,cc_ 规则可以依赖于 @gtest//:main

编写和运行 C++ 测试

例如,您可以创建如下所示的测试 ./test/hello-test.cc

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

然后,为您的测试创建 ./test/BUILD 文件:

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = [
      "-Iexternal/gtest/googletest/include",
      "-Iexternal/gtest/googletest",
    ],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

如需使 hello-greethello-test 可见,您必须将 "//test:__pkg__", 添加到 ./main/BUILD 中的 visibility 属性。

现在,您可以使用 bazel test 来运行测试。

bazel test test:hello-test

这会生成以下输出:

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

添加对预编译库的依赖项

如果您要使用只有已编译版本的库(例如头文件和 .so 文件),请将其封装在 cc_library 规则中:

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

这样,工作区中的其他 C++ 目标就可能依赖于此规则。