このチュートリアルでは、サンプル シナリオを使用して、プロジェクトに C++ ツールチェーンを構成する方法について説明します。
学習内容
このチュートリアルでは、次の方法を学習します。
- ビルド環境をセットアップする
--toolchain_resolution_debug
を使用してツールチェーンの解決をデバッグする- C++ ツールチェーンを構成する
- Bazel が
clang
を使用してアプリケーションをビルドできるように、cc_toolchain
の追加構成を提供する Starlark ルールを作成します。 - Linux マシンで
bazel build //main:hello-world
を実行して C++ バイナリをビルドする bazel build //main:hello-world --platforms=//:android_x86_64
を実行して、Android 用のバイナリをクロスコンパイルします。
始める前に
このチュートリアルでは、Linux を使用していて、C++ アプリケーションを正常にビルドし、適切なツールとライブラリがインストールされていることを前提としています。このチュートリアルでは、システムにインストールできる clang version 16
を使用します。
ビルド環境をセットアップする
ビルド環境を次のようにセットアップします。
まだ行っていない場合は、Bazel 7.0.2 以降をダウンロードしてインストールします。
ルートフォルダに空の
WORKSPACE
ファイルを追加します。次の
cc_binary
ターゲットをmain/BUILD
ファイルに追加します。load("@rules_cc//cc:defs.bzl", "cc_binary") cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )
Bazel はビルド中に C++ で記述された多くの内部ツール(
process-wrapper
など)を使用するため、既存のデフォルトの C++ ツールチェーンがホスト プラットフォームに指定されます。これにより、これらの内部ツールは、このチュートリアルで作成したツールチェーンのツールチェーンを使用してビルドできるようになります。したがって、cc_binary
ターゲットもデフォルトのツールチェーンでビルドされます。次のコマンドを使用してビルドを実行します。
bazel build //main:hello-world
WORKSPACE
にツールチェーンが登録されていない場合にビルドが成功します。内部の詳細を確認するには、次のコマンドを実行します。
bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type' INFO: ToolchainResolution: Target platform @@local_config_platform//:host: Selected execution platform @@local_config_platform//:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools~cc_configure_extension~local_config_cc//:cc-compiler-k8
--platforms
を指定せずに、Bazel は@bazel_tools//cc_configure_extension/local_config_cc//:cc-compiler-k8
を使用して@local_config_platform//:host
のターゲットをビルドします。
C++ ツールチェーンを構成する
C++ ツールチェーンを構成するには、次のように、アプリケーションを繰り返しビルドし、エラーを 1 つずつ除去します。
また、clang version 9.0.1
も前提としていますが、clang のバージョンが異なれば詳細が少し変わるだけです。
toolchain/BUILD
の追加方法filegroup(name = "empty") cc_toolchain( name = "linux_x86_64_toolchain", toolchain_identifier = "linux_x86_64-toolchain", toolchain_config = ":linux_x86_64_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, ) toolchain( name = "cc_toolchain_for_linux_x86_64", toolchain = ":linux_x86_64_toolchain", toolchain_type = "@bazel_tools//tools/cpp:toolchain_type", exec_compatible_with = [ "@platforms//cpu:x86_64", "@platforms//os:linux", ], target_compatible_with = [ "@platforms//cpu:x86_64", "@platforms//os:linux", ], )
次に、
WORKSPACE
を使用してツールチェーンを登録します。register_toolchains( "//toolchain:cc_toolchain_for_linux_x86_64" )
このステップでは、
cc_toolchain
を定義し、ホスト構成のtoolchain
ターゲットにバインドします。ビルドを再度実行します。
toolchain
パッケージはまだlinux_x86_64_toolchain_config
ターゲットを定義していないため、Bazel は次のエラーをスローします。ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.
toolchain/BUILD
ファイルで、次のように空のファイルグループを定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "linux_x86_64_toolchain_config")
ビルドを再度実行します。Bazel から次のエラーがスローされます。
'//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.
CcToolchainConfigInfo
は、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容のtoolchain/cc_toolchain_config.bzl
ファイルを作成して、Bazel にCcToolchainConfigInfo
を提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )
cc_common.create_cc_toolchain_config_info()
は、必要なプロバイダCcToolchainConfigInfo
を作成します。cc_toolchain_config
ルールを使用するには、package ステートメントのすぐ下のtoolchain/BUILD
に load ステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")
「linux_x86_64_ツールチェーン_config」ファイルグループを
cc_toolchain_config
ルールの宣言に置き換えます。cc_toolchain_config(name = "linux_x86_64_toolchain_config")
ビルドを再度実行します。Bazel から次のエラーがスローされます。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`
この時点で、Bazel はコードのビルドを試行するのに十分な情報を持っていますが、必要なビルド アクションの実行に使用するツールはまだわかりません。Starlark ルールの実装を変更して、使用するツールを Bazel に指示します。そのためには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl
の tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )
/usr/bin/clang
と/usr/bin/ld
は、システムの正しいパスにしてください。ビルドを再度実行します。Bazel から次のエラーがスローされます。
ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world': the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain): '/usr/include/c++/13/ctime' '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h' ...
Bazel は、含まれるヘッダーの検索場所を認識する必要があります。この問題は、
cc_binary
のincludes
属性など、複数の方法で解決できます。ここでは、ツールチェーン レベルでcc_common.create_cc_toolchain_config_info
のcxx_builtin_include_directories
パラメータを使用して解決しています。別のバージョンのclang
を使用している場合は、インクルード パスが異なることに注意してください。これらのパスは、ディストリビューションに応じて異なる場合もあります。toolchain/cc_toolchain_config.bzl
の戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-16/lib/clang/16/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )
ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'
これは、リンカーに C++ 標準ライブラリがなく、シンボルが見つからないためです。この問題は、
cc_binary
のlinkopts
属性など、さまざまな方法で解決できます。この問題は、ツールチェーンを使用するターゲットでこのフラグを指定する必要がないようにすることで解決します。次のコードを
toolchain/cc_toolchain_config.bzl
にコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", # NEW "flag_group", # NEW "flag_set", # NEW "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )
bazel build //main:hello-world
を実行すると、最終的にホストのバイナリが正常にビルドされます。toolchain/BUILD
で、cc_toolchain_config
、cc_toolchain
、toolchain
のターゲットをコピーし、ターゲット名のlinux_x86_64
をandroid_x86_64
に置き換えます。WORKSPACE
で、Android 用のツールチェーンを登録します。register_toolchains( "//toolchain:cc_toolchain_for_linux_x86_64", "//toolchain:cc_toolchain_for_android_x86_64" )
bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64
を実行して Android のバイナリをビルドします。
実際には、Linux と Android では異なる C++ ツールチェーン設定を使用する必要があります。相違点に応じて既存の cc_toolchain_config
を変更するか、プラットフォームごとに別個のルール(CcToolchainConfigInfo
プロバイダ)を作成します。
課題を確認する
このチュートリアルでは、基本的な C++ ツールチェーンの構成方法を学習しましたが、ツールチェーンはこの単純な例よりも強力です。
重要なポイントは次のとおりです。
- Bazel がプラットフォーム上の同じ制約値のツールチェーンに解決されるようにするには、コマンドラインで一致する
platforms
フラグを指定する必要があります。言語固有の構成フラグの詳細については、ドキュメントをご覧ください。 - ツールチェーンにツールの場所を伝える必要があります。このチュートリアルでは、簡略化されたバージョンでシステムからツールにアクセスします。自己完結型のアプローチに関心をお持ちの場合は、ワークスペースをご覧ください。別のワークスペースのツールを使用している場合、そのファイルを
cc_toolchain
で使用可能にし、compiler_files
などの属性に対するターゲット依存関係を指定する必要があります。tool_paths
も変更する必要があります。 - 機能を作成して、リンクやその他のアクションなど、さまざまなアクションに渡すフラグをカスタマイズできます。
関連情報
詳しくは、C++ ツールチェーンの構成をご覧ください。