本教程使用示例场景来说明如何为项目配置 C++ 工具链。它基于使用 clang 构建无错的示例 C++ 项目。
学习内容
在本教程中，您将学习如何：
- 设置构建环境
- 配置 C++ 工具链
- 创建为
cc_toolchain提供其他配置的 Starlark 规则，以便 Bazel 可以使用clang构建应用 - 通过在 Linux 机器上运行
bazel build --config=clang_config //main:hello-world来确认预期结果 - 构建 C++ 应用
准备工作
设置构建环境
本教程假定您使用的是 Linux，并且已成功构建 C++ 应用并安装了相应的工具和库。本教程使用 clang version 9.0.1，您可以将其安装在系统上。
请按以下步骤设置构建环境：
如果您尚未下载并安装 Bazel 0.23 或更高版本，请执行此操作。
从 GitHub 下载示例 C++ 项目，并将其放置在本地机器上的空目录中。
将以下
cc_binary目标添加到main/BUILD文件中：cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )在工作区目录的根目录下创建
.bazelrc文件，其中包含以下内容，以启用--config标志的使用：# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
对于条目 build:{config_name} --flag=value，命令行标志 --config={config_name} 与该特定标志相关联。如需了解所使用的标志，请参阅文档：crosstool_top、cpu 和 host_crosstool_top。
当您使用 bazel build --config=clang_config //main:hello-world 构建目标时，Bazel 会使用 cc_toolchain_suite
//toolchain:clang_suite 中的自定义工具链。该套件可能会针对不同 CPU 列出不同的工具链，因此，它使用 --cpu=k8 标志进行了区分。
由于 Bazel 在构建期间使用许多用 C++ 编写的内部工具（例如 process-wrapper），因此系统会为主机平台指定预先存在的默认 C++ 工具链，以便使用这些工具链（而不是本教程中创建的工具链）构建这些工具。
配置 C++ 工具链
要配置 C++ 工具链，请重复构建应用并逐一消除每个错误，如下所述。
使用以下命令运行构建：
bazel build --config=clang_config //main:hello-world因为您在
.bazelrc文件中指定了--crosstool_top=//toolchain:clang_suite，所以 Bazel 会抛出以下错误：No such package `toolchain`: BUILD file not found on package path.在工作区目录中，为软件包创建
toolchain目录并在toolchain目录内创建一个空的BUILD文件。再次运行构建。由于
toolchain软件包尚未定义clang_suite目标，因此 Bazel 会抛出以下错误：No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILD在
toolchain/BUILD文件中，定义一个空文件组，如下所示：package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")再次运行构建。Bazel 会抛出以下错误：
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel 发现
--crosstool_top标志指向未提供必要ToolchainInfo提供方的规则。因此，您需要使--crosstool_top指向提供ToolchainInfo的规则，即cc_toolchain_suite规则。在toolchain/BUILD文件中，将空文件组替换为以下内容：cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性会自动将--cpu（以及指定--compiler时）的值映射到cc_toolchain。您尚未定义任何cc_toolchain目标，Bazel 很快就会投诉您。再次运行构建。Bazel 会抛出以下错误：
Rule '//toolchain:k8_toolchain' does not exist现在，您需要为
cc_toolchain_suite.toolchains属性中的每个值定义cc_toolchain目标。将以下内容添加到toolchain/BUILD文件中：filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )再次运行构建。Bazel 会抛出以下错误：
Rule '//toolchain:k8_toolchain_config' does not exist接下来，将“:k8_toolchain_config”目标添加到
toolchain/BUILD文件中：filegroup(name = "k8_toolchain_config")再次运行构建。Bazel 会抛出以下错误：
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfo是用于配置 C++ 工具链的提供程序。如需修复此错误，请创建一个包含以下内容的toolchain/cc_toolchain_config.bzl文件，以创建为 Bazel 提供CcToolchainConfigInfo的 Starlark 规则：def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()会创建所需的提供程序CcToolchainConfigInfo。如需使用cc_toolchain_config规则，请将 load 语句添加到 package 语句正下方的toolchain/BUILD中：load(":cc_toolchain_config.bzl", "cc_toolchain_config")并将“k8_toolchain_config”文件组替换为
cc_toolchain_config规则的声明：cc_toolchain_config(name = "k8_toolchain_config")再次运行构建。Bazel 会抛出以下错误：
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`此时，Bazel 有足够的信息来尝试构建代码，但 Bazel 仍然不知道要使用哪些工具来完成所需的构建操作。您将修改 Starlark 规则实现，以告知 Bazel 要使用哪些工具。为此，您需要
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl中的 tool_path() 构造函数：# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )确保
/usr/bin/clang和/usr/bin/ld是您的系统的正确路径。再次运行构建。Bazel 会抛出以下错误：
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel 需要知道在哪里搜索包含的标头。有多种方法可以解决此问题，例如使用
cc_binary的includes属性，但在此处，可以使用cc_common.create_cc_toolchain_config_info的cxx_builtin_include_directories参数在工具链级别解决此问题。请注意，如果您使用的是不同版本的clang，包含路径会有所不同。这些路径也可能因分布而异。将
toolchain/cc_toolchain_config.bzl中的返回值修改为如下所示：return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )再次运行构建命令，您将看到如下错误：
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'其原因在于，链接器缺少 C++ 标准库，且找不到其符号。有多种方法可以解决此问题，例如使用
cc_binary的linkopts属性。在这里，通过确保无需指定使用工具链的任何目标不必指定此标志，即可解决此问题。将以下代码复制到
cc_toolchain_config.bzl：# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )如果您运行
bazel build --config=clang_config //main:hello-world，它应该最终会进行构建。
检查您的作业
在本教程中，您学习了如何配置基本的 C++ 工具链，但工具链比这个简单示例更强大。
要点总结如下：
- 您需要在命令行中指定一个应指向 cc_toolchain_suite 的 --crosstool_top 标志
- 您可以使用 .bazelrc 文件为特定配置创建快捷方式
- cc_toolchain_suite 可能会针对不同的 CPU 和编译器列出 cc_toolchains。您可以使用 --cpu 等命令行标志来区分。- 您必须告知工具链工具所在的位置。本教程提供了一个简化版本，您可以从系统访问这些工具。如果您有兴趣了解更独立的方法，可以点击此处了解工作区。您的工具可能来自其他工作区，并且您必须使其文件可供 cc_toolchain 使用，并且具有属性的目标依赖项（例如 compiler_files）。您还需要更改 tool_paths。- 您可以创建功能来自定义应将哪些标志传递给不同的操作（无论是链接还是任何其他类型的操作）。
深入阅读
如需了解详情，请参阅 C++ 工具链配置