목차
패키지
package(default_deprecation, default_package_metadata, default_testonly, default_visibility, features)
이 함수는 패키지의 모든 규칙에 적용되는 메타데이터를 선언합니다. 패키지 (BUILD 파일) 내에서 최대 한 번 사용됩니다.
전체 저장소의 모든 규칙에 적용되는 메타데이터를 선언하는 상대의 경우 저장소 루트에 있는 REPO.bazel 파일에서 repo() 함수를 사용합니다.
repo() 함수는 package()와 정확히 동일한 인수를 사용합니다.
package() 함수는 파일 상단의 모든 load() 문, 그리고 규칙 앞에 호출되어야 합니다.
인수
| 속성 | 설명 |
|---|---|
default_applicable_licenses |
|
default_visibility |
라벨 목록. 기본값은 이 패키지에 있는 규칙의 기본 공개 상태입니다. 규칙의 |
default_deprecation |
문자열. 기본값은 이 패키지의 모든 규칙에 관한 기본
|
default_package_metadata |
라벨 목록. 기본값은 패키지의 다른 모든 타겟에 적용되는 메타데이터 타겟의 기본 목록을 설정합니다. 일반적으로 OSS 패키지 및 라이선스 선언과 관련된 타겟입니다. 예를 보려면 rules_license를 참고하세요. |
default_testonly |
불리언. 명시된 경우를 제외하고 기본값은 이 패키지에 있는 모든 규칙의 기본
|
features |
목록 문자열입니다. 기본값은 이 BUILD 파일의 의미 체계에 영향을 미치는 다양한 플래그를 설정합니다. 이 기능은 일종의 특별한 처리가 필요한 패키지에 태그를 지정하기 위해 빌드 시스템에서 작업하는 사람들이 주로 사용합니다. 빌드 시스템 사용자가 명시적으로 요청하지 않는 한 이 메서드를 사용하지 마세요. |
예
아래 선언은 이 패키지의 규칙이 패키지 그룹//foo:target의 멤버에게만 표시된다는 것을 선언합니다. 규칙에 대한 개별 공개 상태 선언이 있는 경우 이 사양을 재정의합니다.
package(default_visibility = ["//foo:target"])
package_group
package_group(name, packages, includes)
이 함수는 패키지 집합을 정의하고 라벨을 집합에 연결합니다. 라벨은 visibility 속성에서 참조할 수 있습니다.
패키지 그룹은 주로 공개 상태 제어에 사용됩니다. 공개적으로 표시되는 타겟은 소스 트리의 모든 패키지에서 참조할 수 있습니다. 비공개로 표시되는 타겟은 하위 패키지가 아닌 자체 패키지 내에서만 참조할 수 있습니다. 이러한 극단적 사이에서 타겟은 자체 패키지와 하나 이상의 패키지 그룹에서 설명하는 패키지에 대한 액세스를 허용할 수 있습니다. 공개 상태 시스템에 관한 자세한 내용은 공개 상태 속성을 참고하세요.
주어진 패키지는 packages 속성과 일치하거나 includes 속성에 언급된 다른 패키지 그룹 중 하나에 이미 포함되어 있으면 그룹에 있는 것으로 간주됩니다.
패키지 그룹은 기술적으로 타겟이지만 규칙에 의해 생성되지 않으며 그 자체로는 공개 상태 보호 기능이 없습니다.
인수
| 속성 | 설명 |
|---|---|
name |
이름. 필수 항목입니다. 이 대상의 고유한 이름입니다. |
packages |
문자열 목록. 기본값은 0개 이상의 패키지 사양 목록입니다. 각 패키지 사양 문자열의 형식은 다음 중 하나일 수 있습니다.
또한 처음 두 종류의 패키지 사양은 무효화되었음을 나타내기 위해 패키지 그룹에는 양수 사양 중 하나 이상과 일치하는 패키지가 포함되고 음수 사양은 일치하지 않는 패키지가 포함됩니다. 예를 들어 값 공개 상태 외에는 현재 저장소 외부의 패키지를 직접 지정할 수 있는 방법이 없습니다. 이 속성이 누락된 경우 빈 목록으로 설정하는 것과 동일하며, 참고: Bazel 6.0 이전에는 참고: Bazel 6.0 이전에는 이 속성이 |
includes |
라벨 목록. 기본값은 여기에 포함된 다른 패키지 그룹입니다. 이 속성의 라벨은 다른 패키지 그룹을 참조해야 합니다.
참조된 패키지 그룹의 패키지는 이 패키지 그룹의 일부로 가져옵니다. 이는 전이적입니다. 패키지 그룹 무효화된 패키지 사양과 함께 사용하는 경우, 각 그룹의 패키지 집합이 먼저 독립적으로 계산되고 결과가 결합됩니다. 즉, 한 그룹의 무효화된 사양은 다른 그룹의 사양에 영향을 미치지 않습니다. |
예
다음 package_group 선언은 열대 과일이 포함된 'tropical'이라는 패키지 그룹을 지정합니다.
package_group(
name = "tropical",
packages = [
"//fruits/mango",
"//fruits/orange",
"//fruits/papaya/...",
],
)
다음 선언은 가상 애플리케이션의 패키지 그룹을 지정합니다.
package_group(
name = "fooapp",
includes = [
":controller",
":model",
":view",
],
)
package_group(
name = "model",
packages = ["//fooapp/database"],
)
package_group(
name = "view",
packages = [
"//fooapp/swingui",
"//fooapp/webui",
],
)
package_group(
name = "controller",
packages = ["//fooapp/algorithm"],
)
exports_files
exports_files([label, ...], visibility, licenses)
exports_files()는 다른 패키지로 내보내는 이 패키지에 속한 파일 목록을 지정합니다.
패키지의 BUILD 파일은 exports_files() 문을 사용하여 명시적으로 내보낸 소스 파일만 다른 패키지에 속한 소스 파일을 직접 참조할 수 있습니다. 파일 공개 상태에 관해 자세히 알아보세요.
기존 동작으로, 규칙의 입력으로 언급된 파일도 --incompatible_no_implicit_file_export 플래그가 뒤집힐 때까지 기본 공개 상태로 내보내집니다. 그러나 이 동작을 신뢰해서는 안 되며 적극적으로 이전해서는 안 됩니다.
인수
인수는 현재 패키지에 있는 파일의 이름 목록입니다. 가시성 선언도 지정할 수 있습니다. 이 경우 지정된 타겟에 파일이 표시됩니다. 공개 상태를 지정하지 않으면 패키지 기본 공개 상태가 package 함수에 지정된 경우에도 파일이 모든 패키지에 표시됩니다. 라이선스를 지정할 수도 있습니다.
예시
다음 예에서는 test_data 패키지의 텍스트 파일인 golden.txt를 내보내므로 다른 패키지에서 예를 들어 테스트의 data 속성에 사용할 수 있습니다.
# from //test_data/BUILD exports_files(["golden.txt"])
glob
glob(include, exclude=[], exclude_directories=1, allow_empty=True)
Glob은 특정 경로 패턴과 일치하는 파일을 모두 찾고 변경 가능하며 정렬된 경로 목록을 새로 반환하는 도우미 함수입니다. Glob은 자체 패키지의 파일만 검색하고 소스 파일 (생성된 파일이나 다른 타겟은 아님)만 찾습니다.
파일의 패키지 상대 경로가 include 패턴과 일치하고 exclude 패턴과는 일치하지 않으면 소스 파일의 라벨이 결과에 포함됩니다.
include 및 exclude 목록에는 현재 패키지를 기준으로 한 경로 패턴이 포함됩니다. 모든 패턴은 하나 이상의 경로 세그먼트로 구성될 수 있습니다. 일반적인 Unix 경로와 마찬가지로 이러한 세그먼트는 /로 구분됩니다. 세그먼트에는 * 와일드 카드가 포함될 수 있습니다. 디렉터리 구분자 /를 제외한 경로 세그먼트의 모든 하위 문자열 (빈 하위 문자열도 포함)과 일치합니다. 이 와일드 카드는 한 경로 세그먼트 내에서 여러 번 사용할 수 있습니다. 또한 ** 와일드 카드는 0개 이상의 전체 경로 세그먼트와 일치할 수 있지만 독립형 경로 세그먼트로 선언되어야 합니다.
foo/bar.txt는 이 패키지의foo/bar.txt파일과 정확히 일치합니다.foo/*.txt는 파일이.txt로 끝나면 (foo/가 하위 패키지가 아닌 경우)foo/디렉터리의 모든 파일과 일치합니다.foo/a*.htm*는foo/디렉터리에서a로 시작하고 임의의 문자열(비어 있을 수 있음),.htm을 포함하고 다른 임의 문자열로 끝나는 모든 파일(예:foo/axx.htm,foo/a.html또는foo/axxx.html)과 일치합니다.**/a.txt는 이 패키지의 모든 하위 디렉터리에 있는 모든a.txt파일과 일치합니다.- 결과 경로에 있는 하나 이상의 디렉터리가
bar(예:xxx/bar/yyy/zzz/a.txt또는bar/a.txt(**도 세그먼트 0개와 일치) 또는bar/zzz/a.txt이라고 함)**/bar/**/*.txt는 이 패키지의 모든 하위 디렉터리에 있는 모든.txt파일과 일치합니다. **는 이 패키지의 모든 하위 디렉터리에 있는 모든 파일과 일치합니다.**는 그 자체로 세그먼트로 지속되어야 하므로foo**/a.txt는 유효하지 않은 패턴입니다.
exclude_directories 인수가 사용 설정되면 (1로 설정됨) 디렉터리 유형의 파일이 결과에서 생략됩니다 (기본값 1).
allow_empty 인수가 False로 설정된 경우 결과가 빈 목록이 되면 glob 함수에서 오류가 발생합니다.
몇 가지 중요한 제한사항과 주의사항이 있습니다.
-
glob()는 BUILD 파일 평가 중에 실행되므로glob()는 소스 트리에 있는 파일과만 일치하고 생성된 파일은 생성하지 않습니다. 소스 파일과 생성된 파일이 모두 필요한 타겟을 빌드하는 경우에는 생성된 파일의 명시적 목록을 glob에 추가해야 합니다.:mylib및:gen_java_srcs가 포함된 아래 예시를 참고하세요. -
규칙이 일치하는 소스 파일과 이름이 같은 경우 규칙은 파일을 '섀도'합니다.
이를 이해하려면
glob()는 경로 목록을 반환하므로 다른 규칙의 속성 (예:srcs = glob(["*.cc"]))에서glob()를 사용하면 일치하는 경로를 명시적으로 나열하는 것과 동일한 효과가 있습니다. 예를 들어glob()에서["Foo.java", "bar/Baz.java"]가 생성되지만 패키지에 'Foo.java'라는 규칙도 있는 경우(Bazel에서 경고하지만 허용됨)glob()의 소비자는 'Foo.java' 파일 대신 'Foo.java' 규칙(출력)을 사용합니다. 자세한 내용은 GitHub 문제 #10395를 참조하세요. - Glob은 하위 디렉터리의 파일과 일치할 수 있습니다. 하위 디렉터리 이름에는 와일드 카드를 사용할 수 있습니다. 하지만...
-
라벨은 패키지 경계를 넘을 수 없으며 glob은 하위 패키지의 파일과 일치하지 않습니다.
예를 들어
x/y가 패키지 (x/y/BUILD또는 package-path)로 존재하는 경우 패키지x의 glob 표현식**/*.cc에는x/y/z.cc가 포함되지 않습니다. 즉, glob 표현식의 결과는 실제로 BUILD 파일의 존재에 따라 달라집니다. 즉,x/y라는 패키지가 없거나 --deleted_packages 플래그를 사용하여 삭제된 것으로 표시된 경우 동일한 glob 표현식에x/y/z.cc가 포함됩니다. - 위의 제한사항은 어떤 와일드 카드를 사용하는지에 관계없이 모든 glob 표현식에 적용됩니다.
-
파일 이름이
.로 시작하는 숨겨진 파일은**및*와일드 카드 모두와 완전히 일치합니다. 숨겨진 파일을 복합 패턴과 일치시키려면 패턴이.로 시작해야 합니다. 예를 들어*및.*.txt는.foo.txt과 일치하지만*.txt은 일치하지 않습니다. 숨겨진 디렉터리도 동일한 방식으로 일치됩니다. 숨겨진 디렉터리에는 입력으로 필요하지 않은 파일이 포함될 수 있으며 불필요한 globb 파일 수와 메모리 소비가 증가할 수 있습니다. 숨겨진 디렉터리를 제외하려면 '제외' 목록 인수에 추가하세요. -
'** 와일드 카드에는 하나의 모서리 사례가 있습니다. 즉,
"**"패턴은 패키지의 디렉터리 경로와 일치하지 않습니다. 즉,glob(["**"], exclude_directories = 0)은 모든 파일 및 디렉터리를 현재 패키지의 디렉터리에 전이적으로 엄격하게 매칭합니다(단, 하위 패키지 디렉터리로 이동하지는 않습니다. 이에 관한 이전 참고사항).
일반적으로 glob 패턴에 기본 '*'를 사용하는 대신 적절한 확장자 (예: *.html)를 제공해야 합니다. 보다 명시적인 이름은 자체 문서화하므로 실수로 백업 파일이나 emacs/vi/... 자동 저장 파일이 일치되지 않도록 합니다.
빌드 규칙을 작성할 때 glob의 요소를 열거할 수 있습니다. 이를 통해 예를 들어 모든 입력에 개별 규칙을 생성할 수 있습니다. 아래의 확장된 glob 예 섹션을 참고하세요.
Glob의 예
이 디렉터리의 모든 Java 파일과 :gen_java_srcs 규칙에 의해 생성된 모든 파일로 빌드된 Java 라이브러리를 만듭니다.
java_library(
name = "mylib",
srcs = glob(["*.java"]) + [":gen_java_srcs"],
deps = "...",
)
genrule(
name = "gen_java_srcs",
outs = [
"Foo.java",
"Bar.java",
],
...
)
실험용.txt를 제외한 모든 txt 파일을 디렉터리 테스트 데이터에 포함합니다. 테스트 데이터의 하위 디렉터리에 있는 파일은 포함되지 않습니다. 이러한 파일을 포함하려면 재귀 glob (**)을 사용하세요.
sh_test(
name = "mytest",
srcs = ["mytest.sh"],
data = glob(
["testdata/*.txt"],
exclude = ["testdata/experimental.txt"],
),
)
재귀 Glob 예
테스트가 testdata 디렉터리 및 그 하위 디렉터리 (및 하위 디렉터리 등)의 모든 txt 파일에 종속되도록 합니다. BUILD 파일이 포함된 하위 디렉터리는 무시됩니다. 위의 제한사항 및 주의사항을 참고하세요.
sh_test(
name = "mytest",
srcs = ["mytest.sh"],
data = glob(["testdata/**/*.txt"]),
)
이 디렉터리와 모든 하위 디렉터리의 모든 자바 파일에서 빌드된 라이브러리를 만듭니다. 단, 경로에 테스트라는 디렉터리가 포함된 경우는 예외입니다. 이 패턴은 빌드 증분성을 줄여 빌드 시간을 늘릴 수 있으므로 가능하면 피해야 합니다.
java_library(
name = "mylib",
srcs = glob(
["**/*.java"],
exclude = ["**/testing/**"],
),
)
확장된 Glob 예시
현재 디렉터리에서 파일의 줄 수를 계산하는 *_test.cc에 대한 개별 genrule을 만듭니다.
# Conveniently, the build language supports list comprehensions.
[genrule(
name = "count_lines_" + f[:-3], # strip ".cc"
srcs = [f],
outs = ["%s-linecount.txt" % f[:-3]],
cmd = "wc -l $< >$@",
) for f in glob(["*_test.cc"])]
위의 BUILD 파일이 //foo 패키지에 있고 패키지에 일치하는 파일 세 개(a_test.cc, b_test.cc, c_test.cc)가 있는 경우 bazel query '//foo:all'를 실행하면 생성된 모든 규칙이 나열됩니다.
$ bazel query '//foo:all' | sort //foo:count_lines_a_test //foo:count_lines_b_test //foo:count_lines_c_test
select
select(
{conditionA: valuesA, conditionB: valuesB, ...},
no_match_error = "custom message"
)
select()는 규칙 속성을 구성 가능하게 하는 도우미 함수입니다.
거의 모든 속성 할당의 오른쪽을 대체할 수 있으므로 값이 명령줄 Bazel 플래그에 종속됩니다.
예를 들어, 이를 사용하여 플랫폼별 종속 항목을 정의하거나 규칙이 '개발자' 모드에서 빌드되는지 '해제' 모드로 빌드되는지에 따라 다른 리소스를 삽입할 수 있습니다.
기본 용도는 다음과 같습니다.
sh_binary(
name = "mytarget",
srcs = select({
":conditionA": ["mytarget_a.sh"],
":conditionB": ["mytarget_b.sh"],
"//conditions:default": ["mytarget_default.sh"]
})
)
이렇게 하면 구성 조건을 일치하는 값에 매핑하는 select 호출로 일반 라벨 목록 할당을 대체하여 sh_binary의 srcs 속성을 구성할 수 있습니다. 각 조건은 config_setting 또는 constraint_value에 대한 라벨 참조로, 대상의 구성이 예상 값 집합과 일치하는 경우 '일치'합니다. 그러면 mytarget#srcs의 값이 현재 호출과 일치하는 라벨 목록이 됩니다.
참고:
- 호출 시 정확히 조건이 하나만 선택됩니다.
- 여러 조건이 일치하고 한 조건이 다른 조건에 대한 전문화이면 해당 전문화가 우선 적용됩니다. B에 A와 동일한 모든 플래그와 제약 조건 값과 몇 가지 추가 플래그 또는 제약 조건 값이 있으면 조건 B는 조건 A의 특수 분야로 간주됩니다. 즉, 전문화 해결책은 아래 예 2에서와 같이 순서를 만들기 위해 설계되지 않았습니다.
- 여러 조건이 일치하고 하나의 조건이 다른 모든 조건에 대한 전문화가 아닌 경우 모든 조건이 동일한 값으로 확인되지 않는 한 Bazel은 오류와 함께 실패합니다.
- 다른 조건이 일치하지 않으면 특수한 유사 라벨
//conditions:default이 일치하는 것으로 간주됩니다. 이 조건을 생략하면 오류를 방지하기 위해 다른 규칙과 일치해야 합니다. select는 더 큰 속성 할당 내에 삽입할 수 있습니다. 따라서srcs = ["common.sh"] + select({ ":conditionA": ["myrule_a.sh"], ...})와srcs = select({ ":conditionA": ["a.sh"]}) + select({ ":conditionB": ["b.sh"]})는 유효한 표현식입니다.select는 일부 속성을 제외한 대부분의 속성과 함께 사용할 수 있습니다. 호환되지 않는 속성은 문서에nonconfigurable로 표시됩니다.하위 패키지
subpackages(include, exclude=[], allow_empty=True)
subpackages()는 파일 및 디렉터리 대신 하위 패키지를 나열하는glob()와 유사한 도우미 함수입니다.glob()와 동일한 경로 패턴을 사용하며 현재 로드 중인 BUILD 파일의 직접 하위 패키지인 모든 하위 패키지와 일치할 수 있습니다. 포함 및 제외 패턴에 대한 자세한 설명과 예는 glob을 참조하세요.반환되는 하위 패키지의 결과 목록은 정렬된 순서로 표시되며,
exclude의 패턴이 아니라include에 지정된 패턴과 일치하는 현재 로드 패키지 관련 경로를 포함합니다.예시
다음 예에서는
foo/BUILD패키지의 모든 직접 하위 패키지를 나열합니다.# The following BUILD files exist: # foo/BUILD # foo/bar/baz/BUILD # foo/sub/BUILD # foo/sub/deeper/BUILD # # In foo/BUILD a call to subs = subpackages(include = ["**"]) # results in subs == ["sub", "bar/baz"] # # 'sub/deeper' is not included because it is a subpackage of 'foo/sub' not of # 'foo'
일반적으로 이 함수를 직접 호출하는 대신 사용자가 skylib의 '하위 패키지' 모듈을 사용하는 것이 좋습니다.