Java ve Bazel

7.3 · 7.2 · 7.1 · 7.0 · 6.5

Bu sayfa, Java projeleriyle Bazel'i kullanmanıza yardımcı olacak kaynaklar içerir. Bu sayfa, bir eğitime, derleme kurallarına ve Bazel ile Java projeleri oluşturmaya özel diğer bilgilere bağlantı verir.

Bazel ile çalışma

Aşağıdaki kaynaklar, Java projelerinde Bazel ile çalışmanıza yardımcı olur:

Bazel'e geçme

Şu anda Java projelerinizi Maven ile derliyorsanız Maven projelerinizi Bazel ile derlemeye başlamak için taşıma rehberindeki adımları uygulayın:

Java sürümleri

Java'nın yapılandırma bayraklarıyla ayarlanmış iki alakalı sürümü vardır:

  • depodaki kaynak dosyaların sürümü
  • kodu çalıştırmak ve test etmek için kullanılan Java çalışma zamanı sürümü

Deponuzdaki kaynak kodu sürümünü yapılandırma

Ek yapılandırma olmadan, Bazel depodaki tüm Java kaynak dosyalarının tek bir Java sürümünde yazıldığını varsayar. Depodaki kaynakların sürümünü belirtmek için .bazelrc dosyasına build --java_language_version={ver} ekleyin. Burada {ver}, örneğin 11 olabilir. Bazel deposu sahipleri, Bazel ve kullanıcılarının kaynak kodun Java sürüm numarasına referans vermesi için bu işareti ayarlamalıdır. Daha fazla bilgi için Java dili sürüm işareti bölümüne bakın.

Kodu yürütmek ve test etmek için kullanılan JVM'yi yapılandırma

Bazel, derleme için bir JDK, kodu yürütmek ve test etmek için başka bir JDK kullanır.

Varsayılan olarak Bazel, kodu indirdiği bir JDK kullanarak derler ve kodu, yerel makinede yüklü JVM ile yürütüp test eder. Bazel, JAVA_HOME veya yolu kullanarak JVM'yi arar.

Ortaya çıkan ikili programlar, sistem kitaplıklarında yerel olarak yüklenen JVM ile uyumludur. Diğer bir deyişle, elde edilen ikili programlar makinede nelerin yüklü olduğuna bağlıdır.

Yürütme ve test amacıyla kullanılan JVM'yi yapılandırmak için --java_runtime_version işaretini kullanın. Varsayılan değer local_jdk değeridir.

Hermetik test ve derleme

Hermetik derleme oluşturmak için --java_runtime_version=remotejdk_11 komut satırı işaretini kullanabilirsiniz. Kod, uzak bir depodan indirilen JVM için derlenir, yürütülür ve test edilir. Daha fazla bilgi için Java çalışma zamanı sürümü işareti başlıklı makaleyi inceleyin.

Java'da derleme ve derleme araçlarının yürütülmesini yapılandırma

Araçları derlemek ve yürütmek için kullanılan ikinci bir JDK ve JVM çifti vardır. Bu çift, derleme sürecinde kullanılır ancak derleme sonuçlarında yer almaz. Bu JDK ve JVM, --tool_java_language_version ve --tool_java_runtime_version kullanılarak kontrol edilir. Varsayılan değerler sırasıyla 11 ve remotejdk_11'tır.

Yerel olarak yüklü JDK'yi kullanarak derleme

Bazel, JDK'nin dahili özelliklerini geçersiz kıldığı için varsayılan olarak uzak JDK'yi kullanarak derleme yapar. Yerel olarak yüklü JDK'yi kullanan derleme araç zincirleri yapılandırılır ancak kullanılmaz.

Yerel JDK için derleme araç zincirlerini kullanan, yerel olarak yüklenmiş JDK'yı kullanarak derlemek için ek --extra_toolchains=@local_jdk//:all işaretini kullanın. Ancak bu etiketin rastgele tedarikçilerin JDK'sında çalışmayabileceğini unutmayın.

Daha fazla bilgi için Java araç zincirlerini yapılandırma bölümüne bakın.

En iyi uygulamalar

Genel Bazel en iyi uygulamalarına ek olarak, aşağıda Java projelerine özel en iyi uygulamalar yer almaktadır.

Dizin yapısı

Maven'in standart dizin düzenini tercih edin (src/main/java altındaki kaynaklar, src/test/java altındaki testler).

BUILD dosyaları

BUILD dosyalarınızı oluştururken şu kurallara uyun:

  • Derleme performansını artırdığından, Java kaynaklarını içeren dizin başına bir BUILD dosyası kullanın.

  • Her BUILD dosyası şuna benzeyen bir java_library kuralı içermelidir:

    java_library(
    name = "directory-name",
    srcs = glob(["*.java"]),
    deps = [...],
)

  • Kitaplığın adı, BUILD dosyasını içeren dizinin adı olmalıdır. Bu, kitaplığın etiketini kısaltır. Bu durumda, "//package:package" yerine "//package" kullanılır.

  • Kaynaklar, dizindeki tüm Java dosyalarının yinelemeli olmayan bir glob olmalıdır.

  • Testler, src/test altındaki eşleşen bir dizinde yer alır ve bu kitaplığa bağlıdır.

Gelişmiş Java derlemeleri için yeni kurallar oluşturma

Not: Yeni kural oluşturma, gelişmiş derleme ve test senaryoları içindir. Bazel'i kullanmaya başlarken buna ihtiyacınız yoktur.

Aşağıdaki modüller, yapılandırma parçaları ve sağlayıcılar, Java projelerinizi oluştururken Bazel'in becerilerini artırmanıza yardımcı olacaktır:

Java araç zincirlerini yapılandırma

Bazel iki tür Java araç zinciri kullanır: - Java ikili dosyalarını yürütmek ve test etmek için kullanılan yürütme, --java_runtime_version işaretiyle kontrol edilir - Java kaynaklarını derlemek için kullanılan derleme, --java_language_version işaretiyle kontrol edilir

Ek yürütme araç zincirlerini yapılandırma

Yürütme araç zinciri, yerel veya bir depodan alınan JVM'dir. Bu sanal makinenin sürümü, işletim sistemi ve CPU mimarisi hakkında ek bilgiler bulunur.

Java yürütme araç zincirleri, WORKSPACE dosyasında local_java_repository veya remote_java_repository kuralları kullanılarak eklenebilir. Kural eklendiğinde JVM, bir işaret kullanılarak kullanılabilir hale gelir. Aynı işletim sistemi ve CPU mimarisi için birden fazla tanım verildiğinde ilk tanım kullanılır.

Yerel JVM yapılandırması için örnek:

load("@bazel_tools//tools/jdk:local_java_repository.bzl", "local_java_repository")

local_java_repository(
  name = "additionaljdk",          # Can be used with --java_runtime_version=additionaljdk, --java_runtime_version=11 or --java_runtime_version=additionaljdk_11
  version = 11,                    # Optional, if not set it is autodetected
  java_home = "/usr/lib/jdk-15/",  # Path to directory containing bin/java
)

Uzak JVM yapılandırması örneği:

load("@bazel_tools//tools/jdk:remote_java_repository.bzl", "remote_java_repository")

remote_java_repository(
  name = "openjdk_canary_linux_arm",
  prefix = "openjdk_canary", # Can be used with --java_runtime_version=openjdk_canary_11
  version = "11",            # or --java_runtime_version=11
  target_compatible_with = [ # Specifies constraints this JVM is compatible with
    "@platforms//cpu:arm",
    "@platforms//os:linux",
  ],
  urls = ...,               # Other parameters are from http_repository rule.
  sha256 = ...,
  strip_prefix = ...
)

Ek derleme araç zincirleri yapılandırma

Derleme araç zinciri, JDK'den ve Bazel'in derleme sırasında kullandığı birçok araçtan oluşur. Bu araçlarda şunlar bulunur: Prone, katı Java bağımlılıkları, başlık derleme, Android'de sulama, kapsam enstrümantasyonu ve IDE'ler için genel işleme.

JavaBuilder, derleme yürüten ve yukarıda belirtilen özellikleri sağlayan, Bazel paketine sahip bir araçtır. Gerçek derleme, JDK tarafından dahili derleyici kullanılarak yürütülür. Derleme için kullanılan JDK, araç zincirinin java_runtime özelliği tarafından belirtilir.

Bazel, bazı JDK dahili değerlerini geçersiz kılar. JDK sürüm 9'dan büyükse java.compiler ve jdk.compiler modüllerine JDK'nın --patch_module işareti kullanılarak yama uygulanır. JDK 8 sürümü söz konusu olduğunda Java derleyicisi, -Xbootclasspath işareti kullanılarak yamalı hale getirilir.

VanillaJavaBuilder, JDK'nın dahili derleyicisinde değişiklik yapmayan ve ek özelliklere sahip olmayan ikinci bir JavaBuilder uygulamasıdır. VanillaJavaBuilder, yerleşik araç takımlarından hiçbiri tarafından kullanılmaz.

Bazel, derleme sırasında JavaBuilder'a ek olarak başka araçlar da kullanır.

ijar aracı, çağrı imzaları dışındaki her şeyi kaldırmak için jar dosyalarını işler. Ortaya çıkan kavanozlara başlık kavanozu denir. Bunlar, yalnızca bir işlevin gövdesi değiştiğinde aşağı akış bağımlılarını yeniden derleyerek derleme artımlılığını iyileştirmek için kullanılır.

singlejar aracı, birden fazla jar dosyasını tek bir dosyada paketler.

genclass aracı, Java derlemesinin çıktısını son işleme tabi tutar ve yalnızca ek açıklama işleyiciler tarafından oluşturulan kaynakların sınıf dosyalarını içeren bir jar oluşturur.

JacocoRunner aracı, enstrümanlı dosyalar üzerinde Jacoco'yu çalıştırır ve sonuçları LCOV biçiminde sunar.

TestRunner aracı, JUnit 4 testlerini kontrollü bir ortamda yürütür.

BUILD dosyasına default_java_toolchain makrosu ekleyip WORKSPACE dosyasına register_toolchains kuralı ekleyerek veya --extra_toolchains işaretini kullanarak derlemeyi yeniden yapılandırabilirsiniz.

Araç zinciri yalnızca source_version özelliği --java_language_version işaretçisi tarafından belirtilen değerle eşleştiğinde kullanılır.

Örnek araç zinciri yapılandırması:

load(
  "@bazel_tools//tools/jdk:default_java_toolchain.bzl",
  "default_java_toolchain", "DEFAULT_TOOLCHAIN_CONFIGURATION", "BASE_JDK9_JVM_OPTS", "DEFAULT_JAVACOPTS"
)

default_java_toolchain(
  name = "repository_default_toolchain",
  configuration = DEFAULT_TOOLCHAIN_CONFIGURATION,        # One of predefined configurations
                                                          # Other parameters are from java_toolchain rule:
  java_runtime = "@bazel_tools//tools/jdk:remote_jdk11", # JDK to use for compilation and toolchain's tools execution
  jvm_opts = BASE_JDK9_JVM_OPTS + ["--enable_preview"],   # Additional JDK options
  javacopts = DEFAULT_JAVACOPTS + ["--enable_preview"],   # Additional javac options
  source_version = "9",
)

--extra_toolchains=//:repository_default_toolchain_definition kullanılarak veya çalışma alanına register_toolchains("//:repository_default_toolchain_definition") eklenerek kullanılabilir.

Önceden tanımlanmış yapılandırmalar:

  • DEFAULT_TOOLCHAIN_CONFIGURATION: tüm özellikler, JDK sürümleri 9 ve üzerini destekler
  • VANILLA_TOOLCHAIN_CONFIGURATION: Ek özellik yoktur, isteğe bağlı tedarikçi firmaların JDK'lerini destekler.
  • PREBUILT_TOOLCHAIN_CONFIGURATION: varsayılanla aynı, ancak yalnızca önceden oluşturulmuş araçları kullan (ijar, singlejar)
  • NONPREBUILT_TOOLCHAIN_CONFIGURATION: varsayılanla aynıdır, ancak tüm araçlar kaynaklardan derlenmiştir (bu, farklı libc'ye sahip işletim sistemlerinde faydalı olabilir)

JVM ve Java derleyici işaretlerini yapılandırma

JVM ve javac işaretlerini işaretlerle veya default_java_toolchain özellikleriyle yapılandırabilirsiniz.

İlgili işaretler: --jvmopt, --host_jvmopt, --javacopt ve --host_javacopt.

İlgili default_java_toolchain özellikleri javacopts, jvm_opts, javabuilder_jvm_opts ve turbine_jvm_opts'tir.

Pakete özel Java derleyici işaretleri yapılandırması

default_java_toolchain öğesinin package_configuration özelliğini kullanarak belirli kaynak dosyaları için farklı Java derleyici işaretleri yapılandırabilirsiniz. Lütfen aşağıdaki örneği inceleyin.

load("@bazel_tools//tools/jdk:default_java_toolchain.bzl", "default_java_toolchain")

# This is a convenience macro that inherits values from Bazel's default java_toolchain
default_java_toolchain(
    name = "toolchain",
    package_configuration = [
        ":error_prone",
    ],
    visibility = ["//visibility:public"],
)

# This associates a set of javac flags with a set of packages
java_package_configuration(
    name = "error_prone",
    javacopts = [
        "-Xep:MissingOverride:ERROR",
    ],
    packages = ["error_prone_packages"],
)

# This is a regular package_group, which is used to specify a set of packages to apply flags to
package_group(
    name = "error_prone_packages",
    packages = [
        "//foo/...",
        "-//foo/bar/...", # this is an exclusion
    ],
)

Tek bir depoda birden fazla Java kaynak kodu sürümü

Bazel, bir derlemede yalnızca Java kaynaklarının tek bir sürümünü derlemeyi destekler. Bu, bir Java testi veya uygulaması oluştururken tüm bağımlıların aynı Java sürümüne göre oluşturulduğu anlamına gelir.

Ancak farklı işaretler kullanılarak ayrı derlemeler yürütülebilir.

Farklı işaretler kullanma görevini kolaylaştırmak için belirli bir sürüme ait işaret grupları, .bazelrc yapılandırmalarıyla gruplandırılabilir:

build:java8 --java_language_version=8
build:java8 --java_runtime_version=local_jdk_8
build:java11 --java_language_version=11
build:java11 --java_runtime_version=remotejdk_11

Bu yapılandırmalar, --config işaretiyle birlikte kullanılabilir (ör. bazel test --config=java11 //:java11_test).