构建样式指南

7.3 · 7.2 · 7.1 · 7.0 · 6.5

BUILD 文件格式遵循与 Go 相同的方法,其中标准化工具可处理大多数格式问题。Buildifier 是一款工具,可解析和以标准样式生成源代码。因此,每个 BUILD 文件都以相同的自动化方式设置格式,这使得格式在代码审核期间不再是问题。这也让工具更容易理解、修改和生成 BUILD 文件。

BUILD 文件格式必须与 buildifier 的输出一致。

格式设置示例

# Test code implementing the Foo controller.
package(default_testonly = True)

py_test(
    name = "foo_test",
    srcs = glob(["*.py"]),
    data = [
        "//data/production/foo:startfoo",
        "//foo",
        "//third_party/java/jdk:jdk-k8",
    ],
    flaky = True,
    deps = [
        ":check_bar_lib",
        ":foo_data_check",
        ":pick_foo_port",
        "//pyglib",
        "//testing/pybase",
    ],
)

文件结构

建议:请使用以下顺序(每个元素都是可选的):

  • 文件包说明(注释)

  • 所有 load() 语句

  • package() 函数。

  • 对规则和宏的调用

Buildifier 会区分独立评论和附加到元素的评论。如果注释未附加到特定元素,请在其后面使用空行。在进行自动更改时,这一区别非常重要(例如,在删除规则时保留或移除注释)。

# Standalone comment (such as to make a section in a file)

# Comment for the cc_library below
cc_library(name = "cc")

对当前软件包中目标的引用

应通过相对于软件包目录的路径引用文件(切勿使用上级引用,例如 ..)。生成的文件应以“:”开头,以表明它们不是来源。源文件不应带有 : 前缀。规则应以 : 为前缀。例如,假设 x.cc 是一个源文件:

cc_library(
    name = "lib",
    srcs = ["x.cc"],
    hdrs = [":gen_header"],
)

genrule(
    name = "gen_header",
    srcs = [],
    outs = ["x.h"],
    cmd = "echo 'int x();' > $@",
)

目标命名

目标名称应具有描述性。如果目标包含一个源文件,则目标通常应采用从该源文件派生的名称(例如,chat.cccc_library 可以命名为 chatDirectMessage.javajava_library 可以命名为 direct_message)。

软件包的同名目标(与包含目录同名的目标)应提供目录名称所描述的功能。如果没有此类目标,请勿创建同名目标。

引用同名目标时,请优先使用简短名称(//x 而非 //x:x)。如果您位于同一软件包中,请优先使用本地引用(:x 而非 //x)。

避免使用具有特殊含义的“预留”目标名称。其中包括 all__pkg____subpackages__,这些名称具有特殊语义,使用这些名称可能会导致混淆和意外行为。

如果没有普遍的团队惯例,以下是 Google 广泛使用的一些非约束性建议:

  • 一般来说,请使用 "snake_case"
    • 对于包含一个 srcjava_library,这意味着使用的名称与不带扩展名的文件名不同
    • 对于 Java *_binary*_test 规则,请使用“大驼峰式命名法”。这样,目标名称就可以与其中一个 src 匹配。对于 java_test,这使得 test_class 属性可以从目标的名称推断出来。
  • 如果特定目标有多个变体,请添加后缀以消除歧义(例如:foo_dev:foo_prod:bar_x86:bar_x64
  • _test 目标添加 _test_unittestTestTests 后缀
  • 避免使用 _lib_library 等无意义的后缀(除非必须这样做,以避免 _library 目标与其对应的 _binary 之间发生冲突)
  • 对于与 proto 相关的目标:
    • proto_library 个目标的名称应以 _proto 结尾
    • 特定于语言的 *_proto_library 规则应与底层 proto 匹配,但需将 _proto 替换为特定于语言的后缀,例如:
      • cc_proto_library_cc_proto
      • java_proto_library_java_proto
      • java_lite_proto_library_java_proto_lite

公开范围

应尽可能缩小可见性的范围,同时仍允许测试和反向依赖项进行访问。请根据需要使用 __pkg____subpackages__

避免将软件包 default_visibility 设置为 //visibility:public。只能为项目的公共 API 中的目标单独设置 //visibility:public。这些可以是设计为由外部项目依赖的库,也可以是外部项目的构建流程可以使用的二进制文件。

依赖项

依赖项应仅限于直接依赖项(规则中列出的来源所需的依赖项)。请勿列出传递依赖项。

应首先列出软件包本地依赖项,并以与上面对当前软件包中的目标的引用部分兼容的方式引用它们(而不是通过其绝对软件包名称)。

最好直接以单个列表的形式列出依赖项。将多个目标的“常见”依赖项放入一个变量会降低可维护性,使工具无法更改目标的依赖项,并可能导致未使用的依赖项。

Glob

使用 [] 指示“无目标”。请勿使用与任何内容都不匹配的正则表达式:与空列表相比,它更容易出错,并且不太明显。

递归

请勿使用递归 glob 来匹配源文件(例如 glob(["**/*.java"]))。

递归正则表达式会导致 BUILD 文件难以推理,因为它们会跳过包含 BUILD 文件的子目录。

与为每个目录创建一个 BUILD 文件并在其之间定义依赖项图相比,递归正则表达式通常效率较低,因为这样可以实现更好的远程缓存和并行处理。

最好在每个目录中编写一个 BUILD 文件,并定义它们之间的依赖项图。

非递归

通常,非递归正则表达式是可接受的。

其他惯例

  • 使用大写字母和下划线声明常量(例如 GLOBAL_CONSTANT),使用小写字母和下划线声明变量(例如 my_variable)。

  • 标签绝不应拆分,即使其长度超过 79 个字符也是如此。标签应尽可能采用字符串字面量。说明:它使查找和替换变得简单。这也有助于提高可读性。

  • name 属性的值应为字面量常量字符串(在宏中除外)。说明:外部工具使用名称属性来引用规则。他们需要在不解读代码的情况下查找规则。

  • 设置布尔值类型的属性时,请使用布尔值,而不是整数值。由于旧版原因,规则仍会根据需要将整数转换为布尔值,但不建议这样做。原因flaky = 1 可能会被误读为“通过重新运行此目标一次来 deflake 此目标”。flaky = True 明确表示“此测试不稳定”。

与 Python 样式指南的差异

虽然目标是实现与 Python 样式指南的兼容性,但也存在一些差异:

  • 没有严格的行长度限制。长注释和长字符串通常会拆分为 79 列,但这不是必需的。不应在代码审核或提交前脚本中强制执行此规则。原因:标签可以很长,超出此限制。BUILD 文件由工具生成或修改,这种情况很常见,不符合行长度限制。

  • 不支持隐式字符串串联。使用 + 运算符。原因BUILD 文件包含许多字符串列表。我们很容易忘记一个逗号,而这会得到完全不同的结果。这在过去造成了许多 bug。另请参阅此讨论

  • 在规则中,为关键字参数的 = 符号周围添加空格。原因:命名实参比在 Python 中更常见,并且始终位于单独的行中。空格有助于提高可读性。这种惯例已经实施了很长时间,不值得修改所有现有的 BUILD 文件。

  • 默认情况下,请使用双引号来表示字符串。原因:Python 样式指南中未指定这一点,但建议保持一致。因此,我们决定仅使用双引号字符串。许多语言都使用双引号来表示字符串字面量。

  • 在两个顶级定义之间使用单个空行。原因BUILD 文件的结构与典型的 Python 文件不同。它只有顶级语句。使用单个空白行可缩短 BUILD 文件。