Platform

Laporkan masalah Lihat sumber

Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

Bazel dapat mem-build dan menguji kode di berbagai hardware, sistem operasi, dan konfigurasi sistem, menggunakan banyak versi alat build yang berbeda seperti linker dan compiler. Untuk membantu mengelola kompleksitas ini, Bazel memiliki konsep batasan dan platform. Batasan adalah dimensi yang dapat berbeda di lingkungan build atau produksi, seperti arsitektur CPU, ada atau tidaknya GPU, atau versi compiler yang diinstal sistem. Platform adalah kumpulan pilihan bernama untuk batasan ini, yang merepresentasikan resource tertentu yang tersedia di beberapa lingkungan.

Memodelkan lingkungan sebagai platform membantu Bazel memilih toolchain yang sesuai untuk tindakan build secara otomatis. Platform juga dapat digunakan bersama dengan aturan config_setting untuk menulis atribut yang dapat dikonfigurasi.

Bazel mengenali tiga peran yang dapat dilayani platform:

• Host - platform tempat Bazel itu sendiri berjalan.
• Eksekusi - platform tempat alat build menjalankan tindakan build untuk menghasilkan output perantara dan akhir.
• Target - platform tempat output akhir berada dan dieksekusi.

Bazel mendukung skenario build berikut terkait platform:

• Build platform tunggal (default) - platform host, eksekusi, dan target adalah sama. Misalnya, membuat file yang dapat dieksekusi Linux di Ubuntu yang berjalan di CPU Intel x64.

• Build kompilasi silang - platform host dan eksekusi sama, tetapi platform target berbeda. Misalnya, membuat aplikasi iOS di macOS yang berjalan di MacBook Pro.

• Build multiplatform - platform host, eksekusi, dan target semuanya berbeda.

Tips: Untuk mengetahui petunjuk mendetail tentang cara memigrasikan project Anda ke platform, lihat Memigrasikan ke Platform.

Menentukan batasan dan platform

Ruang kemungkinan pilihan untuk platform ditentukan dengan menggunakan aturan constraint_setting dan constraint_value dalam file BUILD. constraint_setting membuat dimensi baru, sedangkan constraint_value membuat nilai baru untuk dimensi tertentu; bersama-sama, keduanya secara efektif menentukan enum dan kemungkinan nilainya. Misalnya, cuplikan file BUILD berikut memperkenalkan batasan untuk versi glibc sistem dengan dua kemungkinan nilai.

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

Batasan dan nilainya dapat ditentukan di berbagai paket dalam ruang kerja. Label tersebut dirujuk berdasarkan label dan tunduk pada kontrol visibilitas biasa. Jika visibilitas memungkinkan, Anda dapat memperluas setelan batasan yang ada dengan menentukan nilai Anda sendiri untuknya.

Aturan platform memperkenalkan platform baru dengan pilihan nilai batasan tertentu. Contoh berikut membuat platform bernama linux_x86, dan menyatakan bahwa platform tersebut menjelaskan lingkungan apa pun yang menjalankan sistem operasi Linux pada arsitektur x86_64 dengan versi glibc 2.25. (Lihat di bawah untuk mengetahui informasi selengkapnya tentang batasan bawaan Bazel.)

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

Catatan: Platform akan dianggap melakukan kesalahan jika menentukan lebih dari satu nilai setelan batasan yang sama, seperti @platforms//cpu:x86_64 dan @platforms//cpu:arm untuk @platforms//cpu:cpu.

Batasan dan platform yang umumnya berguna

Untuk menjaga konsistensi ekosistem, tim Bazel mengelola repositori dengan definisi batasan untuk arsitektur CPU dan sistem operasi yang paling populer. Semua file ini berada di https://github.com/bazelbuild/platforms.

Bazel dikirimkan dengan definisi platform khusus berikut: @platforms//host (diberi alias sebagai @bazel_tools//tools:host_platform). Ini adalah nilai platform host yang terdeteksi otomatis - mewakili platform yang terdeteksi otomatis untuk sistem tempat Bazel berjalan.

Menentukan platform untuk build

Anda dapat menentukan platform host dan target untuk build menggunakan tanda command line berikut:

• --host_platform - default-nya adalah @bazel_tools//tools:host_platform
  • Target ini diberi alias @platforms//host, yang didukung oleh aturan repo yang mendeteksi OS dan CPU host serta menulis target platform.
  • Ada juga @platforms//host:constraints.bzl, yang mengekspos array bernama HOST_CONSTRAINTS, yang dapat digunakan dalam file BUILD dan Starlark lainnya.
• --platforms - default ke platform host
  • Artinya, jika tidak ada flag lain yang ditetapkan, @platforms//host adalah platform target.
  • Jika --host_platform ditetapkan dan bukan --platforms, nilai --host_platform adalah platform host dan target.

Melewati target yang tidak kompatibel

Saat mem-build untuk platform target tertentu, sebaiknya lewati target yang tidak akan pernah berfungsi di platform tersebut. Misalnya, driver perangkat Windows Anda kemungkinan akan menghasilkan banyak error compiler saat membangun di mesin Linux dengan //.... Gunakan atribut target_compatible_with untuk memberi tahu Bazel batasan platform target yang dimiliki kode Anda.

Penggunaan atribut ini yang paling sederhana membatasi target ke satu platform. Target tidak akan dibangun untuk platform yang tidak memenuhi semua batasan. Contoh berikut membatasi win_driver_lib.cc ke Windows 64-bit.

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib hanya kompatibel untuk dibangun dengan Windows 64-bit dan tidak kompatibel dengan yang lainnya. Inkompatibilitas bersifat transitif. Target apa pun yang bergantung secara transitif pada target yang tidak kompatibel dianggap tidak kompatibel.

Kapan target dilewati?

Target dilewati jika dianggap tidak kompatibel dan disertakan dalam build sebagai bagian dari perluasan pola target. Misalnya, dua pemanggilan berikut melewati target yang tidak kompatibel yang ditemukan dalam perluasan pola target.

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

Pengujian yang tidak kompatibel dalam test_suite juga dilewati jika test_suite ditentukan di command line dengan --expand_test_suites. Dengan kata lain, target test_suite di command line berperilaku seperti :all dan .... Penggunaan --noexpand_test_suites mencegah perluasan dan menyebabkan target test_suite dengan pengujian yang tidak kompatibel juga menjadi tidak kompatibel.

Menentukan target yang tidak kompatibel secara eksplisit di command line akan menghasilkan pesan error dan build yang gagal.

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

Target eksplisit yang tidak kompatibel akan dilewati secara otomatis jika --skip_incompatible_explicit_targets diaktifkan.

Batasan yang lebih ekspresif

Untuk fleksibilitas yang lebih besar dalam menyatakan batasan, gunakan @platforms//:incompatible constraint_value yang tidak dipenuhi oleh platform mana pun.

Gunakan select() bersama dengan @platforms//:incompatible untuk menyatakan batasan yang lebih rumit. Misalnya, gunakan untuk menerapkan logika OR dasar. Berikut menandai library yang kompatibel dengan macOS dan Linux, tetapi tidak dengan platform lain.

Catatan: Daftar batasan kosong setara dengan "kompatibel dengan semuanya".

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

Penjelasan di atas dapat diartikan sebagai berikut:

1. Saat menargetkan macOS, target tidak memiliki batasan.
2. Saat menargetkan Linux, target tidak memiliki batasan.
3. Jika tidak, target memiliki batasan @platforms//:incompatible. Karena @platforms//:incompatible bukan bagian dari platform mana pun, target dianggap tidak kompatibel.

Untuk membuat batasan Anda lebih mudah dibaca, gunakan skylib's selects.with_or().

Anda dapat mengekspresikan kompatibilitas terbalik dengan cara yang serupa. Contoh berikut menjelaskan library yang kompatibel dengan semua kecuali ARM.

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

Mendeteksi target yang tidak kompatibel menggunakan bazel cquery

Anda dapat menggunakan IncompatiblePlatformProvider dalam format output Starlark bazel cquery untuk membedakan target yang tidak kompatibel dari target yang kompatibel.

Hal ini dapat digunakan untuk memfilter target yang tidak kompatibel. Contoh di bawah hanya akan mencetak label untuk target yang kompatibel. Target yang tidak kompatibel tidak dicetak.

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

Masalah Umum

Target yang tidak kompatibel mengabaikan batasan visibilitas.