このチュートリアルでは、サンプル シナリオを使用して、C++ ツールチェーンを構築しました。
学習内容
このチュートリアルでは、次の方法について学びます。
- ビルド環境をセットアップする
--toolchain_resolution_debug
を使用してツールチェーンの解決をデバッグする- C++ ツールチェーンを構成する
- Starlark ルールを作成して、追加の
Bazel でアプリケーションをビルドできるように、
cc_toolchain
の構成 参加者:clang
- 次を実行して C++ バイナリをビルドします。
Linux マシン上の
bazel build //main:hello-world
bazel build //main:hello-world --platforms=//:android_x86_64
を実行して、Android のバイナリをクロスコンパイルします。
始める前に
このチュートリアルでは、Linux を使用していて、
C++ アプリケーションをインストールし、適切なツールとライブラリをインストールしました。
このチュートリアルでは、システムにインストールできる clang version 16
を使用します。
ビルド環境をセットアップする
ビルド環境を次のように設定します。
まだ実施していない場合は Bazel 7.0.2 以降をダウンロードしてインストールします。
ルートフォルダに空の
WORKSPACE
ファイルを追加します。次の
cc_binary
ターゲットをmain/BUILD
ファイルに追加します。load("@rules_cc//cc:defs.bzl", "cc_binary") cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )
Bazel は、C++ で記述された多くの内部ツールをビルド時に使用するため、
process-wrapper
の場合、既存のデフォルトの C++ ツールチェーンが 表示されます。これにより、これらの内部ツールはそれを使って ツールチェーンと同じコードを使用します。したがって、cc_binary
ターゲットは デフォルトのツールチェーンでビルドされます。次のコマンドを使用してビルドを実行します。
bazel build //main:hello-world
WORKSPACE
にツールチェーンが登録されていない状態でビルドが成功します。内部の詳細を確認するには、次のコマンドを実行します。
bazel build //main:hello-world --toolchain_resolution_debug='@bazel_tools//tools/cpp:toolchain_type' INFO: ToolchainResolution: Target platform @@local_config_platform//:host: Selected execution platform @@local_config_platform//:host, type @@bazel_tools//tools/cpp:toolchain_type -> toolchain @@bazel_tools+cc_configure_extension+local_config_cc//:cc-compiler-k8
--platforms
を指定せずに、Bazel はターゲットをビルドします。@local_config_platform//:host
を使用@bazel_tools//cc_configure_extension/local_config_cc//:cc-compiler-k8
C++ ツールチェーンを構成する
C++ ツールチェーンを構成するには、アプリケーションを繰り返しビルドし、 各エラーを 1 つずつ処理します。
また、clang version 9.0.1
を前提としていますが、詳細は変更されるだけです。
若干異なることがあります。
次で
toolchain/BUILD
を追加:filegroup(name = "empty") cc_toolchain( name = "linux_x86_64_toolchain", toolchain_identifier = "linux_x86_64-toolchain", toolchain_config = ":linux_x86_64_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, ) toolchain( name = "cc_toolchain_for_linux_x86_64", toolchain = ":linux_x86_64_toolchain", toolchain_type = "@bazel_tools//tools/cpp:toolchain_type", exec_compatible_with = [ "@platforms//cpu:x86_64", "@platforms//os:linux", ], target_compatible_with = [ "@platforms//cpu:x86_64", "@platforms//os:linux", ], )
次に、ツールチェーンを
WORKSPACE
に登録します。register_toolchains( "//toolchain:cc_toolchain_for_linux_x86_64" )
このステップでは、
cc_toolchain
を定義し、それをtoolchain
ターゲットにバインドします。 ホスト構成を変更できます。ビルドを再度実行します。
toolchain
パッケージはまだlinux_x86_64_toolchain_config
ターゲットの場合、Bazel は次のエラーをスローします。ERROR: toolchain/BUILD:4:13: in toolchain_config attribute of cc_toolchain rule //toolchain:linux_x86_64_toolchain: rule '//toolchain:linux_x86_64_toolchain_config' does not exist.
toolchain/BUILD
ファイルで、空のファイル グループを次のように定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "linux_x86_64_toolchain_config")
ビルドを再度実行します。Bazel は次のエラーをスローします。
'//toolchain:linux_x86_64_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'.
CcToolchainConfigInfo
は、構成に使用するプロバイダです。 C++ ツールチェーンを使用します。このエラーを修正するには、Starlark ルールを作成します これは、CcToolchainConfigInfo
を Bazel に提供するものです。 次の内容のtoolchain/cc_toolchain_config.bzl
ファイル:def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )
cc_common.create_cc_toolchain_config_info()
は、必要なプロバイダを作成します。CcToolchainConfigInfo
。cc_toolchain_config
ルールを使用するには、負荷を ステートメントを package ステートメントのすぐ下にあるtoolchain/BUILD
に追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")
そして、"linux_x86_64_ツールチェーン_config"を宣言を含むファイルグループ
cc_toolchain_config
ルールの場合:cc_toolchain_config(name = "linux_x86_64_toolchain_config")
ビルドを再度実行します。Bazel は次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`
この時点で、Bazel にはコードのビルドを試みるのに十分な情報がありますが、 必要なビルドを完了するためにどのツールを使用すればよいか、まだわかっていません。 できます。Starlark ルールの実装を変更して、Bazel に何を伝えるかを指定します。 使用できます。そのためには、ツールの tool_path() コンストラクタを
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl
:# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )
/usr/bin/clang
と/usr/bin/ld
が正しいパスであることを確認する 選択しますビルドを再度実行します。Bazel は次のエラーをスローします。
ERROR: main/BUILD:3:10: Compiling main/hello-world.cc failed: absolute path inclusion(s) found in rule '//main:hello-world': the source file 'main/hello-world.cc' includes the following non-builtin files with absolute paths (if these are builtin files, make sure these paths are in your toolchain): '/usr/include/c++/13/ctime' '/usr/include/x86_64-linux-gnu/c++/13/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/13/bits/os_defines.h' ...
Bazel は、含まれているヘッダーを検索する場所を認識する必要があります。他にも この問題は、
includes
属性を使用するなど、複数の方法で解決できます。cc_binary
ですが、ここでは、cxx_builtin_include_directories
パラメータcc_common.create_cc_toolchain_config_info
を指定します。ただし、 別のバージョンのclang
を使用している場合、インクルード パスは次のようになります。 異なりますこれらのパスは、ディストリビューションによって異なる場合もあります。toolchain/cc_toolchain_config.bzl
の戻り値を変更して、 例:return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-16/lib/clang/16/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )
ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'
その理由は、リンカーに C++ 標準がないためです シンボルを見つけることができません。これには多くの方法がありますが たとえば、
cc_binary
のlinkopts
属性を使用するなどです。この場合、 ツールチェーンを使用するターゲットでは、 指定します。次のコードを
toolchain/cc_toolchain_config.bzl
にコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", # NEW "flag_group", # NEW "flag_set", # NEW "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )
bazel build //main:hello-world
を実行すると、最終的にホストのバイナリが正常にビルドされます。toolchain/BUILD
で、cc_toolchain_config
、cc_toolchain
、 ターゲットをtoolchain
個作成し、ターゲット内のlinux_x86_64
をandroid_x86_64
に置き換えます できます。WORKSPACE
で、Android のツールチェーンを登録するregister_toolchains( "//toolchain:cc_toolchain_for_linux_x86_64", "//toolchain:cc_toolchain_for_android_x86_64" )
bazel build //main:hello-world --android_platforms=//toolchain:android_x86_64
を実行して、Android 用のバイナリをビルドします。
実際には、Linux と Android では異なる C++ ツールチェーン構成を使用する必要があります。マイページ
差分のために既存の cc_toolchain_config
を変更するか、
個別のルール(CcToolchainConfigInfo
プロバイダなど)を
説明します。
作業内容を確認する
このチュートリアルでは基本的な C++ ツールチェーンの構成方法を学びましたが、 ツールチェーンは、この簡単な例よりも強力です。
重要なポイントは次のとおりです。
- Bazel がこれに対応するには、それに対応する
platforms
フラグをコマンドラインで指定する必要があります。 プラットフォーム上の同じ制約値に対するツールチェーンに解決されます。 詳しくは、言語固有の構成フラグのドキュメントをご覧ください。 - ツールが存在する場所をツールチェーンに通知する必要があります。このチュートリアルの内容
簡易版では システムからツールにアクセスできます条件
より自己完結型のアプローチに関心がある場合は、
ワークスペース。ツールの元になるのは
各ワークスペースでファイルを利用できるようにし
次のような属性のターゲット依存関係を持つ
cc_toolchain
へcompiler_files
。tool_paths
も変更する必要があります。 - 機能を作成して、どのフラグを渡すかをカスタマイズできます。 さまざまなアクションを指定できます。
関連情報
詳しくは、 C++ ツールチェーン構成