Maven から Bazel への移行

問題を報告 ソースを表示 毎晩

このページでは、前提条件やインストール手順など、Maven から Bazel に移行する方法について説明します。Maven と Bazel の違いと、Guava プロジェクトを使用した移行例について説明します。

ビルドツールから Bazel に移行する場合は、開発チーム、CI システム、その他の関連システムを完全に移行するまで、両方のビルドツールを並行して実行することをおすすめします。Maven と Bazel は同じリポジトリで実行できます。

注: Bazel は、rules_jvm_external を使用した Maven アーティファクトのダウンロードと公開をサポートしていますが、Maven ベースのプラグインを直接サポートしているわけではありません。Maven 互換性レイヤがないため、Maven プラグインを Bazel で直接実行することはできません。

始める前に

• Bazel をインストールします（まだインストールしていない場合）。
• Bazel を初めて使用する場合は、移行を開始する前に、Bazel の概要: Java のビルドのチュートリアルをご覧ください。このチュートリアルでは、Bazel のコンセプト、構造、ラベル構文について説明します。

Maven と Bazel の違い

• Maven では最上位の pom.xml ファイルを使用します。Bazel は複数のビルドファイルと、BUILD ファイルごとの複数のターゲットをサポートしているため、Maven のビルドよりも増分のビルドが可能です。
• Maven がデプロイ プロセスの手順を管理します。Bazel はデプロイを自動化しません。
• Bazel を使用すると、言語間の依存関係を表現できます。
• プロジェクトに新しいセクションを追加した場合、Bazel で新しい BUILD ファイルの追加が必要になる場合があります。新しい Java パッケージごとに BUILD ファイルを追加することをおすすめします。

Maven から Bazel に移行する

プロジェクトを Bazel に移行する手順は次のとおりです。

1. WORKSPACE ファイルを作成する
2. 1 つの BUILD ファイルを作成する
3. さらに BUILD ファイルを作成する
4. Bazel を使用したビルド

以下の例は、Guava プロジェクトを Maven から Bazel に移行した場合のものです。使用される Guava プロジェクトはリリース v31.1 です。Guava を使用する例では、移行の各ステップについては説明しませんが、移行のために手動で生成または追加されたファイルとコンテンツは示しています。

$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1

1. WORKSPACE ファイルを作成する

プロジェクトのルートに WORKSPACE という名前のファイルを作成します。プロジェクトに外部依存関係がない場合は、ワークスペース ファイルを空にできます。

プロジェクトがプロジェクトのディレクトリにないファイルまたはパッケージに依存している場合は、これらの外部依存関係をワークスペース ファイルで指定します。ワークスペース ファイルの外部依存関係のリストを自動化するには、rules_jvm_external を使用します。このルールセットの使用方法については、README をご覧ください。

注: 以前に推奨されたツール generate_workspace は、Bazel チームによるメンテナンスではなく、

Guava プロジェクトの例: 外部依存関係

rules_jvm_external ルールセットを使用して、Guava プロジェクトの外部依存関係を一覧表示できます。

次のスニペットを WORKSPACE ファイルに追加します。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

RULES_JVM_EXTERNAL_TAG = "4.3"
RULES_JVM_EXTERNAL_SHA = "6274687f6fc5783b589f56a2f1ed60de3ce1f99bc4e8f9edef3de43bdf7c6e74"

http_archive(
    name = "rules_jvm_external",
    sha256 = RULES_JVM_EXTERNAL_SHA,
    strip_prefix = "rules_jvm_external-%s" % RULES_JVM_EXTERNAL_TAG,
    url = "https://github.com/bazelbuild/rules_jvm_external/archive/%s.zip" % RULES_JVM_EXTERNAL_TAG,
)

load("@rules_jvm_external//:defs.bzl", "maven_install")

maven_install(
    artifacts = [
        "com.google.code.findbugs:jsr305:3.0.2",
        "com.google.errorprone:error_prone_annotations:2.11.0",
        "com.google.j2objc:j2objc-annotations:1.3",
        "org.codehaus.mojo:animal-sniffer-annotations:1.20",
        "org.checkerframework:checker-qual:3.12.0",
    ],
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)

2. 1 つの BUILD ファイルを作成する

ワークスペースを定義し、外部依存関係（該当する場合）をリストアップしたら、プロジェクトのビルド方法を記述する BUILD ファイルを作成する必要があります。1 つの pom.xml ファイルを使用する Maven とは異なり、Bazel では多くの BUILD ファイルを使用してプロジェクトをビルドできます。これらのファイルには複数のビルド ターゲットを指定します。これにより、Bazel は増分ビルドを生成できます。

BUILD ファイルを段階的に追加します。まず、プロジェクトのルートに 1 つの BUILD ファイルを追加し、そのファイルを使用して Bazel を使用した初期ビルドを行います。次に、よりきめ細かなターゲットで BUILD ファイルを追加してビルドを改良します。

1. WORKSPACE ファイルと同じディレクトリにテキスト ファイルを作成し、BUILD という名前を付けます。

2. この BUILD ファイルで、適切なルールを使用して、プロジェクトをビルドするためのターゲットを 1 つ作成します。次のヒントを参考にしてください。

   • 適切なルールを使用します。

     • 単一の Maven モジュールでプロジェクトをビルドするには、次のように java_library ルールを使用します。

       java_library(
           name = "everything",
           srcs = glob(["src/main/java/**/*.java"]),
           resources = glob(["src/main/resources/**"]),
           deps = ["//:all-external-targets"],
       )
       

     • 複数の Maven モジュールを含むプロジェクトをビルドするには、次のように java_library ルールを使用します。

       java_library(
           name = "everything",
           srcs = glob([
               "Module1/src/main/java/**/*.java",
               "Module2/src/main/java/**/*.java",
               ...
           ]),
           resources = glob([
               "Module1/src/main/resources/**",
               "Module2/src/main/resources/**",
               ...
           ]),
           deps = ["//:all-external-targets"],
       )
       

     • バイナリをビルドするには、java_binary ルールを使用します。

       java_binary(
           name = "everything",
           srcs = glob(["src/main/java/**/*.java"]),
           resources = glob(["src/main/resources/**"]),
           deps = ["//:all-external-targets"],
           main_class = "com.example.Main"
       )
       

   • 属性を指定します。

     • name: ターゲットにわかりやすい名前を付けます。上記の例では、ターゲットは「Everything」と呼ばれます。
     • srcs: グロビングを使用して、プロジェクト内のすべての .java ファイルを一覧表示します。
     • resources: グロビングを使用してプロジェクト内のすべてのリソースを一覧表示します。
     • deps: プロジェクトに必要な外部依存関係を決定する必要があります。たとえば、generate_workspace ツールを使用して外部依存関係のリストを生成した場合、java_library の依存関係は generated_java_libraries マクロにリストされているライブラリになります。

   • Guava プロジェクトの移行に関するこの最上位の BUILD ファイルの例をご覧ください。

3. これで、プロジェクトのルートに BUILD ファイルが作成されました。プロジェクトをビルドし、機能することを確認します。コマンドラインで、ワークスペース ディレクトリから bazel build //:everything を使用し、Bazel でプロジェクトをビルドします。

   これで、Bazel を使用したプロジェクトが正常にビルドされました。プロジェクトの増分ビルドを可能にするには、BUILD ファイルを追加する必要があります。

Guava プロジェクトの例: 1 つの BUILD ファイルから開始する

Guava プロジェクトを Bazel に移行する場合、最初に 1 つの BUILD ファイルを使用してプロジェクト全体をビルドします。ワークスペース ディレクトリにあるこの最初の BUILD ファイルの内容は次のとおりです。

java_library(
    name = "everything",
    srcs = glob([
        "guava/src/**/*.java",
        "futures/failureaccess/src/**/*.java",
    ]),
    javacopts = ["-XepDisableAllChecks"],
    deps = [
        "@maven//:com_google_code_findbugs_jsr305",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_j2objc_j2objc_annotations",
        "@maven//:org_checkerframework_checker_qual",
        "@maven//:org_codehaus_mojo_animal_sniffer_annotations",
    ],
)

3. さらに BUILD ファイルを作成する（省略可）

最初のビルドの完了後に確認したように、Bazel は 1 つの BUILD file でのみ動作します。それでも、きめ細かいターゲットを持つ BUILD ファイルを追加して、ビルドを小さなチャンクに分割することを検討してください。

複数のターゲットを持つ複数の BUILD ファイルを使用すると、ビルドの粒度が向上し、次のことが可能になります。

• プロジェクトの増分ビルドの増加
• ビルドの並列実行が増えたため
• 将来のユーザーのためにビルドの保守性を向上させる
• パッケージ間のターゲットの可視性を制御できるため、実装の詳細を含むライブラリが公開 API に漏れるなどの問題を防止できます。

BUILD ファイルをさらに追加する際のヒント:

• まず、各 Java パッケージに BUILD ファイルを追加します。依存関係が最も少ない Java パッケージから始めて、依存関係が最も多いパッケージを順に取得していきます。
• BUILD ファイルを追加してターゲットを指定したら、これらの新しいターゲットを、それに依存するターゲットの deps セクションに追加します。glob() 関数はパッケージの境界を越えません。そのため、パッケージの数が増えると、glob() に一致するファイルは縮小されます。
• BUILD ファイルを main ディレクトリに追加する場合は、必ず BUILD ファイルを対応する test ディレクトリに追加してください。
• パッケージ間の可視性を適切に制限するように注意してください。
• BUILD ファイルの設定で発生したエラーをトラブルシューティングしやすくするため、各ビルドファイルを追加する際に、Bazel を使用したプロジェクトのビルドを続行するようにしてください。bazel build //... を実行して、すべてのターゲットが引き続きビルドされていることを確認します。

4. Bazel を使用したビルド

Bazel を使用してビルドし、BUILD ファイルを追加してビルドの設定を検証しています。

必要な粒度の BUILD ファイルがある場合は、Bazel を使用してすべてのビルドを生成できます。