टेस्ट करना

अभी तक किसी भी व्यक्ति ने चेक इन नहीं किया है किसी समस्या की शिकायत करें सोर्स देखें रात · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

बेज़ल में स्टारलार्क कोड को टेस्ट करने के कई अलग-अलग तरीके हैं. यह पेज पर, इस्तेमाल के उदाहरण के हिसाब से मौजूदा सबसे सही तरीकों और फ़्रेमवर्क को इकट्ठा किया जाता है.

जांच के नियम

Skylib में एक टेस्ट फ़्रेमवर्क है, जिसे unittest.bzl विश्लेषण के दौरान, नियमों के व्यवहार की जांच करने के लिए. जैसे, उनकी कार्रवाइयां और सेवा देने वाली कंपनियां. ऐसे टेस्ट को "ऐनलिसिस टेस्ट" कहा जाता है और इस समय सबसे अच्छी हैं नियमों के अंदरूनी काम की जांच करने का विकल्प मिल जाता है.

कुछ सावधानियां:

• टेस्ट दावे बिल्ड में होते हैं, न कि एक अलग टेस्ट रनर प्रोसेस. टेस्ट के ज़रिए बनाए गए टारगेट के नाम ऐसे होने चाहिए अन्य टेस्ट या बिल्ड के टारगेट को पूरा कर सकते हैं. इस गड़बड़ी की वजह से टेस्ट के दौरान होता है. बेज़ल इसे एक बिल्ड की गड़बड़ी के तौर पर देखते हैं, न कि टेस्ट फ़ेलियर.

• इसलिए, नियमों को टेस्ट करने के लिए, इसे काफ़ी मात्रा में बॉयलरप्लेट की ज़रूरत होती है और परीक्षण दावों वाले नियमों में. यह बॉयलरप्लेट चुनौती भरा लग सकता है, चुनें. इससे ध्यान रखने में सहायता मिलती है कि मैक्रो लोड होने के चरण के दौरान उसका मूल्यांकन करके टारगेट जनरेट किए जाते हैं. विश्लेषण के दौरान, लागू करने वाले फ़ंक्शन बाद के समय तक नहीं चलते हैं.

• विश्लेषण की जांच का मकसद है कि यह काफ़ी छोटा और हल्का हो. कुछ विश्लेषण टेस्टिंग फ़्रेमवर्क की सुविधाओं का इस्तेमाल सिर्फ़ टारगेट के लिए, ट्रांज़िटिव डिपेंडेंसी की ज़्यादा से ज़्यादा संख्या (फ़िलहाल 500) हो. ऐसा, इन सुविधाओं का बड़े पैमाने पर इस्तेमाल करने पर, परफ़ॉर्मेंस पर पड़ने वाले असर की वजह से होता है टेस्ट.

बुनियादी सिद्धांत है कि टेस्टिंग नियम तय करना, जो टेस्ट के नियम से तय होता है. इससे टेस्टिंग नियम का ऐक्सेस, टेस्ट के नियम में तय हो जाता है सेवा देने वाली कंपनियां.

जांच के नियम को लागू करने का फ़ंक्शन, दावों को पूरा करता है. अगर कोई कोई भी गड़बड़ी होने पर, इन्हें fail() पर कॉल करने पर तुरंत नहीं बताया जाता (जिसकी मदद से विश्लेषण-समय बिल्ड की गड़बड़ी ट्रिगर करता है, लेकिन गड़बड़ियों को जनरेट की गई ऐसी स्क्रिप्ट जो जांच के दौरान फ़ेल हो गई.

नीचे खिलौने का एक छोटा सा उदाहरण देखें और उसके बाद कार्रवाइयों की जांच करने का एक उदाहरण देखें.

कम से कम उदाहरण

//mypkg/myrules.bzl:

MyInfo = provider(fields = {
    "val": "string value",
    "out": "output File",
})

def _myrule_impl(ctx):
    """Rule that just generates a file and returns a provider."""
    out = ctx.actions.declare_file(ctx.label.name + ".out")
    ctx.actions.write(out, "abc")
    return [MyInfo(val="some value", out=out)]

myrule = rule(
    implementation = _myrule_impl,
)

//mypkg/myrules_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "analysistest")
load(":myrules.bzl", "myrule", "MyInfo")

# ==== Check the provider contents ====

def _provider_contents_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    # If preferred, could pass these values as "expected" and "actual" keyword
    # arguments.
    asserts.equals(env, "some value", target_under_test[MyInfo].val)

    # If you forget to return end(), you will get an error about an analysis
    # test needing to return an instance of AnalysisTestResultInfo.
    return analysistest.end(env)

# Create the testing rule to wrap the test logic. This must be bound to a global
# variable, not called in a macro's body, since macros get evaluated at loading
# time but the rule gets evaluated later, at analysis time. Since this is a test
# rule, its name must end with "_test".
provider_contents_test = analysistest.make(_provider_contents_test_impl)

# Macro to setup the test.
def _test_provider_contents():
    # Rule under test. Be sure to tag 'manual', as this target should not be
    # built using `:all` except as a dependency of the test.
    myrule(name = "provider_contents_subject", tags = ["manual"])
    # Testing rule.
    provider_contents_test(name = "provider_contents_test",
                           target_under_test = ":provider_contents_subject")
    # Note the target_under_test attribute is how the test rule depends on
    # the real rule target.

# Entry point from the BUILD file; macro for running each test case's macro and
# declaring a test suite that wraps them together.
def myrules_test_suite(name):
    # Call all test functions and wrap their targets in a suite.
    _test_provider_contents()
    # ...

    native.test_suite(
        name = name,
        tests = [
            ":provider_contents_test",
            # ...
        ],
    )

//mypkg/BUILD:

load(":myrules.bzl", "myrule")
load(":myrules_test.bzl", "myrules_test_suite")

# Production use of the rule.
myrule(
    name = "mytarget",
)

# Call a macro that defines targets that perform the tests at analysis time,
# and that can be executed with "bazel test" to return the result.
myrules_test_suite(name = "myrules_test")

यह टेस्ट, bazel test //mypkg:myrules_test की मदद से किया जा सकता है.

शुरुआती load() स्टेटमेंट के अलावा, इसमें दो मुख्य हिस्से होते हैं फ़ाइल:

• इनकी जांच की जाती है. हर टेस्ट में 1) विश्लेषण का समय शामिल होता है परीक्षण नियम के लिए कार्यान्वयन फ़ंक्शन, 2) analysistest.make() के ज़रिए टेस्टिंग नियम और 3) लोडिंग-टाइम फ़ंक्शन (मैक्रो) का इस्तेमाल करके, टेस्ट के नियम और उसकी डिपेंडेंसी का एलान करना और जांच करना नियम. अगर टेस्ट केस के बीच दावे नहीं बदलते हैं, तो 1) और 2) इसे कई टेस्ट केस ने शेयर किया है.

• टेस्ट सुइट फ़ंक्शन, जिसमें हर क्वेरी के लिए लोड होने में लगने वाले समय के फ़ंक्शन को कॉल किया जाता है टेस्ट करता है और सभी टेस्ट को एक साथ बंडल करने के लिए test_suite टारगेट का एलान करता है.

एक जैसा नाम रखने के लिए, सुझाए गए नाम रखने के तरीके का पालन करें: foo को जांच के नाम का हिस्सा, जो बताता है कि टेस्ट क्या जांच रहा है (ऊपर दिए गए उदाहरण में provider_contents). उदाहरण के लिए, JUnit परीक्षण विधि को testFoo नाम दिया जाएगा.

इसके बाद:

• टेस्ट में टेस्ट और टारगेट जनरेट करने वाला मैक्रो नाम _test_foo (_test_provider_contents)

• इसके टेस्ट के नियम का नाम foo_test (provider_contents_test) होना चाहिए

• इस नियम टाइप के टारगेट का लेबल foo_test होना चाहिए (provider_contents_test)

• परीक्षण नियम के लिए लागू फ़ंक्शन का नाम दिया जाना चाहिए _foo_test_impl (_provider_contents_test_impl)

• टेस्ट में शामिल नियमों के टारगेट के लेबल और उनकी डिपेंडेंसी की शुरुआत foo_ (provider_contents_) से होनी चाहिए

ध्यान दें कि सभी लक्ष्यों के लेबल उसी लक्ष्य के अन्य लेबल के साथ विरोधाभास कर सकते हैं पैकेज बनाएं, ताकि टेस्ट के लिए एक यूनीक नाम का इस्तेमाल किया जा सके.

जांच नहीं की जा सकी

इससे यह पुष्टि करने में मदद मिल सकती है कि कोई नियम कुछ इनपुट या सोर्स में फ़ेल हो जाता है राज्य. इसके लिए, विश्लेषण टेस्ट फ़्रेमवर्क का इस्तेमाल करें:

analysistest.make की मदद से बनाए गए जांच के नियम में expect_failure की जानकारी होनी चाहिए:

failure_testing_test = analysistest.make(
    _failure_testing_test_impl,
    expect_failure = True,
)

जांच के नियम को लागू करने से यह पता चलना चाहिए कि गड़बड़ी किस तरह की है जो हुआ (खास तौर पर, गड़बड़ी का मैसेज):

def _failure_testing_test_impl(ctx):
    env = analysistest.begin(ctx)
    asserts.expect_failure(env, "This rule should never work")
    return analysistest.end(env)

यह भी पक्का करें कि टेस्ट में आपका टारगेट, खास तौर पर 'मैन्युअल' के तौर पर टैग किया गया हो. इसके बिना, :all का इस्तेमाल करके अपने पैकेज में सभी टारगेट बनाने पर जो जान-बूझकर फ़ेल हो रहे टारगेट का बिल्ड इस्तेमाल कर पाते हैं. साथ ही, आपको बिल्ड फ़ेल करने के बारे में भी पता चलता है. के साथ 'मैन्युअल' है, तो परीक्षण के अंतर्गत आपका लक्ष्य केवल तभी निर्मित होगा, जब स्पष्ट रूप से बताया गया हो, या गैर-मैन्युअल टारगेट की डिपेंडेंसी (जैसे कि टेस्ट के लिए बनाया गया नियम):

def _test_failure():
    myrule(name = "this_should_fail", tags = ["manual"])

    failure_testing_test(name = "failure_testing_test",
                         target_under_test = ":this_should_fail")

# Then call _test_failure() in the macro which generates the test suite and add
# ":failure_testing_test" to the suite's test targets.

रजिस्टर की गई कार्रवाइयों की पुष्टि की जा रही है

हो सकता है कि आप ऐसे टेस्ट लिखना चाहें जो आपकी कार्रवाइयों के बारे में दावे करते हों नियम रजिस्टर करते हैं, उदाहरण के लिए, ctx.actions.run() का इस्तेमाल करके. इस सुविधा को अपने विश्लेषण के लिए टेस्ट नियम लागू करने का फ़ंक्शन. एक उदाहरण:

def _inspect_actions_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    actions = analysistest.target_actions(env)
    asserts.equals(env, 1, len(actions))
    action_output = actions[0].outputs.to_list()[0]
    asserts.equals(
        env, target_under_test.label.name + ".out", action_output.basename)
    return analysistest.end(env)

ध्यान दें कि analysistest.target_actions(env) Action ऑब्जेक्ट, जो टारगेट की जांच की जा रही है.

अलग-अलग फ़्लैग के तहत नियम के व्यवहार की पुष्टि करना

आप यह पुष्टि कर सकते हैं कि आपका वास्तविक नियम एक निश्चित बिल्ड के लिए खास तरीके से काम करता है फ़्लैग. उदाहरण के लिए, अगर कोई उपयोगकर्ता यह तय करता है, तो आपका नियम अलग तरह से काम कर सकता है:

bazel build //mypkg:real_target -c opt

बनाम

bazel build //mypkg:real_target -c dbg

पहली नज़र में, ऐसा करने के लिए, ज़रूरी बिल्ड फ़्लैग:

bazel test //mypkg:myrules_test -c opt

हालांकि, इसके बाद यह नामुमकिन है कि आपके टेस्ट सुइट में एक साथ यह टेस्ट करेगा, जो -c opt के तहत नियम के व्यवहार की पुष्टि करेगा. साथ ही, दूसरा टेस्ट भी करेगा कि -c dbg के तहत नियम के व्यवहार की पुष्टि करता है. दोनों टेस्ट नहीं चलाए जा सकेंगे एक ही बिल्ड में!

टेस्ट तय करते समय, अपनी पसंद के बिल्ड फ़्लैग तय करके इस समस्या को हल किया जा सकता है नियम:

myrule_c_opt_test = analysistest.make(
    _myrule_c_opt_test_impl,
    config_settings = {
        "//command_line_option:compilation_mode": "opt",
    },
)

आम तौर पर, टेस्ट किए जा रहे टारगेट का विश्लेषण, मौजूदा बिल्ड फ़्लैग के आधार पर किया जाता है. config_settings को तय करने से, बताए गए कमांड लाइन की वैल्यू बदल जाती है के विकल्प. (कोई भी अनिर्दिष्ट विकल्प अपने मानों को वास्तविक कमांड लाइन).

बताए गए config_settings शब्दकोश में, कमांड लाइन फ़्लैग ऐसे होने चाहिए किसी खास प्लेसहोल्डर वैल्यू //command_line_option: के साथ प्रीफ़िक्स लगा होना चाहिए, जैसा कि दिखाया गया है पढ़ें.

आर्टफ़ैक्ट की पुष्टि करना

जनरेट की गई फ़ाइलें सही हैं या नहीं, यह पता करने के कुछ मुख्य तरीके यहां दिए गए हैं:

• आपके पास शेल, Python या किसी दूसरी भाषा में टेस्ट स्क्रिप्ट लिखने का विकल्प होता है. साथ ही, सही *_test नियम टाइप का टारगेट बनाएं.

• आपको जिस तरह की जांच करनी है उसके लिए खास नियम का इस्तेमाल किया जा सकता है.

टेस्ट टारगेट का इस्तेमाल करना

आर्टफ़ैक्ट की पुष्टि करने का सबसे आसान तरीका है, स्क्रिप्ट लिखना और अपनी BUILD फ़ाइल में *_test टारगेट जोड़ें. ऐसे आर्टफ़ैक्ट जिन्हें आपको चेक इस टारगेट की डेटा डिपेंडेंसी होनी चाहिए. अगर आपका पुष्टि करने वाला लॉजिक यह है यह एक से ज़्यादा टेस्ट के लिए फिर से इस्तेमाल किया जा सकता है. यह एक ऐसी स्क्रिप्ट होनी चाहिए जो कमांड लाइन इस्तेमाल करे ऐसे आर्ग्युमेंट जिन्हें टेस्ट टारगेट के args एट्रिब्यूट से कंट्रोल किया जाता है. यह रही उदाहरण जो पुष्टि करता है कि ऊपर दिए गए myrule का आउटपुट, "abc" है.

//mypkg/myrule_validator.sh:

if [ "$(cat $1)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed for each target whose artifacts are to be checked.
sh_test(
    name = "validate_mytarget",
    srcs = [":myrule_validator.sh"],
    args = ["$(location :mytarget.out)"],
    data = [":mytarget.out"],
)

कस्टम नियम का इस्तेमाल करना

एक ज़्यादा जटिल विकल्प शेल स्क्रिप्ट को एक ऐसे टेम्प्लेट के रूप में लिखना है जो नए नियम से इंस्टैंशिएट हो जाता है. इसमें ज़्यादा सीधे तौर पर नहीं होना और स्टारलार्क शामिल है लॉजिक, लेकिन साफ़ BUILD फ़ाइलों तक ले जाता है. फ़ायदे के तौर पर, किसी भी तर्क को प्री-प्रोसेसिंग को स्क्रिप्ट के बजाय Starlark में किया जा सकता है और स्क्रिप्ट यह थोड़ा और सेल्फ़-डॉक्यूमेंटिग का काम करता है, क्योंकि इसमें सिम्बॉलिक प्लेसहोल्डर का इस्तेमाल किया जाता है ( विकल्प) को अंकों में बदलें.

//mypkg/myrule_validator.sh.template:

if [ "$(cat %TARGET%)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/myrule_validation.bzl:

def _myrule_validation_test_impl(ctx):
  """Rule for instantiating myrule_validator.sh.template for a given target."""
  exe = ctx.outputs.executable
  target = ctx.file.target
  ctx.actions.expand_template(output = exe,
                              template = ctx.file._script,
                              is_executable = True,
                              substitutions = {
                                "%TARGET%": target.short_path,
                              })
  # This is needed to make sure the output file of myrule is visible to the
  # resulting instantiated script.
  return [DefaultInfo(runfiles=ctx.runfiles(files=[target]))]

myrule_validation_test = rule(
    implementation = _myrule_validation_test_impl,
    attrs = {"target": attr.label(allow_single_file=True),
             # You need an implicit dependency in order to access the template.
             # A target could potentially override this attribute to modify
             # the test logic.
             "_script": attr.label(allow_single_file=True,
                                   default=Label("//mypkg:myrule_validator"))},
    test = True,
)

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed just once, to expose the template. Could have also used export_files(),
# and made the _script attribute set allow_files=True.
filegroup(
    name = "myrule_validator",
    srcs = [":myrule_validator.sh.template"],
)

# Needed for each target whose artifacts are to be checked. Notice that you no
# longer have to specify the output file name in a data attribute, or its
# $(location) expansion in an args attribute, or the label for the script
# (unless you want to override it).
myrule_validation_test(
    name = "validate_mytarget",
    target = ":mytarget",
)

इसके अलावा, टेंप्लेट एक्सपैंशन की कार्रवाई का इस्तेमाल करने के बजाय, आपके पास ने टेंप्लेट को .bzl फ़ाइल में स्ट्रिंग के तौर पर इनलाइन किया और str.format तरीके या %-फ़ॉर्मैटिंग का इस्तेमाल करके, विश्लेषण के चरण को पूरा करेंगे.

Starlark की सुविधाओं की जांच की जा रही है

Skylib का unittest.bzl फ़्रेमवर्क का इस्तेमाल यूटिलिटी फ़ंक्शन (इसका मतलब है कि ऐसे फ़ंक्शन जिनका इस्तेमाल न तो मैक्रो और न ही नियम लागू करना). unittest.bzl की analysistest लाइब्रेरी, unittest का इस्तेमाल किया जा सकता है. ऐसे टेस्ट सुइट के लिए, सुविधा फ़ंक्शन unittest.suite() का इस्तेमाल बॉयलरप्लेट को कम करने के लिए किया जा सकता है.

//mypkg/myhelpers.bzl:

def myhelper():
    return "abc"

//mypkg/myhelpers_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "unittest")
load(":myhelpers.bzl", "myhelper")

def _myhelper_test_impl(ctx):
  env = unittest.begin(ctx)
  asserts.equals(env, "abc", myhelper())
  return unittest.end(env)

myhelper_test = unittest.make(_myhelper_test_impl)

# No need for a test_myhelper() setup function.

def myhelpers_test_suite(name):
  # unittest.suite() takes care of instantiating the testing rules and creating
  # a test_suite.
  unittest.suite(
    name,
    myhelper_test,
    # ...
  )

//mypkg/BUILD:

load(":myhelpers_test.bzl", "myhelpers_test_suite")

myhelpers_test_suite(name = "myhelpers_tests")

ज़्यादा उदाहरणों के लिए, Skylib के टेस्ट देखें.