创建宏

报告问题 查看源代码

想象一下，您需要在构建中运行某个工具。例如，您可能需要生成或预处理源文件，或者压缩二进制文件。在本教程中，您将创建一个用于调整图片大小的宏。

宏适合用于简单的任务。如果您想执行更复杂的操作（例如添加对新编程语言的支持），请考虑创建一条规则。规则可以为您提供更大的控制力和灵活性。

如需创建用于调整图片大小的宏，最简单的方法是使用 genrule：

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

如果您需要调整更多图片的大小，可能需要重复使用该代码。为此，请在单独的 .bzl 文件中定义一个函数，然后调用 miniature.bzl 文件：

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

注意事项：

• 按照惯例，像规则一样，宏也有 name 参数。

• 要记录宏的行为，请像在 Python 中一样使用文档字符串。

• 如需调用 genrule 或任何其他原生规则，请使用 native.。

• 使用 **kwargs 将额外参数转发到底层 genrule（其工作方式与 Python 中一样）。这非常有用，因为用户可以使用 visibility 或 tags 等标准属性。

现在，使用 BUILD 文件中的宏：

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)