顯示設定

回報問題 查看來源

本頁面說明 Bazel 的兩種瀏覽權限系統：目標瀏覽權限和負載瀏覽權限。

這兩種瀏覽權限有助於其他開發人員區分程式庫的公用 API 及其實作詳細資料，並有助於隨著工作區擴增來強制執行結構。淘汰公用 API 時，您也可以使用瀏覽權限，在拒絕新使用者時允許現有使用者。

目標瀏覽權限

「目標瀏覽權限」可用於控管哪些使用者可能依賴您的目標，也就是誰可能會在 deps 等屬性中使用目標的標籤。

如果目標 B 屬於同一套件，或者A允許查看B套件，目標 A 就可以看到。因此，套件是決定是否允許存取權的精細單位。如果 B 依附 A，但 B 無法查看，則所有嘗試建構 B 的作業會在分析期間失敗。A

請注意，授予套件瀏覽權限，並不會自行授予其子套件的瀏覽權限。如要進一步瞭解套件和子套件，請參閱概念和術語。

對於原型設計，您可以設定標記 --check_visibility=false，停用目標瀏覽權限強制執行功能。在提交的程式碼中，這不應對正式環境使用。

控制瀏覽權限的主要方法是使用規則目標上的 visibility 屬性。本節說明這項屬性的格式，以及如何判斷目標的瀏覽權限。

瀏覽權限規格

所有規則目標皆具有使用標籤清單的 visibility 屬性。每個標籤都會採用下列其中一種形式。除最後一種形式外，這些只是語法預留位置，都不會對應至任何實際目標。

  • "//visibility:public"：授予所有套件的存取權。(不得與任何其他規格合併使用)。

  • "//visibility:private"：不會授予任何其他存取權；只有這個套件中的目標可以使用這個目標。(不得與任何其他規格合併使用)。

  • "//foo/bar:__pkg__"：授予 //foo/bar 的存取權 (但不授予子套件的存取權)。

  • "//foo/bar:__subpackages__"：授予 //foo/bar 及其所有直接和間接子套件的存取權。

  • "//some_pkg:my_package_group"：授予指定 package_group 中所有套件的存取權。

    • 套件群組會使用不同的語法來指定套件。在套件群組中，表單 "//foo/bar:__pkg__" 和 "//foo/bar:__subpackages__" 分別會替換為 "//foo/bar" 和 "//foo/bar/..."。同樣地，"//visibility:public" 和 "//visibility:private" 只是 "public" 和 "private"。

舉例來說，如果 //some/package:mytarget 的 visibility 設為 [":__subpackages__", "//tests:__pkg__"]，則 //some/package/... 來源樹狀結構中的任何目標，以及 //tests/BUILD 中定義的目標，但無法用於 //tests/integration/BUILD 中定義的目標。

最佳做法：如要讓同一組套件顯示多個目標，請使用 package_group，而不要在每個目標的 visibility 屬性中重複列出清單。這樣可提高可讀性，並避免清單脫離同步。

規則目標瀏覽權限

規則目標的瀏覽權限如下：

  1. 其 visibility 屬性的值 (如有設定)；或

  2. 目標 BUILD 檔案中 package 陳述式的 default_visibility 引數值 (如有這類宣告)。

  3. //visibility:private.

最佳做法：避免將 default_visibility 設為公開。設計原型或小型程式碼集可能比較方便，但可能會意外增加公開目標，因為程式碼集不斷擴增。建議您明確指出哪些目標是套件公用介面的一部分。

範例

檔案 //frobber/bin/BUILD：

# This target is visible to everyone
cc_binary(
    name = "executable",
    visibility = ["//visibility:public"],
    deps = [":library"],
)

# This target is visible only to targets declared in the same package
cc_library(
    name = "library",
    # No visibility -- defaults to private since no
    # package(default_visibility = ...) was used.
)

# This target is visible to targets in package //object and //noun
cc_library(
    name = "subject",
    visibility = [
        "//noun:__pkg__",
        "//object:__pkg__",
    ],
)

# See package group "//frobber:friends" (below) for who can
# access this target.
cc_library(
    name = "thingy",
    visibility = ["//frobber:friends"],
)

檔案 //frobber/BUILD：

# This is the package group declaration to which target
# //frobber/bin:thingy refers.
#
# Our friends are packages //frobber, //fribber and any
# subpackage of //fribber.
package_group(
    name = "friends",
    packages = [
        "//fribber/...",
        "//frobber",
    ],
)

產生的檔案目標瀏覽權限

產生的檔案目標瀏覽權限與產生該檔案的規則目標相同。

來源檔案目標瀏覽權限

您可以呼叫 exports_files 來明確設定來源檔案目標的瀏覽權限。當沒有任何 visibility 引數傳遞至 exports_files 時，系統會公開顯示設定。exports_files 不得用於覆寫所產生檔案的瀏覽權限。

如果來源檔案目標未顯示在呼叫 exports_files 中，其瀏覽權限取決於標記 --incompatible_no_implicit_file_export 的值：

  • 如果設定旗標，瀏覽權限就會是私人狀態。

  • 否則，系統會套用舊版行為：顯示設定會與 BUILD 檔案的 default_visibility 相同；如未指定預設瀏覽權限，則會設為不公開。

避免依賴舊版行為。如果來源檔案目標需要非私人瀏覽權限，一律編寫 exports_files 宣告。

最佳做法：在可能的情況下，請優先公開規則目標，而非來源檔案。舉例來說，請將檔案納入非私人 java_library 目標中，而不是在 .java 檔案上呼叫 exports_files。一般來說，規則目標只能直接參照位於同一套件中的來源檔案。

範例

檔案 //frobber/data/BUILD：

exports_files(["readme.txt"])

檔案 //frobber/bin/BUILD：

cc_binary(
  name = "my-program",
  data = ["//frobber/data:readme.txt"],
)

配置設定瀏覽權限

以往，Bazel 並未強制規定 select() 金鑰中參照的 config_setting 目標。有兩個標記可用來移除這項舊版行為：

  • --incompatible_enforce_config_setting_visibility 可針對這些目標啟用瀏覽權限檢查功能。為協助進行遷移，也會導致任何未指定 visibility 的 config_setting 視為公開 (無論套件層級的 default_visibility 為何)。

  • --incompatible_config_setting_private_default_visibility 會讓未指定 visibility 的 config_setting 遵循套件的 default_visibility，並改回備用不公開瀏覽權限，就像任何其他規則目標一樣。如未設定 --incompatible_enforce_config_setting_visibility，則為免人工管理。

避免依賴舊版行為。如果套件要用於目前套件外的 config_setting，則在套件尚未指定適當的 default_visibility 的情況下，應有明確的 visibility。

套件群組目標瀏覽權限

package_group 目標不含 visibility 屬性。一律會公開顯示

隱含依附元件的瀏覽權限

某些規則具有隱含依附元件 - 這些依附元件在 BUILD 檔案中沒有拼寫，但屬於該規則的每個例項。例如，cc_library 規則可能會從其每個規則目標建立隱含依附元件，連結到代表 C++ 編譯器的可執行目標。

系統會根據已定義規則 (或切面) 的 .bzl 檔案，檢查這類隱含依附元件的瀏覽權限。在本範例中，C++ 編譯器可設為不公開，只要與 cc_library 規則的定義位於相同的套件中即可。做為備用方案，如果定義中未顯示隱含依附元件，則會依照 cc_library 目標進行檢查。

如要變更這項行為，停用 --incompatible_visibility_private_attributes_at_definition。停用後，系統會將隱含依附元件視為任何其他依附元件。這表示規則的每個例項都必須能查看需要依賴的目標 (例如 C++ 編譯器)。在實務上，這通常表示目標必須具有公開瀏覽權限。

如要將規則限制用於特定套件，請改用載入瀏覽權限。

載入瀏覽權限

載入瀏覽權限可控管 .bzl 檔案能否從目前套件以外的其他 BUILD 或 .bzl 檔案載入。

就像目標瀏覽權限會保護由目標封裝的原始碼一樣，負載瀏覽權限可保護由 .bzl 檔案封裝的建構邏輯。舉例來說，BUILD 檔案作者可能想將某些重複的目標定義分解為 .bzl 檔案中的巨集。在缺乏負載可視性的情況下，他們可能會發現同一個工作區中的其他協作者重複使用其巨集，而修改巨集會破壞其他團隊的建構作業。

請注意，.bzl 檔案不一定有對應的來源檔案目標。如果確實如此，則無法保證載入瀏覽權限和目標瀏覽權限與目標一致。也就是說，同一個 BUILD 檔案或許能夠載入 .bzl 檔案，但無法將其列在 filegroup 的 srcs 中，反之亦然。如果規則想使用 .bzl 檔案做為原始碼，這有時可能會發生問題，例如用於產生或測試說明文件。

針對原型設計，您可以設定 --check_bzl_visibility=false，停用載入瀏覽權限強制執行功能。和 --check_visibility=false 一樣，提交的程式碼時不應這麼做。

自 Bazel 6.0 起才能使用載入瀏覽權限。

宣告負載瀏覽權限

如要設定 .bzl 檔案的載入瀏覽權限，請在檔案中呼叫 visibility() 函式。visibility() 的引數是套件規格清單，就像 package_group 的 packages 屬性一樣。不過，visibility() 不接受排除套件規格。

在頂層 (非函式內)，對 visibility() 的呼叫只能發生一次，最好在 load() 陳述式之後。

不同於目標瀏覽權限，預設的載入顯示一律為公開。凡是未呼叫 visibility() 的檔案，皆可從工作區的任意位置載入。建議您在任何非專為套件外使用的新 .bzl 檔案頂端新增 visibility("private")。

範例

# //mylib/internal_defs.bzl

# Available to subpackages and to mylib's tests.
visibility(["//mylib/...", "//tests/mylib/..."])

def helper(...):
    ...

# //mylib/rules.bzl

load(":internal_defs.bzl", "helper")
# Set visibility explicitly, even though public is the default.
# Note the [] can be omitted when there's only one entry.
visibility("public")

myrule = rule(
    ...
)

# //someclient/BUILD

load("//mylib:rules.bzl", "myrule")          # ok
load("//mylib:internal_defs.bzl", "helper")  # error

...

載入瀏覽權限做法

本節說明管理載入瀏覽權限宣告的訣竅。

因式分解顯示設定

如有多個 .bzl 檔案的瀏覽權限相同，建議您將套件規格列入共通清單。例如：

# //mylib/internal_defs.bzl

visibility("private")

clients = [
    "//foo",
    "//bar/baz/...",
    ...
]

# //mylib/feature_A.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

# //mylib/feature_B.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

這有助於避免各種 .bzl 檔案的瀏覽權限之間意外出現偏差。如果 clients 清單較大，也更易讀。

撰寫顯示設定

有時，您可能需要讓由多個較小的許可清單組成的許可清單能夠查看 .bzl 檔案。這類似於 package_group 可以透過其 includes 屬性整合其他 package_group 的方式。

假設您要淘汰廣泛使用的巨集。您希望只有現有使用者以及自己團隊擁有的套件能查看這個容器。您可以撰寫：

# //mylib/macros.bzl

load(":internal_defs.bzl", "our_packages")
load("//some_big_client:defs.bzl", "their_remaining_uses")

# List concatenation. Duplicates are fine.
visibility(our_packages + their_remaining_uses)

複製套件群組

與目標瀏覽權限不同的是，您無法在 package_group 中定義載入瀏覽權限。如要重複使用相同的許可清單來實現目標瀏覽權限和載入瀏覽權限，建議您將套件規格清單移至 .bzl 檔案，讓這兩種宣告都能參照該檔案。以上述因素顯示瀏覽權限中的範例為基礎，您可能會撰寫：

# //mylib/BUILD

load(":internal_defs", "clients")

package_group(
    name = "my_pkg_grp",
    packages = clients,
)

只有在清單不含任何排除套件規格時，才能使用這種做法。

保護個別符號

任何名稱開頭為底線的 Starlark 符號都無法從另一個檔案載入。這可讓您輕鬆建立私人符號，但無法讓您只和少數信任的檔案共用這些符號。另一方面，載入瀏覽權限可讓您控管其他套件可查看 .bzl file 的內容，但無法讓您防止載入任何非底線的符號。

幸好，您可以結合這兩項功能，獲得精細的控制選項。

# //mylib/internal_defs.bzl

# Can't be public, because internal_helper shouldn't be exposed to the world.
visibility("private")

# Can't be underscore-prefixed, because this is
# needed by other .bzl files in mylib.
def internal_helper(...):
    ...

def public_util(...):
    ...

# //mylib/defs.bzl

load(":internal_defs", "internal_helper", _public_util="public_util")
visibility("public")

# internal_helper, as a loaded symbol, is available for use in this file but
# can't be imported by clients who load this file.
...

# Re-export public_util from this file by assigning it to a global variable.
# We needed to import it under a different name ("_public_util") in order for
# this assignment to be legal.
public_util = _public_util

bzl-visibility 建構工具 Lint

如果使用者的檔案本身並非位於目錄的父項底下，就會從名為 internal 或 private 的目錄載入檔案時，建構工具 Lint 會顯示警告訊息。這個 Lint 會優先顯示載入瀏覽權限功能，在 .bzl 檔案宣告瀏覽權限的工作區中則不需要。