การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

Nightly · 9.0 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 7.7

หากคุณเพิ่งเคยใช้ Bazel โปรดเริ่มต้นด้วยบทแนะนำการสร้าง Android ด้วย Bazel

ภาพรวม

Bazel สามารถทำงานในการกำหนดค่าการสร้างที่แตกต่างกันได้หลายแบบ ซึ่งรวมถึงการกำหนดค่าหลายแบบที่ใช้ ชุดเครื่องมือ (Toolchain) ของ Android Native Development Kit (NDK) ซึ่งหมายความว่ากฎปกติ cc_library และ cc_binary สามารถคอมไพล์สำหรับ Android ได้โดยตรงภายใน Bazel Bazel ทำได้โดยใช้กฎที่เก็บ android_ndk_repository

ข้อกำหนดเบื้องต้น

โปรดตรวจสอบว่าคุณได้ติดตั้ง Android SDK และ NDK แล้ว

หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

ดูข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository ได้ที่รายการ Build Encyclopedia

หากคุณใช้ Android NDK เวอร์ชันล่าสุด (r22 ขึ้นไป) ให้ใช้ การติดตั้งใช้งาน Starlark ของ android_ndk_repository และทำตามวิธีการใน ไฟล์ README

การเริ่มใช้งานอย่างง่าย

หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มการขึ้นต่อกัน cc_library ลงในกฎ android_binary หรือ android_library

ตัวอย่างเช่น หากมีไฟล์ BUILD ต่อไปนี้สำหรับแอป Android

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้จะสร้างกราฟเป้าหมายต่อไปนี้

ตัวอย่างผลการแข่ง

รูปที่ 1 กราฟบิลด์ของโปรเจ็กต์ Android ที่มีการขึ้นต่อกัน cc_library

หากต้องการสร้างแอป เพียงเรียกใช้คำสั่งต่อไปนี้

bazel build //app/src/main:app

คำสั่ง bazel build จะคอมไพล์ไฟล์ Java, ไฟล์ทรัพยากร Android และ cc_library แล้วแพ็กทุกอย่างลงใน APK

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel จะคอมไพล์ cc_libraries ทั้งหมดลงในไฟล์ออบเจ็กต์ที่แชร์ (.so) ไฟล์เดียว ซึ่งกำหนดเป้าหมายเป็น ABI armeabi-v7a โดยค่าเริ่มต้น หากต้องการเปลี่ยนการตั้งค่านี้หรือสร้างสำหรับ ABI หลายรายการพร้อมกัน โปรดดูส่วนเกี่ยวกับการกำหนดค่า ABI เป้าหมาย

ตัวอย่างการตั้งค่า

ตัวอย่างนี้มีอยู่ในที่เก็บตัวอย่างของ Bazel

ในไฟล์ BUILD.bazel มีการกำหนดเป้าหมาย 3 รายการด้วยกฎ android_binary, android_library และ cc_library

เป้าหมายระดับบนสุด android_binary จะสร้าง APK

เป้าหมาย cc_library มีไฟล์แหล่งที่มา C++ ไฟล์เดียวที่มีการติดตั้งใช้งานฟังก์ชัน JNI ดังนี้

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

เป้าหมาย android_library จะระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และการ ขึ้นต่อกันในเป้าหมาย cc_library ในตัวอย่างนี้ MainActivity.java จะโหลด ไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นของเมธอดสำหรับฟังก์ชัน JNI ดังนี้

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า STL

หากต้องการกำหนดค่า C++ STL ให้ใช้แฟล็ก --android_crosstool_top

bazel build //:app --android_crosstool_top=target label

STL ที่มีอยู่ใน @androidndk มีดังนี้

STL ป้ายกำกับเป้าหมาย
STLport @androidndk//:toolchain-stlport
libc++ @androidndk//:toolchain-libcpp
gnustl @androidndk//:toolchain-gnu-libstdcpp

สำหรับ r16 และต่ำกว่า STL เริ่มต้นคือ gnustl สำหรับ r17 ขึ้นไปคือ libc++ เป้าหมาย @androidndk//:default_crosstool จะมีชื่อแทนเป็น STL เริ่มต้นที่เกี่ยวข้องเพื่อให้ใช้งานได้สะดวก

โปรดทราบว่าตั้งแต่ r18 เป็นต้นไป ระบบจะนำ STLport และ gnustl ออก ทำให้ libc++ เป็น STL เดียวใน NDK

ดูข้อมูลเพิ่มเติมเกี่ยวกับ STL เหล่านี้ได้ในเอกสารประกอบของ NDK

การกำหนดค่า ABI เป้าหมาย

หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --fat_apk_cpu ดังนี้

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

โดยค่าเริ่มต้น Bazel จะสร้างโค้ดเนทีฟของ Android สำหรับ armeabi-v7a หากต้องการสร้างสำหรับ x86 (เช่น สำหรับโปรแกรมจำลอง) ให้ส่ง --fat_apk_cpu=x86 หากต้องการสร้าง Fat APK สำหรับสถาปัตยกรรมหลายรายการ คุณสามารถระบุ CPU หลายรายการได้ เช่น --fat_apk_cpu=armeabi-v7a,x86

หากระบุ ABI มากกว่า 1 รายการ Bazel จะสร้าง APK ที่มีออบเจ็กต์ที่แชร์ สำหรับแต่ละ ABI

ABI ต่อไปนี้พร้อมใช้งาน ทั้งนี้ขึ้นอยู่กับการแก้ไข NDK และระดับ API ของ Android

การแก้ไข NDK ABI
16 และต่ำกว่า armeabi, armeabi-v7a, arm64-v8a, mips, mips64, x86, x86_64
17 ขึ้นไป armeabi-v7a, arm64-v8a, x86, x86_64

ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสารประกอบของ NDK

เราไม่แนะนำให้ใช้ Fat APK แบบหลาย ABI สำหรับบิลด์ที่เผยแพร่ เนื่องจากจะเพิ่ม ขนาดของ APK แต่ก็อาจมีประโยชน์สำหรับบิลด์ที่ใช้ในการพัฒนาและ QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

มาตรฐาน C++ แฟล็ก
C++98 ค่าเริ่มต้น ไม่ต้องใช้แฟล็ก
C++11 --cxxopt=-std=c++11
C++14 --cxxopt=-std=c++14

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และลิงเกอร์ด้วย --cxxopt, --copt และ --linkopt ใน คู่มือผู้ใช้

นอกจากนี้ คุณยังระบุแฟล็กคอมไพเลอร์และลิงเกอร์เป็นแอตทริบิวต์ใน cc_library ได้โดยใช้ copts และ linkopts เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การผสานรวมกับแพลตฟอร์มและชุดเครื่องมือ

โมเดลการกำหนดค่าของ Bazel กำลังเปลี่ยนไปใช้ แพลตฟอร์ม และ ชุดเครื่องมือ หากบิลด์ใช้แฟล็ก --platforms เพื่อเลือกสถาปัตยกรรมหรือระบบปฏิบัติการที่จะสร้าง คุณจะต้องส่งแฟล็ก --extra_toolchains ไปยัง Bazel เพื่อใช้ NDK

ตัวอย่างเช่น หากต้องการผสานรวมกับชุดเครื่องมือ android_arm64_cgo ที่กฎ Go มีให้ ให้ส่ง --extra_toolchains=@androidndk//:all นอกเหนือจากแฟล็ก --platforms

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

นอกจากนี้ คุณยังลงทะเบียนชุดเครื่องมือเหล่านี้ได้โดยตรงในไฟล์ WORKSPACE ดังนี้

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

การลงทะเบียนชุดเครื่องมือเหล่านี้จะบอกให้ Bazel ค้นหาชุดเครื่องมือในไฟล์ BUILD (สำหรับ NDK 20) เมื่อแก้ไขข้อจำกัดด้านสถาปัตยกรรมและระบบปฏิบัติการ

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

หลักการทำงาน: ขอแนะนำการเปลี่ยนการกำหนดค่า Android

กฎ android_binary สามารถขอให้ Bazel สร้างการขึ้นต่อกันในการกำหนดค่าที่เข้ากันได้กับ Android อย่างชัดเจน เพื่อให้บิลด์ Bazel ทำงานได้ โดยไม่ต้องใช้แฟล็กพิเศษใดๆ ยกเว้น --fat_apk_cpu และ --android_crosstool_top สำหรับการกำหนดค่า ABI และ STL

เบื้องหลังการทำงาน การกำหนดค่าอัตโนมัตินี้ใช้การเปลี่ยนการกำหนดค่า Android

กฎที่เข้ากันได้ เช่น android_binary จะเปลี่ยน การกำหนดค่าของการขึ้นต่อกันเป็นการกำหนดค่า Android โดยอัตโนมัติ ดังนั้นจึงมีเพียง กราฟย่อยเฉพาะของ Android ในบิลด์เท่านั้นที่จะได้รับผลกระทบ ระบบจะประมวลผลส่วนอื่นๆ ของกราฟบิลด์ โดยใช้การกำหนดค่าเป้าหมายระดับบนสุด และอาจประมวลผลเป้าหมายเดียวในการกำหนดค่าทั้ง 2 แบบ หากมีเส้นทางผ่านกราฟบิลด์ที่รองรับการดำเนินการดังกล่าว

เมื่อ Bazel อยู่ในการกำหนดค่าที่เข้ากันได้กับ Android ไม่ว่าจะระบุไว้ที่ระดับ บนสุดหรือเนื่องจากจุดเปลี่ยนระดับที่สูงกว่า จุดเปลี่ยน เพิ่มเติมที่พบจะไม่แก้ไขการกำหนดค่าอีก

ตำแหน่งในตัวเดียวที่ทริกเกอร์การเปลี่ยนไปใช้การกำหนดค่า Android คือ android_binary's deps แอตทริบิวต์

ตัวอย่างเช่น หากคุณพยายามสร้างเป้าหมาย android_library ที่มีการขึ้นต่อกัน cc_library โดยไม่มีแฟล็ก คุณอาจพบข้อผิดพลาดเกี่ยวกับส่วนหัว JNI ที่ขาดหายไป

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

โดยหลักการแล้ว การเปลี่ยนอัตโนมัติเหล่านี้ควรทำให้ Bazel ทำสิ่งที่ถูกต้องใน กรณีส่วนใหญ่ อย่างไรก็ตาม หากเป้าหมายในบรรทัดคำสั่ง Bazel อยู่ต่ำกว่ากฎการเปลี่ยนเหล่านี้แล้ว เช่น นักพัฒนาซอฟต์แวร์ C++ ทดสอบ cc_library ที่เฉพาะเจาะจง คุณจะต้องใช้ --crosstool_top ที่กำหนดเอง

การสร้าง cc_library สำหรับ Android โดยไม่ใช้ android_binary

หากต้องการสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ให้ใช้แฟล็ก --crosstool_top, --cpu และ --host_crosstool_top

เช่น

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

ในตัวอย่างนี้ ระบบจะสร้างเป้าหมาย cc_library และ cc_binary ระดับบนสุด โดยใช้ชุดเครื่องมือ NDK อย่างไรก็ตาม การดำเนินการนี้จะทำให้เครื่องมือโฮสต์ของ Bazel เองถูกสร้าง ด้วยชุดเครื่องมือ NDK (และสำหรับ Android) เนื่องจากระบบจะคัดลอกชุดเครื่องมือโฮสต์จากชุดเครื่องมือเป้าหมาย หากต้องการหลีกเลี่ยงปัญหานี้ ให้ระบุค่าของ --host_crosstool_top เป็น @bazel_tools//tools/cpp:toolchain เพื่อ ตั้งค่าชุดเครื่องมือ C++ ของโฮสต์อย่างชัดเจน

แนวทางนี้จะส่งผลต่อทั้งทรีบิลด์

คุณสามารถใส่แฟล็กเหล่านี้ลงในการกำหนดค่า bazelrc (1 รายการสำหรับแต่ละ ABI) ใน project/.bazelrc ได้ดังนี้

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

จากนั้นหากต้องการสร้าง cc_library สำหรับ x86 ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ให้ใช้วิธีนี้กับเป้าหมายระดับล่าง (เช่น cc_library) หรือเมื่อ คุณทราบแน่ชัดว่ากำลังสร้างอะไรอยู่ ให้ใช้การเปลี่ยนการกำหนดค่าอัตโนมัติจาก android_binary สำหรับเป้าหมายระดับสูงที่คุณคาดว่าจะสร้างเป้าหมายจำนวนมากที่คุณควบคุมไม่ได้