常見 C++ 建構用途

回報問題查看原始碼 Nightly · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

以下列舉一些最常見的用途，說明如何使用 Bazel 建構 C++ 專案。如果您尚未完成，請完成「Bazel 簡介：建構 C++ 專案」教學課程，開始使用 Bazel 建構 C++ 專案。

如要瞭解 cc_library 和 hdrs 標頭檔案，請參閱 cc_library。

在目標中加入多個檔案

您可以使用 glob 在單一目標中納入多個檔案。例如：

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

透過這個目標，Bazel 會在包含此目標的 BUILD 檔案 (不含子目錄) 所在的目錄中，建構所找到的所有 .cc 和 .h 檔案。

使用轉置包含

如果檔案包含標頭，則任何以該檔案做為來源的規則 (也就是在 srcs、hdrs 或 textual_hdrs 屬性中擁有該檔案) 都應依附所附加標頭的程式庫規則。相反地，只有直接依附元件需要指定為依附元件。舉例來說，假設 sandwich.h 包含 bread.h，而 bread.h 包含 flour.h。sandwich.h 不包含 flour.h (誰會想在三明治中加入麵粉？)，因此 BUILD 檔案會如下所示：

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

在此範例中，sandwich 程式庫依附於 bread 程式庫，而 bread 程式庫依附於 flour 程式庫。

新增包含路徑

有時您無法 (或不想) 在工作區根目錄中加入路徑。現有的程式庫可能已包含目錄，但該目錄與工作區中的路徑不相符。舉例來說，假設您的目錄結構如下所示：

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel 會預期 some_lib.h 會以 legacy/some_lib/include/some_lib.h 的形式納入，但假設 some_lib.cc 包含 "some_lib.h"。如要讓該包含路徑有效，legacy/some_lib/BUILD 需要指定 some_lib/include 目錄為包含目錄：

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

這對外部相依項目特別實用，因為其標頭檔案必須搭配 / 前置字元加入。

包括外部程式庫

假設您使用 Google Test。您可以使用 WORKSPACE 檔案中的其中一個存放區函式，下載 Google 測試並在存放區中提供：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

接著建立 gtest.BUILD，這是用來編譯 Google 測試的 BUILD 檔案。Google Test 有幾項「特殊」需求，因此其 cc_library 規則會變得更複雜：

googletest-release-1.10.0/src/gtest-all.cc #include googletest-release-1.10.0/src/ 中的所有其他檔案：從編譯中排除該檔案，以免重複符號產生連結錯誤。
它會使用相對於 googletest-release-1.10.0/include/ 目錄 ("gtest/gtest.h") 的標頭檔案，因此您必須將該目錄新增至包含路徑。
它需要連結至 pthread，因此請將其新增為 linkopt。

因此，最終規則如下所示：

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

這會造成混亂：所有項目都會加上前置字串 googletest-release-1.10.0，做為封存檔案結構的副產品。您可以新增 strip_prefix 屬性，讓 http_archive 移除這個前置字元：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD 會變成這樣：

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

cc_ 規則現在可以依附於 @gtest//:main。

編寫及執行 C++ 測試

舉例來說，您可以建立測試 ./test/hello-test.cc，例如：

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

接著，為測試建立 ./test/BUILD 檔案：

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

如要讓 hello-greet 對 hello-test 可見，您必須在 ./main/BUILD 的 visibility 屬性中新增 "//test:__pkg__",。

您現在可以使用 bazel test 執行測試。

bazel test test:hello-test

這會產生以下輸出內容：

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

新增對預先編譯程式庫的依附元件

如果您只擁有已編譯版本的程式庫 (例如標頭和 .so 檔案)，請將該程式庫包裝在 cc_library 規則中：

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

這樣一來，您的工作區中的其他 C++ 目標就能依附這項規則。