Platformlar

Sorun bildirme Kaynağı görüntüleme Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Bazel, bağlayıcı ve derleyici gibi derleme araçlarının birçok farklı sürümünü kullanarak çeşitli donanım, işletim sistemleri ve sistem yapılandırmaları üzerinde kod oluşturup test edebilir. Bazel, bu karmaşıklığı yönetmeye yardımcı olmak için sınırlamalar ve platformlar kavramına sahiptir. Kısıtlama; CPU mimarisi, GPU'nun olup olmaması veya sistem tarafından yüklenmiş derleyici sürümü gibi derleme ya da üretim ortamlarının farklılık gösterebileceği boyuttur. Platform, bazı ortamlarda mevcut olan belirli kaynakları temsil eden, bu kısıtlamalar için adlandırılmış bir seçenekler koleksiyonudur.

Ortamı bir platform olarak modellemek, Bazel'in derleme işlemleri için uygun araç zincirlerini otomatik olarak seçmesine yardımcı olur. Platformlar, yapılandırılabilir özellikler yazmak için config_setting kuralıyla birlikte de kullanılabilir.

Bazel, bir platformun oynayabileceği üç rolü tanır:

• Ana makine: Bazel'in çalıştığı platform.
• Yürütme: Derleme araçlarının ara ve nihai çıkışlar üretmek için derleme işlemlerini yürüttüğü bir platformdur.
• Hedef: Nihai çıkışın yer aldığı ve yürütüldüğü platformdur.

Bazel, platformlarla ilgili aşağıdaki derleme senaryolarını destekler:

• Tek platformlu derlemeler (varsayılan): Ana makine, yürütme ve hedef platformlar aynıdır. Örneğin, Ubuntu'da Intel x64 CPU'da çalışan bir Linux yürütülebilir dosyası oluşturma.

• Derlemeler arası derlemeler: Ana makine ve yürütme platformları aynıdır ancak hedef platform farklıdır. Örneğin, macOS'te MacBook Pro üzerinde bir iOS uygulaması derleyebiliriz.

• Çoklu platform derlemeleri: Ana makine, yürütme ve hedef platformların hepsi farklıdır.

İpucu: Projenizi platformlara taşımayla ilgili ayrıntılı talimatlar için Platformlara geçiş sayfasını inceleyin.

Kısıtlamaları ve platformları tanımlama

Platformlar için olası seçenekler alanı, BUILD dosyalarında constraint_setting ve constraint_value kuralları kullanılarak tanımlanır. constraint_setting yeni bir boyut oluştururken constraint_value belirli bir boyut için yeni bir değer oluşturur. Bu iki değer birlikte bir enum ve olası değerlerini etkili bir şekilde tanımlar. Örneğin, aşağıdaki BUILD dosyası snippet'inde, sistemin glibc sürümü için iki olası değer içeren bir kısıtlama sunulmaktadır.

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

Kısıtlamalar ve değerleri, çalışma alanındaki farklı paketlerde tanımlanabilir. Bunlara etikete göre referans verilir ve genel görünürlük kontrollerine tabidir. Görünürlük izin veriyorsa kendi değerinizi tanımlayarak mevcut bir kısıtlama ayarını genişletebilirsiniz.

platform kuralı, belirli kısıtlama değeri seçenekleri içeren yeni bir platform sunar. Aşağıdaki kod, linux_x86 adlı bir platform oluşturur ve 2.25 glibc sürümüne sahip bir x86_64 mimarisinde Linux işletim sistemi çalıştıran tüm ortamları tanımladığını belirtir. (Bazel'in yerleşik kısıtlamaları hakkında daha fazla bilgi edinmek için aşağıya bakın.)

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

Not: Platformların aynı kısıtlama ayarında birden fazla değeri (ör. @platforms//cpu:cpu için @platforms//cpu:x86_64 ve@platforms//cpu:arm) belirtmesi hatadır.

Genel olarak yararlı kısıtlamalar ve platformlar

Ekosistemin tutarlılığını sağlamak amacıyla Bazel ekibi, en popüler CPU mimarileri ve işletim sistemleri için kısıtlı tanımlar içeren bir depoya sahip. Bunların tümü https://github.com/bazelbuild/platforms adresinde yer alır.

Bazel, aşağıdaki özel platform tanımı ile birlikte gönderilir: @local_config_platform//:host. Bu, otomatik olarak algılanan ana makine platformu değeridir ve Bazel'in çalıştığı sistem için otomatik olarak algılanan platformu temsil eder.

Derleme için platform belirtme

Aşağıdaki komut satırı işaretlerini kullanarak bir derleme için ana makineyi ve hedef platformları belirtebilirsiniz:

• --host_platform: Varsayılan olarak @local_config_platform//:host değerine ayarlanır.
  • @local_config_platform, ana makine işletim sistemini ve CPU'yu algılayan ve platform hedefini yazan bir depo kuralıdır.
  • Ayrıca, diğer BUILD ve Starlark dosyalarında kullanılabilecek HOST_CONSTRAINTS adlı bir diziyi gösteren @local_config_platform//:constraintz.bzl öğesini de oluşturur.
• --platforms: Varsayılan olarak ana makine platformu kullanılır
  • Bu, başka işaret ayarlanmadığında hedef platformun @local_config_platform//:host olduğu anlamına gelir.
  • --platforms yerine --host_platform ayarlandıysa --host_platform değeri hem ana makine hem de hedef platformdur.

Uyumlu olmayan hedefleri atlama

Belirli bir hedef platform için reklam oluştururken, genellikle o platformda hiçbir zaman çalışmayacak hedeflerin atlanması önerilir. Örneğin, Windows cihaz sürücünüz //... ile bir Linux makinesinde derleme yaparken büyük olasılıkla çok sayıda derleyici hatası oluşturur. Bazel'e, kodunuzun hangi hedef platform kısıtlamalarına sahip olduğunu bildirmek için target_compatible_with özelliğini kullanın.

Bu özelliğin en basit kullanımı, hedefi tek bir platformla kısıtlar. Hedef, tüm kısıtlamaları karşılamayan platformlar için oluşturulmaz. Aşağıdaki örnekte win_driver_lib.cc, 64 bit Windows ile sınırlandırılmıştır.

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        "@platforms//os:windows",
    ],
)

:win_driver_lib, yalnızca 64 bit Windows ile derleme için uyumludur ve diğer tüm sistemlerle uyumlu değildir. Uyumsuzluk geçişlidir. Geçişli olarak uyumsuz bir hedefe bağlı olan hedeflerin kendisi uyumsuz olarak kabul edilir.

Hedefler ne zaman atlanır?

Hedefler, uyumlu olmadığı kabul edildiğinde ve hedef kalıp genişletmesinin bir parçası olarak derlemeye dahil edildiğinde atlanır. Örneğin, aşağıdaki iki çağrı, hedef kalıp genişletmesinde bulunan uyumsuz hedefleri atlar.

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

test_suite içindeki uyumlu olmayan testler de test_suite, komut satırında --expand_test_suites ile belirtilirse benzer şekilde atlanır. Başka bir deyişle, komut satırındaki test_suite hedefleri :all ve ... gibi davranır. --noexpand_test_suites kullanılması, genişletmeyi engeller ve uyumsuz testlere sahip test_suite hedeflerinin de uyumsuz olmasına neden olur.

Komut satırında uyumlu olmayan bir hedefin açıkça belirtilmesi hata mesajına ve başarısız derlemeye neden olur.

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

--skip_incompatible_explicit_targets etkinse uyumlu olmayan açık hedefler sessizce atlanır.

Daha etkileyici kısıtlamalar

Kısıtlamaları ifade etme konusunda daha fazla esneklik için hiçbir platformun uygun olmadığı @platforms//:incompatible constraint_value kullanın.

Daha karmaşık kısıtlamaları ifade etmek için select() ile @platforms//:incompatible birlikte kullanın. Örneğin, temel VEYA mantığını uygulamak için kullanın. Aşağıdaki işaret, macOS ve Linux ile uyumlu ancak diğer platformlarla uyumlu olmayan bir kitaplığı gösterir.

Not: Boş bir kısıtlama listesi, "her şeyle uyumlu" anlamına gelir.

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

Yukarıdaki bilgiler aşağıdaki gibi yorumlanabilir:

1. macOS hedeflenirken hedefin herhangi bir kısıtlaması yoktur.
2. Linux hedeflenirken hedefin herhangi bir kısıtlaması yoktur.
3. Aksi takdirde, hedef @platforms//:incompatible kısıtlamasına sahip olur. @platforms//:incompatible herhangi bir platformun parçası olmadığı için hedef uyumlu değildir.

Kısıtlamalarınızı daha okunabilir hale getirmek için skylib selects.with_or() kullanın.

Ters uyumluluğu da benzer şekilde ifade edebilirsiniz. Aşağıdaki örnekte, ARM haricindeki her şeyle uyumlu bir kitaplık gösterilmektedir.

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

bazel cquery kullanılarak uyumlu olmayan hedefler algılanıyor

Uyumsuz hedefleri uyumlu hedeflerden ayırt etmek için bazel cquery ürününün Starlark çıkış biçiminde IncompatiblePlatformProvider kullanabilirsiniz.

Bu, uyumlu olmayan hedefleri filtrelemek için kullanılabilir. Aşağıdaki örnekte yalnızca uyumlu hedeflere ait etiketler yazdırılır. Uyumlu olmayan hedefler yazdırılmaz.

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

Bilinen sorunlar

Uyumsuz hedefler görünürlük kısıtlamalarını yoksayar.