本頁面由 Cloud Translation API 翻譯而成。

設定

本頁面說明 Starlark 設定的優點和基本用法，Bazel 的 API 可用來自訂專案建構方式。內容包括如何定義建構設定並提供範例。

這麼做可以：

為專案定義自訂標記，不再需要使用 --define
撰寫轉場效果，以不同於父項的設定依附元件設定依附元件 (例如 --compilation_mode=opt 或 --cpu=arm)
將更好的預設值烘焙為規則 (例如使用指定 SDK 自動建構 //my:android_app)

並全部移除 .bzl 檔案 (無需使用 Bazel 版本)。請前往 bazelbuild/examples 存放區查看範例。

使用者定義的建構設定

建構設定是單一的設定資訊。請將設定視為鍵/值對應。設定 --cpu=ppc 和 --copt="-DFoo" 會產生類似 {cpu: ppc, copt: "-DFoo"} 的設定。每個項目都是建構設定。

cpu 和 copt 等傳統旗標為原生設定，其鍵已定義，且其值會在原生 bazel Java 程式碼中設定。Bazel 使用者只能透過指令列和其他原生維護的 API 讀取及寫入這些內容。如要變更原生旗標和公開這些旗標的 API，您必須發布 Terraform 版本。使用者定義的建構設定是在 .bzl 檔案中定義，因此不需要 bazel 版本來登錄變更。此外，您也可以透過指令列設定這些項目 (若已指定為 flags，詳情請見下文)，但也可以透過使用者定義的轉場效果進行設定。

定義建構設定

端對端範例

`build_setting` `rule()` 參數

建構設定是與任何其他規則一樣的規則，並且會使用 Starlark rule() 函式的 build_setting 屬性來區分。

# example/buildsettings/build_settings.bzl
string_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)

build_setting 屬性會採用指定建構設定類型的函式。類型僅限於一組基本的 Starlark 類型，例如 bool 和 string。詳情請參閱 config 模組說明文件。而在規則的實作函式中，可以完成更複雜的輸入。詳情請參閱下方說明。

config 模組的函式採用選用的布林參數 flag (預設為 false)。如果 flag 設為 true，使用者也可以在指令列透過預設值和轉換，在指令列上設定建構設定。使用者不一定能調整所有設定。舉例來說，假設您做為規則寫入者，想要在測試規則中開啟某些偵錯模式，表示您不想讓使用者在其他非測試規則內，刻意開啟該功能。

使用 ctx.build_setting_value

如同所有規則，建構設定規則具有實作函式。您可以透過 ctx.build_setting_value 方法存取建構設定的基本 Starlark 類型值。這個方法僅適用於建構設定規則的 ctx 物件。這些實作方法可直接轉送建構設定值或對其執行其他工作，例如類型檢查或建立較複雜的結構體建立。以下示範如何實作以 enum 為基礎的建構設定：

# example/buildsettings/build_settings.bzl
TemperatureProvider = provider(fields = ['type'])

temperatures = ["HOT", "LUKEWARM", "ICED"]

def _impl(ctx):
    raw_temperature = ctx.build_setting_value
    if raw_temperature not in temperatures:
        fail(str(ctx.label) + " build setting allowed to take values {"
             + ", ".join(temperatures) + "} but was set to unallowed value "
             + raw_temperature)
    return TemperatureProvider(type = raw_temperature)

temperature = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)

定義多設定字串旗標

字串設定有額外的 allow_multiple 參數，可在指令列或 bazelrc 中設定多次標記。其預設值仍透過字串類型屬性設定：

# example/buildsettings/build_settings.bzl
allow_multiple_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True, allow_multiple = True)
)

# example/BUILD
load("//example/buildsettings:build_settings.bzl", "allow_multiple_flag")
allow_multiple_flag(
    name = "roasts",
    build_setting_default = "medium"
)

系統會將標記的各項設定視為單一值：

$ bazel build //my/target --//example:roasts=blonde \
    --//example:roasts=medium,dark

上述內容剖析為 {"//example:roasts": ["blonde", "medium,dark"]}，ctx.build_setting_value 則會傳回 ["blonde", "medium,dark"] 清單。

將建構設定執行個體化

使用 build_setting 參數定義的規則具有隱含的必要的 build_setting_default 屬性。這個屬性採用的類型與 build_setting 參數所宣告的類型相同。

# example/buildsettings/build_settings.bzl
FlavorProvider = provider(fields = ['type'])

def _impl(ctx):
    return FlavorProvider(type = ctx.build_setting_value)

flavor = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)

# example/BUILD
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
    name = "favorite_flavor",
    build_setting_default = "APPLE"
)

預先定義的設定

端對端範例

Skylib 程式庫包含一組預先定義的設定，您可以例項化，不必寫入自訂 Starlark。

舉例來說，如要定義接受一組有限字串值的設定：

# example/BUILD
load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
string_flag(
    name = "myflag",
    values = ["a", "b", "c"],
    build_setting_default = "a",
)

如需完整清單，請參閱「常見建構設定規則」。

使用建構設定

視建構設定而定

如果目標想讀取設定資訊，可以透過一般屬性依附元件直接依附建構設定。

# example/rules.bzl
load("//example/buildsettings:build_settings.bzl", "FlavorProvider")
def _rule_impl(ctx):
    if ctx.attr.flavor[FlavorProvider].type == "ORANGE":
        ...

drink_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "flavor": attr.label()
    }
)

# example/BUILD
load("//example:rules.bzl", "drink_rule")
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
    name = "favorite_flavor",
    build_setting_default = "APPLE"
)
drink_rule(
    name = "my_drink",
    flavor = ":favorite_flavor",
)

語言可能會建立一組標準建構設定，所有該語言的所有規則都依附於該設定。雖然 fragments 的原生概念不再以硬式編碼物件的形式存在於 Starlark 設定世界中，但要轉譯這個概念的方法之一是使用一組常見的隱含屬性。舉例來說：

# kotlin/rules.bzl
_KOTLIN_CONFIG = {
    "_compiler": attr.label(default = "//kotlin/config:compiler-flag"),
    "_mode": attr.label(default = "//kotlin/config:mode-flag"),
    ...
}

...

kotlin_library = rule(
    implementation = _rule_impl,
    attrs = dicts.add({
        "library-attr": attr.string()
    }, _KOTLIN_CONFIG)
)

kotlin_binary = rule(
    implementation = _binary_impl,
    attrs = dicts.add({
        "binary-attr": attr.label()
    }, _KOTLIN_CONFIG)

在指令列中使用建構設定

與大多數的原生標記類似，您可以使用指令列來設定標示為標記的建構設定。建構設定的名稱是其完整目標路徑，使用 name=value 語法：

$ bazel build //my/target --//example:string_flag=some-value # allowed
$ bazel build //my/target --//example:string_flag some-value # not allowed

支援特殊布林值語法：

$ bazel build //my/target --//example:boolean_flag
$ bazel build //my/target --no//example:boolean_flag

使用建構設定別名

您可以為建構設定目標路徑設定別名，以便更容易使用指令列。別名的功能與原生標記類似，也可以使用雙破折號選項語法。

透過將 --flag_alias=ALIAS_NAME=TARGET_PATH 新增至 .bazelrc 來設定別名。舉例來說，如要將別名設為 coffee，請按照下列步驟操作：

# .bazelrc
build --flag_alias=coffee=//experimental/user/starlark_configurations/basic_build_setting:coffee-temp

最佳做法：多次設定別名會導致系統優先採用最後設定。使用不重複的別名名稱，避免意外剖析結果。

如要使用別名，請輸入別名，取代建構設定目標路徑。根據上述 coffee 範例，已在使用者的 .bazelrc 中設定：

$ bazel build //my/target --coffee=ICED

而不是

$ bazel build //my/target --//experimental/user/starlark_configurations/basic_build_setting:coffee-temp=ICED

最佳做法：雖然您可以在指令列中設定別名，但將其放在 .bazelrc 中可減少指令列的雜訊。

標籤類型的建構設定

端對端範例

與其他建構設定不同，您無法使用 build_setting 規則參數定義標籤類型的設定。然而，bazel 有兩項內建規則：label_flag 和 label_setting。這些規則會將建構設定的實際目標供應商轉送至該建構設定的實際目標。轉換功能可讀取/寫入 label_flag 和 label_setting，且使用者可以像其他 build_setting 規則一樣設定 label_flag。唯一的差別在於無法自訂

「標籤類型」設定最終會取代晚期預設設定的功能。延遲繫結的預設屬性為「標籤」類型的屬性，其最終值可受設定影響。在 Starlark 中，這會取代 configuration_field API。

# example/rules.bzl
MyProvider = provider(fields = ["my_field"])

def _dep_impl(ctx):
    return MyProvider(my_field = "yeehaw")

dep_rule = rule(
    implementation = _dep_impl
)

def _parent_impl(ctx):
    if ctx.attr.my_field_provider[MyProvider].my_field == "cowabunga":
        ...

parent_rule = rule(
    implementation = _parent_impl,
    attrs = { "my_field_provider": attr.label() }
)

# example/BUILD
load("//example:rules.bzl", "dep_rule", "parent_rule")

dep_rule(name = "dep")

parent_rule(name = "parent", my_field_provider = ":my_field_provider")

label_flag(
    name = "my_field_provider",
    build_setting_default = ":dep"
)

建構設定和 select()

端對端範例

使用者可以透過 select()，在建構設定中設定屬性。建構設定目標可傳遞至 config_setting 的 flag_values 屬性。用來比對的值會以 String 的形式傳遞，然後剖析為建構設定的類型來進行比對。

config_setting(
    name = "my_config",
    flag_values = {
        "//example:favorite_flavor": "MANGO"
    }
)

使用者定義的轉場效果

設定轉換會將已設定目標的轉換對應至建構圖表中的另一個目標。

設定規則的規則必須包含特殊屬性：

  "_allowlist_function_transition": attr.label(
      default = "@bazel_tools//tools/allowlists/function_transition_allowlist"
  )

透過新增轉場效果，即可輕鬆探索建構圖的大小。這會針對您可以建立此規則目標的套件設定許可清單。上方程式碼區塊的預設值是允許列出所有項目。不過，如果想要限制哪些使用者正在使用您的規則，可以將該屬性設為指向您的自訂許可清單。如果您想提供建議或協助，瞭解轉換會對建構效能造成哪些影響，請與 bazel-discuss@googlegroups.com 聯絡。

定義

轉換會定義規則之間的設定變更。例如，「編譯依附元件，採用的 CPU 與父項不同」之類的要求會由轉換處理。

正式轉換是指從輸入設定到一或多個輸出設定的函式。多數轉場效果會是 1:1，例如「使用 --cpu=ppc 覆寫輸入設定」。此外，也可以有 1:2 以上的轉場效果，但會有特殊限制。

在 Starlark 中，轉場效果的定義方式與規則類似，需定義 transition() 函式和實作函式。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {"//example:favorite_flavor" : "MINT"}

hot_chocolate_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

transition() 函式採用實作函式、要讀取的建構設定(inputs)，以及一組可寫入的建構設定 (outputs)。實作函式有兩個參數：settings 和 attr。settings 是所有在 inputs 參數中宣告為 transition() 的字典 {String:Object}。

attr 是附加轉換規則的屬性和值的字典。做為傳出邊緣轉換作業附加時，這些屬性的值都會是已設定的後選取() 解析度。做為即將推出的邊緣轉換附加時，attr 不包含任何使用選取器解析值的屬性。如果 --foo 上的後續邊緣轉換會讀取屬性 bar，然後選取 --foo 以設定 bar 屬性，則後續邊緣轉換也可能會在轉場中讀取錯誤的 bar 值。

實作函式必須傳回要套用的新建構設定值的字典 (或字典清單，若有多種輸出設定則適用)。傳回的字典金鑰組必須包含傳遞至轉換函式 outputs 參數的建構設定組合。即使建構設定不會在轉換過程中實際變更，情況也是如此，因此其原始值必須在傳回的字典中明確傳遞。

定義 1:2 以上的轉場效果

端對端範例

「傳出邊緣轉換」可將單一輸入設定對應至兩個以上的輸出設定。如要定義組合多架構程式碼的規則，這就非常實用。

1:2 以上的轉場效果，是透過在轉換實作函式中傳回字典清單來定義。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return [
        {"//example:favorite_flavor" : "LATTE"},
        {"//example:favorite_flavor" : "MOCHA"},
    ]

coffee_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

他們也可以設定自訂鍵，規則實作函式可用來讀取個別依附元件：

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "Apple deps": {"//command_line_option:cpu": "ppc"},
        "Linux deps": {"//command_line_option:cpu": "x86"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]
)

附加轉場效果

端對端範例

轉場效果可連接以下兩處：外來邊緣和傳出邊緣。實際上，這表示規則可以轉換自己的設定 (即將進入邊緣轉換)，並轉換其依附元件設定 (連出邊緣轉換)。

注意：目前無法將 Starlark 轉換附加至原生規則。如果需要這樣做，請聯絡 bazel-discuss@googlegroups.com，以協助您找出解決方法。

連入邊緣轉場效果

將 transition 物件 (由 transition() 建立) 附加至 rule() 的 cfg 參數，即可啟用傳入邊緣轉換：

# example/rules.bzl
load("example/transitions:transitions.bzl", "hot_chocolate_transition")
drink_rule = rule(
    implementation = _impl,
    cfg = hot_chocolate_transition,
    ...

連入邊緣轉場必須為 1:1 轉場效果。

傳出邊緣轉場效果

如要啟用傳出邊緣轉場效果，請將 transition 物件 (由 transition() 建立) 附加至屬性的 cfg 參數：

# example/rules.bzl
load("example/transitions:transitions.bzl", "coffee_transition")
drink_rule = rule(
    implementation = _impl,
    attrs = { "dep": attr.label(cfg = coffee_transition)}
    ...

連出邊緣轉場可為 1:1 或 1:2 以上。

如要瞭解如何讀取這些鍵，請參閱「使用轉場效果存取屬性」一節。

原生選項轉換

端對端範例

Starlark 轉換還可透過選項名稱的特殊前置字串，宣告原生建構設定選項的讀取和寫入作業。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {"//command_line_option:cpu": "k8"}

cpu_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]

不支援的原生選項

Bazel 不支援在 --define 上透過 "//command_line_option:define" 進行轉換。請改用自訂建構設定。一般來說，我們不建議使用 --define 改用建構設定。

Bazel 不支援在 --config 上轉換。這是因為 --config 是展開為其他標記的「expansion」標記。

至關重要的一點是，--config 可能包含不會影響建構設定的標記，例如 --spawn_strategy。Bazel 在設計上無法將這類標記繫結至個別目標。這表示在轉換中無法同步套用這些變數。

如要解決這個問題，您可以明確列出轉換過程中的設定「是」的標記。這需要同時將 --config 的延伸至兩個地方，也就是已知的 UI 模糊效果。

啟用多個建構設定的轉換

調整允許多個值的建構設定時，必須透過清單設定該設定的值。

# example/buildsettings/build_settings.bzl
string_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True, allow_multiple = True)
)

# example/BUILD
load("//example/buildsettings:build_settings.bzl", "string_flag")
string_flag(name = "roasts", build_setting_default = "medium")

# example/transitions/rules.bzl
def _transition_impl(settings, attr):
    # Using a value of just "dark" here will throw an error
    return {"//example:roasts" : ["dark"]},

coffee_transition = transition(
    implementation = _transition_impl,
    inputs = [],
    outputs = ["//example:roasts"]
)

免人工管理轉場效果

如果轉場效果傳回 {}、[] 或 None，這是將所有設定保留原始值的簡寫。比起明確地為每個輸出內容自行設定，這麼做會更加便利。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (attr)
    if settings["//example:already_chosen"] is True:
      return {}
    return {
      "//example:favorite_flavor": "dark chocolate",
      "//example:include_marshmallows": "yes",
      "//example:desired_temperature": "38C",
    }

hot_chocolate_transition = transition(
    implementation = _impl,
    inputs = ["//example:already_chosen"],
    outputs = [
        "//example:favorite_flavor",
        "//example:include_marshmallows",
        "//example:desired_temperature",
    ]
)

透過轉換存取屬性

端對端範例

當你將轉場效果附加至連出邊緣 (無論轉換作業為 1:1 或 1:2 以上的轉場效果) 時，如果 ctx.attr 尚未轉換，則會強製成為清單。系統未指定這份清單中的元素順序。

# example/transitions/rules.bzl
def _transition_impl(settings, attr):
    return {"//example:favorite_flavor" : "LATTE"},

coffee_transition = transition(
    implementation = _transition_impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

def _rule_impl(ctx):
    # Note: List access even though "dep" is not declared as list
    transitioned_dep = ctx.attr.dep[0]

    # Note: Access doesn't change, other_deps was already a list
    for other_dep in ctx.attr.other_deps:
      # ...


coffee_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "dep": attr.label(cfg = coffee_transition)
        "other_deps": attr.label_list(cfg = coffee_transition)
    })

如果轉場效果為 1:2+ 並設定了自訂鍵，則 ctx.split_attr 可用來讀取每個鍵的個別依附元件：

# example/transitions/rules.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "Apple deps": {"//command_line_option:cpu": "ppc"},
        "Linux deps": {"//command_line_option:cpu": "x86"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]
)

def _rule_impl(ctx):
    apple_dep = ctx.split_attr.dep["Apple deps"]
    linux_dep = ctx.split_attr.dep["Linux deps"]
    # ctx.attr has a list of all deps for all keys. Order is not guaranteed.
    all_deps = ctx.attr.dep

multi_arch_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "dep": attr.label(cfg = multi_arch_transition)
    })

請參閱完整範例。

與平台和工具鍊整合

現今許多原生旗標 (例如 --cpu 和 --crosstool_top) 都與工具鍊解析度有關。日後在目標平台上進行轉換，可能會取代這些標記類型的明確轉換。

記憶體和效能注意事項

新增轉換和因此在建構作業中加入新設定會產生成本：較大的建構圖表、難以理解的建構圖表及建構速度較慢。當您考慮在建構規則中使用轉換時，建議您考量這些成本。以下舉例說明轉換可能如何使建構圖表呈指數成長。

行為不良的建構版本：個案研究

擴充性圖表

圖 1 顯示頂層目標及其依附元件的擴充性圖表。

此圖表顯示頂層目標 //pkg:app，其依附於兩個目標：//pkg:1_0 和 //pkg:1_1。這兩種目標都依附於 //pkg:2_0 和 //pkg:2_1 兩個目標。這兩種目標都取決於 //pkg:3_0 和 //pkg:3_1 兩個目標。這會持續到 //pkg:n_0 和 //pkg:n_1，而兩者都依附單一目標 //pkg:dep。

建立//pkg:app需要 \(2n+2\) 目標：

//pkg:app
//pkg:dep
//pkg:i_0和//pkg:i_1 ( \(i\) - \([1..n]\))

假設您implement旗標 --//foo:owner=<STRING> 和 //pkg:i_b

depConfig = myConfig + depConfig.owner="$(myConfig.owner)$(b)"

換句話說，//pkg:i_b 會在其所有依附元件的 --owner 的舊值中附加 b。

會產生下列設定的目標：

//pkg:app                              //foo:owner=""
//pkg:1_0                              //foo:owner=""
//pkg:1_1                              //foo:owner=""
//pkg:2_0 (via //pkg:1_0)              //foo:owner="0"
//pkg:2_0 (via //pkg:1_1)              //foo:owner="1"
//pkg:2_1 (via //pkg:1_0)              //foo:owner="0"
//pkg:2_1 (via //pkg:1_1)              //foo:owner="1"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_0)  //foo:owner="00"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_1)  //foo:owner="01"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_0)  //foo:owner="10"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_1)  //foo:owner="11"
...

//pkg:dep 會產生 \(2^n\) 設定的目標：config.owner= 中所有使用者「\(b_0b_1...b_n\)」的 \(b_i\) \(\{0,1\}\)。

這會使建構圖比目標圖表指數大上，產生對應的記憶體和效能結果。

待辦事項：新增評估和緩解這些問題的策略。

其他資訊

如要進一步瞭解如何修改建構設定，請參閱：

設定

使用者定義的建構設定

定義建構設定

build_setting rule() 參數

使用 ctx.build_setting_value

定義多設定字串旗標

將建構設定執行個體化

預先定義的設定

使用建構設定

視建構設定而定

在指令列中使用建構設定

使用建構設定別名

標籤類型的建構設定

建構設定和 select()

使用者定義的轉場效果

定義

定義 1:2 以上的轉場效果

附加轉場效果

連入邊緣轉場效果

傳出邊緣轉場效果

原生選項轉換

不支援的原生選項

啟用多個建構設定的轉換

免人工管理轉場效果

透過轉換存取屬性

與平台和工具鍊整合

記憶體和效能注意事項

行為不良的建構版本：個案研究

其他資訊

`build_setting` `rule()` 參數