优化性能

<ph type="x-smartling-placeholder"></ph> 报告问题 查看来源 敬上 每晚 · 7.3。 · 7.2 条 · 7.1敬上 · 7.0。 · 6.5

在编写规则时，最常见的性能隐患是遍历或复制 从依赖项累积的数据。从整体上汇总时 因此这些操作很容易占用 O(N^2) 时间或空间。为了避免这种情况， 对了解如何有效使用抑郁症至关重要。

这可能很难正确实现，因此 Bazel 还提供了一个内存分析器 可帮助您找出可能犯错的地方。注意： 在将低效规则纳入考量范围之前， 广泛使用。

使用 Depset

每当从规则依赖项中汇总信息时，都应该使用 depsets。仅使用普通列表或字典来发布信息 当前规则的本地区域。

Depset 将信息表示为支持共享的嵌套图表。

请参考下图：

C -> B -> A
D ---^

每个节点发布一个字符串。使用 depsets 时，数据如下所示：

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

请注意，每项只会被提及一次。使用列表，您可以得到以下结果：

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

请注意，在本例中，'a' 被提及了四次！对于较大的图表， 问题只会变得更糟。

以下是正确使用 Depset 的规则实施示例， 发布传递信息。请注意，可以在本地发布规则 使用列表获取信息，因为这不是 O(N^2)。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

如需了解详情，请参阅 depset 概览页面。

避免调用 depset.to_list()

您可以使用 to_list()，但这样做通常会导致 O(N^2) 费用。尽可能避免除调试之外的任何展平设置 目的。

一个常见的误解是，如果只这样做，你就可以自由地平缓心情 （例如 <xx>_binary 规则），则费用不是 累积的值。但仍然 您需要构建一组具有重叠依赖项的目标。这种情况会发生在 构建测试 //foo/tests/... 或在导入 IDE 项目时。

减少对 depset 的调用次数

在循环中调用 depset 通常是错误做法。这可能导致 非常深的嵌套，导致性能不佳。例如：

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

此代码可以轻松替换。首先，收集传递性偏差，然后 一次性合并所有标签：

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

有时可以使用列表理解来减少这一限制：

x = depset(transitive = [i.deps for i in inputs])

对命令行使用 ctx.actions.args()

构建命令行时，您应该使用 ctx.actions.args()。 这样一来，所有推迟的扩展都会推迟到执行阶段。

除了严格提升速度之外，这还可以减少 有时可能会高出 90% 甚至更多

以下是一些技巧：

  • 直接以实参形式传递 Depset 和列表，而不是展平它们 。系统会为您增加 ctx.actions.args() 的存储空间。 如果您需要对废弃内容进行任何转换，请查看 查看是否有任何项目需要支付相应费用，请查看 ctx.actions.args#add。

  • 您是否将 File#path 作为参数传递？不需要。不限 文件会自动转换为 path，将推迟到展开时间。

  • 通过将字符串串联在一起来构造字符串。 最好的字符串参数是一个常量，因为其内存将在 规则的所有实例

  • 如果参数对命令行而言太长，则会添加 ctx.actions.args() 对象 可以使用 ctx.actions.args#use_param_file。这是 在执行操作时在后台完成的操作如果您需要明确指定 参数文件，您可以使用 ctx.actions.write。

示例：

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

传递操作输入应已停用

使用 ctx.actions.run 构建操作时，请勿 请记住，inputs 字段接受 depset。当输入为 从依赖项中传递。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

悬挂式

如果 Bazel 显示为挂起，可以按 Ctrl-\ 或发送 通过 Bazel 的 SIGQUIT 信号 (kill -3 $(bazel info server_pid)) 获取线程 转储到文件$(bazel info output_base)/server/jvm.out中。

由于如果 bazel 处于挂起状态，您可能无法运行 bazel info，因此 output_base 目录通常是 bazel-<workspace> 的父级 符号链接。

性能剖析

JSON 轨迹配置文件 有助于快速了解 Bazel 在调用期间花了时间。

内存分析

Bazel 附带一个内置的内存分析器，可以帮助您检查规则的 内存用量。如果出现问题，您可以转储相应堆以查找 导致该问题的确切代码行。

启用内存跟踪

您必须将以下两个启动标志传递给每次 Bazel 调用：

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

这些操作会以内存跟踪模式启动服务器。如果您忘记了 一次 Bazel 调用，服务器将重新启动，而您必须重新开始

使用内存跟踪器

例如，查看目标 foo 及其作用。仅接收者 运行分析而不是运行构建执行阶段，添加 --nobuild 标志。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

接下来，查看整个 Bazel 实例使用了多少内存：

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

使用 bazel dump --rules 按规则类对其进行细分：

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

通过生成 pprof 文件来查看内存的流向 使用 bazel dump --skylark_memory：

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

使用 pprof 工具调查堆。建议您从 使用 pprof -flame $HOME/prof.gz 获取火焰图。

从 https://github.com/google/pprof 获取 pprof。

获取用几行注释的最常用调用点的文本转储：

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)