宏

报告问题 查看源代码 每夜 build · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本页介绍了使用宏的基础知识，包括典型用例、调试和惯例。

宏是从 BUILD 文件调用的函数，可实例化规则。宏主要用于现有规则和其他宏的封装和代码重复使用。在加载阶段结束时，宏将不再存在，而 Bazel 只能看到一组具体的实例化规则。

用法

宏的典型用例是，您想要重复使用规则。

例如，BUILD 文件中的 genrule 使用 //:generator 生成一个文件，并在命令中硬编码 some_arg 参数：

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

如果您想使用不同的实参生成更多文件，则可能需要将此代码提取到宏函数中。我们将宏命名为 file_generator，它具有 name 和 arg 参数。将 genrule 替换为以下内容：

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

在这里，您可以从位于 //path 软件包中的 .bzl 文件加载 file_generator 符号。通过将宏函数定义放在单独的 .bzl 文件中，您可以保持 BUILD 文件的简洁性和声明性，并且可以从工作区中的任何软件包加载 .bzl 文件。

最后，在 path/generator.bzl 中编写宏的定义，以封装和参数化原始 Genrule 定义：

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

您还可以使用宏将规则串联起来。以下示例展示了链式 genrule，其中 genrule 使用上一个 genrule 的输出作为输入：

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

该示例仅为第二代规则分配了可见性值。这样一来，宏作者就可以隐藏中间规则的输出，使其不被工作区中的其他目标依赖。

展开宏

如需了解某个宏的用途，请将 query 命令与 --output=build 结合使用，以查看展开后的形式：

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

实例化原生规则

原生规则（不需要 load() 语句的规则）可以从原生模块实例化：

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

如果您需要知道软件包名称（例如，哪个 BUILD 文件调用了宏），请使用函数 native.package_name()。请注意，native 只能在 .bzl 文件中使用，不能在 WORKSPACE 或 BUILD 文件中使用。

宏中的标签解析

由于宏是在加载阶段进行求值的，因此宏中出现的标签字符串（例如 "//foo:bar"）是相对于使用宏的 BUILD 文件进行解读的，而不是相对于定义宏的 .bzl 文件进行解读。对于要用于其他代码库的宏（例如，因为它们是已发布的 Starlark 规则集的一部分），这种行为通常不受欢迎。

如需获得与 Starlark 规则相同的行为，请使用 Label 构造函数封装标签字符串：

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main workspace, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

调试

  • bazel query --output=build //my/path:all 会显示 BUILD 文件在评估后的外观。所有宏、正则表达式、循环都会展开。已知限制：select 表达式目前不会显示在输出中。

  • 您可以根据 generator_function（生成规则的函数）或 generator_name（宏的名称属性）过滤输出：bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'

  • 如需了解 foo 规则在 BUILD 文件中生成的确切位置，您可以尝试以下技巧。在 BUILD 文件顶部附近插入以下代码行：cc_library(name = "foo")。运行 Bazel。创建规则 foo 时，您会收到一个异常（由于名称冲突），其中会显示完整的堆栈轨迹。

  • 您还可以使用 print 进行调试。它会在加载阶段以 DEBUG 日志行的形式显示消息。在将代码提交到仓库之前，除极少数情况外，请移除 print 调用，或在默认值为 False 的 debugging 参数下对其进行条件化处理。

错误

如果您想抛出错误，请使用 fail 函数。向用户明确说明问题所在以及如何修复 BUILD 文件。 无法捕获错误。

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

惯例

  • 实例化规则的所有公共函数（不以下划线开头的函数）都必须具有 name 参数。此参数不应是可选参数（请勿提供默认值）。

  • 公共函数应使用遵循 Python 惯例的文档字符串。

  • 在 BUILD 文件中，宏的 name 参数必须是关键字参数（而非位置参数）。

  • 由宏生成的规则的 name 属性应包含名称参数作为前缀。例如，macro(name = "foo") 可以生成 cc_library foo 和 Genrule foo_gen。

  • 在大多数情况下，可选参数的默认值应为 None。None 可以直接传递给原生规则，这些规则的处理方式与未传入任何参数的行为相同。因此，无需出于此目的将其替换为 0、False 或 []。相反，宏应遵循其创建的规则，因为默认规则可能很复杂，也可能会随时间而变化。此外，通过查询语言或构建系统内部访问时，显式设置为默认值的参数与从未设置（或设置为 None）的参数看起来不同。

  • 宏应该有一个可选的 visibility 参数。