一般的な C++ ビルドのユースケース

Nightly · 9.1 · 9.0 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 8.1

ここでは、Bazel を使用して C++ プロジェクトをビルドする際の一般的なユースケースを紹介します。まだ Bazel を使用して C++ プロジェクトをビルドしたことがない場合は、チュートリアル Bazel の概要: C++ プロジェクトをビルドするを完了して、Bazel を使用した C++ プロジェクトのビルドを始めてください。

cc_library と hdrs ヘッダー ファイルについては、 cc_libraryをご覧ください。

ターゲットに複数のファイルを含める

globを使用すると、1 つのターゲットに複数のファイルを含めることができます。次に例を示します。

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

このターゲットを使用すると、Bazel は、このターゲットを含む BUILD ファイルと同じディレクトリにあるすべての .cc ファイルと .h ファイルをビルドします（サブディレクトリは除きます）。

推移的なインクルードを使用する

ファイルにヘッダーが含まれている場合、そのファイルをソースとするルール（つまり、 srcs、hdrs、または textual_hdrs 属性にそのファイルがあるルール）は、インクルードされたヘッダーのライブラリ ルールに依存する必要があります。逆に、依存関係として指定する必要があるのは直接的な依存関係のみです。たとえば、sandwich.h に bread.h が含まれており、bread.h に flour.h が含まれているとします。sandwich.h には flour.h が含まれていないため（サンドイッチに小麦粉を入れる人はいないでしょう）、BUILD ファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここで、sandwich ライブラリは bread ライブラリに依存し、bread ライブラリは flour ライブラリに依存します。

インクルード パスを追加する

ワークスペースのルートにインクルード パスを配置できない（または配置したくない）場合があります。既存のライブラリには、ワークスペース内のパスと一致しないインクルード ディレクトリがすでに存在している可能性があります。たとえば、ディレクトリ構造が次のとおりであるとします。

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel は some_lib.h が legacy/some_lib/include/some_lib.h としてインクルードされることを想定していますが、some_lib.cc には "some_lib.h" が含まれています。そのインクルード パスを有効にするには、legacy/some_lib/BUILD で some_lib/include ディレクトリがインクルード ディレクトリであることを指定する必要があります。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

これは外部依存関係で特に便利です。外部依存関係のヘッダー ファイルは、/ 接頭辞を付けてインクルードする必要があります。

外部ライブラリのインクルード

Google Test を使用しているとします。 WORKSPACE ファイルのリポジトリ関数を使用して Google Test をダウンロードし、リポジトリで使用できるようにします。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

次に、Google Test のコンパイルに使用する BUILD ファイル gtest.BUILD を作成します。 Google Test には、cc_library ルールを複雑にするいくつかの「特別な」要件があります。

  • googletest-release-1.10.0/src/gtest-all.cc は googletest-release-1.10.0/src/ 内の他のすべてのファイルを #include します。重複するシンボルのリンクエラーを防ぐため、コンパイルから除外してください。

  • googletest-release-1.10.0/include/ ディレクトリ（"gtest/gtest.h"）を基準とするヘッダー ファイルを使用するため、 そのディレクトリをインクルード パスに追加する必要があります。

  • pthread にリンクする必要があるため、linkopt として追加します。

したがって、最終的なルールは次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

これはやや煩雑です。アーカイブの構造の副産物として、すべてに googletest-release-1.10.0 が接頭辞として付いています。strip_prefix 属性を追加すると、http_archive でこの接頭辞を削除できます。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

すると、gtest.BUILD は次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

これで、cc_ ルールは @gtest//:main に依存できます。

C++ テストを作成して実行する

たとえば、次のようなテスト ./test/hello-test.cc を作成できます。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

次に、テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test に表示するには、 "//test:__pkg__", を visibility 属性に ./main/BUILD 追加する必要があります。

bazel test を使用してテストを実行できます。

bazel test test:hello-test

出力は次のようになります。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

プリコンパイル済みライブラリへの依存関係を追加する

コンパイル済みバージョン（ヘッダーと .so ファイルなど）のみがあるライブラリを使用する場合は、cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

これにより、ワークスペース内の他の C++ ターゲットがこのルールに依存できるようになります。