本頁面由 Cloud Translation API 翻譯而成。

常見 C++ 建構用途

您可以在這裡找到一些使用 Bazel 建構 C++ 專案的常見用途。如果您尚未使用 Bazel 建構 C++ 專案，請完成「Bazel 簡介：建構 C++ 專案」教學課程，開始建構 C++ 專案。

如要瞭解 cc_library 和 hdrs 標頭檔案，請參閱 cc_library。

在目標中加入多個檔案

您可以使用 glob 在單一目標中加入多個檔案。例如：

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

有了這個目標，Bazel 會在與包含此目標的 BUILD 檔案相同的目錄中建構所有 .cc 和 .h 檔案 (不包括子目錄)。

使用遞移性包括

如果檔案包含標頭，則任何以該檔案做為來源的規則 (也就是檔案在 srcs、hdrs 或 textual_hdrs 屬性中) 皆應依附標頭的程式庫規則而定。相反地，只需將直接依附元件指定為依附元件，舉例來說，假設 sandwich.h 包含 bread.h，而 bread.h 包含 flour.h。sandwich.h 不包含 flour.h (誰想加水三明治？)，因此 BUILD 檔案會如下所示：

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

在本例中，sandwich 程式庫依附於 bread 程式庫，後者依附於 flour 程式庫。

新增 include 路徑

有時，您無法 (或不想) 根層級包含路徑位於工作區根目錄。現有程式庫的 include 目錄可能與工作區中的路徑不符。舉例來說，假設您的目錄結構如下：

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel 預計會將 some_lib.h 納入 legacy/some_lib/include/some_lib.h，但假設 some_lib.cc 包含 "some_lib.h"。如要讓包含路徑有效，legacy/some_lib/BUILD 需將 some_lib/include 目錄指定為包含目錄：

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

這對外部依附元件來說特別實用，因為其標頭檔案必須另外加上 / 前置字串。

加入外部程式庫

假設您正在使用 Google Test。您可以使用 WORKSPACE 檔案中的其中一個存放區函式下載 Google 測試，並在存放區中提供該函式：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

然後建立 gtest.BUILD，這是用於編譯 Google 測試的 BUILD 檔案。 Google 測試有多個「特殊」要求，使得 cc_library 規則更加複雜：

googletest-release-1.10.0/src/gtest-all.cc #include 則用於 googletest-release-1.10.0/src/ 中的所有其他檔案：將該檔案從編譯中排除，以避免重複符號的連結錯誤。
這個檔案使用相對於 googletest-release-1.10.0/include/ 目錄 ("gtest/gtest.h") 的標頭檔案，因此您必須將該目錄加入 include 路徑中。
需要在 pthread 中連結，因此請將其新增為 linkopt。

因此最終規則會如下所示：

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

這看起來有點混亂：所有內容都會加上 googletest-release-1.10.0 前置字串，當做封存結構的副作用。您可以新增 strip_prefix 屬性，讓 http_archive 去除這個前置字串：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

則 gtest.BUILD 看起來會像這樣：

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

現在 cc_ 規則可以使用 @gtest//:main。

編寫及執行 C++ 測試

舉例來說，您可以建立測試 ./test/hello-test.cc，例如：

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

然後為測試建立 ./test/BUILD 檔案：

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

如要向 hello-test 顯示 hello-greet，您必須在 ./main/BUILD 的 visibility 屬性中加入 "//test:__pkg__",。

您現在可以使用 bazel test 執行測試。

bazel test test:hello-test

這會產生以下輸出內容：

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

新增預先編譯程式庫的依附元件

如要使用您只有已編譯版本的程式庫 (例如標頭和 .so 檔案)，請將該程式庫納入 cc_library 規則中：

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

這樣一來，工作區中的其他 C++ 目標就能使用這項規則。