Sử dụng macro để tạo động từ tuỳ chỉnh

Báo cáo sự cố Xem nguồn

Hoạt động tương tác hằng ngày với Bazel chủ yếu diễn ra thông qua một số lệnh: build, test và run. Tuy nhiên, đôi khi, bạn có thể cảm thấy hạn chế về những việc này: có thể bạn muốn đẩy các gói vào một kho lưu trữ, xuất bản tài liệu cho người dùng cuối hoặc triển khai ứng dụng bằng Kubernetes. Nhưng Bazel không có lệnh publish hoặc deploy. Những thao tác này phù hợp ở đâu?

Lệnh chạy bazel

Do Bazel tập trung vào tính ẩn giấu, khả năng tái tạo và mức độ gia tăng, nên các lệnh build và test không hữu ích trong các nhiệm vụ trên. Những thao tác này có thể chạy trong một hộp cát, có quyền truy cập mạng bị giới hạn và không đảm bảo sẽ chạy lại với mọi bazel build.

Thay vào đó, hãy dựa vào bazel run: quy trình làm việc cho các tác vụ mà bạn muốn có hiệu ứng phụ. Người dùng Bazel đã quen thuộc với các quy tắc tạo tệp thực thi, còn tác giả quy tắc có thể tuân theo một nhóm mẫu chung để mở rộng quy tắc này cho các "động từ tuỳ chỉnh".

Trong tự nhiên: rules_k8s

Ví dụ: hãy xem xét rules_k8s, các quy tắc của Kubernetes cho Bazel. Giả sử bạn có mục tiêu sau đây:

# BUILD file in //application/k8s
k8s_object(
    name = "staging",
    kind = "deployment",
    cluster = "testing",
    template = "deployment.yaml",
)

Quy tắc k8s_object tạo một tệp YAML của Kubernetes tiêu chuẩn khi bazel build được sử dụng trên mục tiêu staging. Tuy nhiên, các mục tiêu bổ sung cũng được macro k8s_object tạo với các tên như staging.apply và :staging.delete. Các tập lệnh bản dựng này để thực hiện những hành động đó. Khi được thực thi bằng bazel run staging.apply, các tập lệnh này sẽ hoạt động giống như lệnh bazel k8s-apply hoặc bazel k8s-delete của chính chúng ta.

Ví dụ khác: ts_api_guardian_test

Mẫu này cũng có thể xem được trong dự án Angular. Macro ts_api_guardian_test tạo ra 2 mục tiêu. Đầu tiên là mục tiêu nodejs_test chuẩn, so sánh một số đầu ra đã tạo với một tệp "vàng" (tức là tệp chứa kết quả dự kiến). Bạn có thể tạo và chạy ứng dụng này bằng lệnh gọi bazel test thông thường. Trong angular-cli, bạn có thể chạy một mục tiêu như vậy bằng bazel test //etc/api:angular_devkit_core_api.

Theo thời gian, chúng tôi có thể cần cập nhật tệp quan trọng này vì các lý do chính đáng. Việc cập nhật thủ công này rất tẻ nhạt và dễ xảy ra lỗi, vì vậy, macro này cũng cung cấp mục tiêu nodejs_binary cập nhật tệp vàng, thay vì so sánh với nó. Trên thực tế, cùng một tập lệnh kiểm thử có thể được viết để chạy ở chế độ "xác minh" hoặc "chấp nhận", dựa vào cách tập lệnh đó được gọi. Việc này tuân theo cùng một mẫu mà bạn đã tìm hiểu: không có lệnh bazel test-accept gốc nhưng bạn có thể đạt được hiệu quả tương tự với bazel run //etc/api:angular_devkit_core_api.accept.

Mẫu này có thể khá mạnh mẽ và trở nên khá phổ biến khi bạn tìm hiểu cách nhận ra mẫu.

Điều chỉnh các quy tắc của riêng bạn

Macro là thành phần chính của mẫu này. Macro được sử dụng như quy tắc, nhưng có thể tạo một số mục tiêu. Thông thường, chúng sẽ tạo một mục tiêu có tên được chỉ định để thực hiện hành động tạo bản dựng chính: có thể tạo một tệp nhị phân thông thường, hình ảnh Docker hoặc tệp lưu trữ mã nguồn. Trong mẫu này, các mục tiêu bổ sung được tạo ra để tạo ra các tập lệnh có hiệu ứng phụ dựa trên kết quả của mục tiêu chính, chẳng hạn như xuất bản tệp nhị phân thu được hoặc cập nhật kết quả kiểm thử dự kiến.

Để minh hoạ điều này, hãy gói một quy tắc ảo tạo ra một trang web có Sphinx với một macro để tạo một mục tiêu bổ sung cho phép người dùng xuất bản trang web đó khi đã sẵn sàng. Hãy xem xét quy tắc hiện có sau đây để tạo một trang web bằng Sphinx:

_sphinx_site = rule(
     implementation = _sphinx_impl,
     attrs = {"srcs": attr.label_list(allow_files = [".rst"])},
)

Tiếp theo, hãy xem xét một quy tắc như sau. Quy tắc này sẽ tạo một tập lệnh mà khi chạy sẽ xuất bản các trang đã tạo:

_sphinx_publisher = rule(
    implementation = _publish_impl,
    attrs = {
        "site": attr.label(),
        "_publisher": attr.label(
            default = "//internal/sphinx:publisher",
            executable = True,
        ),
    },
    executable = True,
)

Cuối cùng, hãy xác định macro sau đây để tạo mục tiêu cho cả hai quy tắc trên:

def sphinx_site(name, srcs = [], **kwargs):
    # This creates the primary target, producing the Sphinx-generated HTML.
    _sphinx_site(name = name, srcs = srcs, **kwargs)
    # This creates the secondary target, which produces a script for publishing
    # the site generated above.
    _sphinx_publisher(name = "%s.publish" % name, site = name, **kwargs)

Trong các tệp BUILD, hãy dùng macro như thể macro này chỉ tạo mục tiêu chính:

sphinx_site(
    name = "docs",
    srcs = ["index.md", "providers.md"],
)

Trong ví dụ này, mục tiêu "tài liệu" được tạo, giống như macro là một quy tắc Bazel chuẩn, duy nhất. Khi được tạo, quy tắc này sẽ tạo một số cấu hình và chạy Sphinx để tạo một trang web HTML, sẵn sàng cho việc kiểm tra thủ công. Tuy nhiên, một mục tiêu "docs.publish" khác cũng được tạo để tạo tập lệnh để xuất bản trang web. Sau khi kiểm tra kết quả của mục tiêu chính, bạn có thể sử dụng bazel run :docs.publish để phát hành mục tiêu đó ra công chúng, giống như một lệnh bazel publish ảo.

Sẽ không rõ ràng ngay việc triển khai quy tắc _sphinx_publisher sẽ trông như thế nào. Thông thường, các thao tác như vậy sẽ ghi tập lệnh shell trình chạy. Phương thức này thường bao gồm việc sử dụng ctx.actions.expand_template để viết một tập lệnh shell rất đơn giản, trong trường hợp này là gọi tệp nhị phân của nhà xuất bản bằng đường dẫn đến đầu ra của mục tiêu chính. Bằng cách này, việc triển khai của nhà xuất bản có thể vẫn mang tính chung chung, quy tắc _sphinx_site chỉ có thể tạo HTML và tập lệnh nhỏ này là tất cả những gì cần thiết để kết hợp cả hai với nhau.

Trong rules_k8s, đây thực sự là những gì .apply thực hiện: expand_template viết một tập lệnh Bash rất đơn giản, dựa trên apply.sh.tpl, chạy kubectl với dữ liệu đầu ra của mục tiêu chính. Sau đó, tập lệnh này có thể được tạo và chạy bằng bazel run :staging.apply, cung cấp lệnh k8s-apply một cách hiệu quả cho các mục tiêu k8s_object.